二十九、oracle 觸發器

標籤：

一、觸發器簡介

      觸發器的定義就是說某個條件成立的時候，觸發器裡面所定義的語句就會被自動的執行。因此觸發器不需要人為的去調用，也不能調用。然後，觸發器的觸發條件其實在你定義的時候就已經設定好了。這裡面需要說明一下，觸發器可以分為語句級觸發器和行級觸發器。詳細的介紹可以參考網上的資料，簡單的說就是語句級的觸發器可以在某些語句執行前或執行後被觸發。而行級觸發器則是在定義的了觸發的表中的行資料改變時就會被觸發一次。
具體舉例：
1、 在一個表中定義的語句級的觸發器，當這個表被刪除時，程式就會自動執行觸發器裡面定義的操作過程。這個就是刪除表的操作就是觸發器執行的條件了。
2、 在一個表中定義了行級的觸發器，那當這個表中一行資料發生變化的時候，比如刪除了一行記錄，那觸發器也會被自動執行了。

     

二、觸發器文法

觸發器的文法：
create [or replace] tigger 觸發器名 觸發時間 觸發事件
on 表名
[for each row]
begin
  pl/sql語句
end
其中：
觸發器名：觸發器對象的名稱。由於觸發器是資料庫自動執行的，因此該名稱只是一個名稱，沒有實質的用途。
觸發時間：指明觸發器何時執行，該值可取：
before：表示在資料庫動作之前觸發器執行;
after：表示在資料庫動作之後觸發器執行。
觸發事件：指明哪些資料庫動作會觸發此觸發器：
insert：資料庫插入會觸發此觸發器;
update：資料庫修改會觸發此觸發器;
delete：資料庫刪除會觸發此觸發器。
表 名：資料庫觸發器所在的表。
for each row：對錶的每一行觸發器執行一次。如果沒有這一選項，則只對整個表執行一次。

    

觸發器能實現如下功能：

功能：
1、 允許/限制對錶的修改
2、 自動產生衍生的資料行，比如自增欄位
3、 強制資料一致性
4、 提供審計和日誌記錄
5、 防止無效的交易處理
6、 啟用複雜的商務邏輯

     

舉例
1)、下面的觸發器在更新表tb_emp之前觸發，目的是不允許在周末修改表：

create or replace trigger auth_secure before insert or update or DELETE 
on tb_emp
begin
   IF(to_char(sysdate,‘DY‘)=‘星期日‘) THEN
       RAISE_APPLICATION_ERROR(-20600,‘不能在周末修改表tb_emp‘);
   END IF;
END;
/

    

2)、使用觸發器實現序號自增
建立一個測試表：

create table tab_user(
   id number(11) primary key,
   username varchar(50),
   password varchar(50)
);

建立一個序列：

create sequence my_seq increment by 1 start with 1 nomaxvalue nocycle cache 20;

建立一個觸發器：

CREATE OR REPLACE TRIGGER MY_TGR
  BEFORE INSERT ON TAB_USER
  FOR EACH ROW--對錶的每一行觸發器執行一次
DECLARE
  NEXT_ID NUMBER;
BEGIN
  SELECT MY_SEQ.NEXTVAL INTO NEXT_ID FROM DUAL;
  :NEW.ID := NEXT_ID; --:NEW表示新插入的那條記錄
END;

向表插入資料:

insert into tab_user(username,password) values(‘admin‘,‘admin‘);
insert into tab_user(username,password) values(‘fgz‘,‘fgz‘);
insert into tab_user(username,password) values(‘test‘,‘test‘);
COMMIT;

查詢表結果：SELECT * FROM TAB_USER;

      

3)、當使用者對test表執行DML語句時，將相關資訊記錄到日誌表

--建立測試表
CREATE TABLE test(
   t_id   NUMBER(4),
   t_name VARCHAR2(20),
   t_age  NUMBER(2),
   t_sex  CHAR
);
--建立記錄測試表
CREATE TABLE test_log(
   l_user   VARCHAR2(15),
   l_type   VARCHAR2(15),
   l_date   VARCHAR2(30)
);

建立觸發器：     

--建立觸發器
CREATE OR REPLACE TRIGGER TEST_TRIGGER
  AFTER DELETE OR INSERT OR UPDATE ON TEST
DECLARE
  V_TYPE TEST_LOG.L_TYPE%TYPE;
BEGIN
  IF INSERTING THEN
    --INSERT觸發
    V_TYPE := ‘INSERT‘;
    DBMS_OUTPUT.PUT_LINE(‘記錄已經成功插入，並已記錄到日誌‘);
  ELSIF UPDATING THEN
    --UPDATE觸發
    V_TYPE := ‘UPDATE‘;
    DBMS_OUTPUT.PUT_LINE(‘記錄已經成功更新，並已記錄到日誌‘);
  ELSIF DELETING THEN
    --DELETE觸發
    V_TYPE := ‘DELETE‘;
    DBMS_OUTPUT.PUT_LINE(‘記錄已經成功刪除，並已記錄到日誌‘);
  END IF;
  INSERT INTO TEST_LOG
  VALUES
    (USER, V_TYPE, TO_CHAR(SYSDATE, ‘yyyy-mm-dd hh24:mi:ss‘)); --USER表示目前使用者名
END;
/

--下面我們來分別執行DML語句
INSERT INTO test VALUES(101,‘zhao‘,22,‘M‘);
UPDATE test SET t_age = 30 WHERE t_id = 101;
DELETE test WHERE t_id = 101;
--然後查看效果
SELECT * FROM test;
SELECT * FROM test_log;

運行結果如下：

        

3)、建立觸發器，它將映射emp表中每個部門的總人數和總工資 

--建立映射表
CREATE TABLE dept_sal AS 
SELECT deptno, COUNT(empno) total_emp, SUM(sal) total_sal 
FROM scott.emp 
GROUP BY deptno;

     

--建立觸發器
CREATE OR REPLACE TRIGGER EMP_INFO
  AFTER INSERT OR UPDATE OR DELETE ON scott.EMP
DECLARE
  CURSOR CUR_EMP IS
    SELECT DEPTNO, COUNT(EMPNO) AS TOTAL_EMP, SUM(SAL) AS TOTAL_SAL FROM scott.EMP GROUP BY DEPTNO;
BEGIN
  DELETE DEPT_SAL; --觸發時首先刪除映射表資訊 
  FOR V_EMP IN CUR_EMP LOOP
    --DBMS_OUTPUT.PUT_LINE(v_emp.deptno || v_emp.total_emp || v_emp.total_sal);  
    --插入資料  
    INSERT INTO DEPT_SAL
    VALUES
      (V_EMP.DEPTNO, V_EMP.TOTAL_EMP, V_EMP.TOTAL_SAL);
  END LOOP;
END;

      

--對emp表進行DML操作
INSERT INTO emp(empno,deptno,sal) VALUES(‘123‘,‘10‘,10000);
SELECT * FROM dept_sal;
DELETE EMP WHERE empno=123;
SELECT * FROM dept_sal;

 顯示結果如下：

           

4)、建立觸發器，用來記錄表的刪除資料

--建立表
CREATE TABLE employee(
   id   VARCHAR2(4)  NOT NULL, 
   name VARCHAR2(15) NOT NULL, 
   age  NUMBER(2)    NOT NULL, 
   sex  CHAR NOT NULL
);

--插入資料
INSERT INTO employee VALUES(‘e101‘,‘zhao‘,23,‘M‘);
INSERT INTO employee VALUES(‘e102‘,‘jian‘,21,‘F‘);

--建立記錄表(包含資料記錄)
CREATE TABLE old_employee AS SELECT * FROM employee;

--建立觸發器
CREATE OR REPLACE TRIGGER TIG_OLD_EMP
  AFTER DELETE ON EMPLOYEE
  FOR EACH ROW --語句級觸發，即每一行觸發一次
BEGIN
  INSERT INTO OLD_EMPLOYEE VALUES (:OLD.ID, :OLD.NAME, :OLD.AGE, :OLD.SEX); --:old代表舊值
END;
/

--下面進行測試
DELETE employee;
SELECT * FROM old_employee;

      

5)、建立觸發器，利用視圖插入資料

--建立表
CREATE TABLE tab1 (tid NUMBER(4) PRIMARY KEY,tname VARCHAR2(20),tage NUMBER(2));
CREATE TABLE tab2 (tid NUMBER(4),ttel VARCHAR2(15),tadr VARCHAR2(30));

--插入資料
INSERT INTO tab1 VALUES(101,‘zhao‘,22);
INSERT INTO tab1 VALUES(102,‘yang‘,20);
INSERT INTO tab2 VALUES(101,‘13761512841‘,‘AnHuiSuZhou‘);
INSERT INTO tab2 VALUES(102,‘13563258514‘,‘AnHuiSuZhou‘);

--建立視圖串連兩張表
CREATE OR REPLACE VIEW tab_view AS SELECT tab1.tid,tname,ttel,tadr FROM tab1,tab2  WHERE tab1.tid = tab2.tid;

--建立觸發器
CREATE OR REPLACE TRIGGER TAB_TRIGGER
  INSTEAD OF INSERT ON TAB_VIEW
BEGIN
  INSERT INTO TAB1 (TID, TNAME) VALUES (:NEW.TID, :NEW.TNAME);
  INSERT INTO TAB2 (TTEL, TADR) VALUES (:NEW.TTEL, :NEW.TADR);
END;
/

--現在就可以利用視圖插入資料
INSERT INTO tab_view VALUES(106,‘ljq‘,‘13886681288‘,‘beijing‘);

--查詢
SELECT * FROM tab_view;
SELECT * FROM tab1;
SELECT * FROM tab2;

     

6)、建立觸發器，比較emp表中更新的工資

--建立觸發器
set serveroutput on;
CREATE OR REPLACE TRIGGER SAL_EMP
  BEFORE UPDATE ON EMP
  FOR EACH ROW
BEGIN
  IF :OLD.SAL > :NEW.SAL THEN
    DBMS_OUTPUT.PUT_LINE(‘工資減少‘);
  ELSIF :OLD.SAL < :NEW.SAL THEN
    DBMS_OUTPUT.PUT_LINE(‘工資增加‘);
  ELSE
    DBMS_OUTPUT.PUT_LINE(‘工資未作任何變動‘);
  END IF;
  DBMS_OUTPUT.PUT_LINE(‘更新前工資 ：‘ || :OLD.SAL);
  DBMS_OUTPUT.PUT_LINE(‘更新後工資 ：‘ || :NEW.SAL);
END;
/

--執行UPDATE查看效果
UPDATE emp SET sal = 3000 WHERE empno = ‘7788‘;

運行結果如下：

        

7)、建立觸發器，將操作CREATE、DROP儲存在log_info表

--建立表
CREATE TABLE log_info( 
   manager_user VARCHAR2(15), 
   manager_date VARCHAR2(15),
   manager_type VARCHAR2(15), 
   obj_name     VARCHAR2(15), 
   obj_type     VARCHAR2(15)
);

--建立觸發器
set serveroutput on;
CREATE OR REPLACE TRIGGER TRIG_LOG_INFO
  AFTER CREATE OR DROP ON SCHEMA
BEGIN
  INSERT INTO LOG_INFO
  VALUES
    (USER,
     SYSDATE,
     SYS.DICTIONARY_OBJ_NAME,
     SYS.DICTIONARY_OBJ_OWNER,
     SYS.DICTIONARY_OBJ_TYPE);
END;
/


--測試語句
CREATE TABLE a(id NUMBER);
CREATE TYPE aa AS OBJECT(id NUMBER);
DROP TABLE a;
DROP TYPE aa;

--查看效果
SELECT * FROM log_info;

      

--相關資料字典-----------------------------------------------------
SELECT * FROM USER_TRIGGERS;
--必須以DBA身份登陸才能使用此資料字典
SELECT * FROM ALL_TRIGGERS;SELECT * FROM DBA_TRIGGERS; 

--啟用和禁用
ALTER TRIGGER trigger_name DISABLE;
ALTER TRIGGER trigger_name ENABLE;

二十九、oracle 觸發器