VFP中用SPT訪問SQL Server資料庫

　　VFP因它簡單易學，可快速建立應用軟體而深受廣大程式員喜愛，但其資料庫系統不安全也令廣大使用者非常頭痛。隨著MS SQL Server資料庫系統的推廣應用，其強大的安全效能普遍受到好評。筆者在長期的編程實踐中，發現利用VFP的SQL pass-through(SPT)技術結合MS SQL Server資料庫系統，也能像VB、Delphi、PowerBuilder一樣輕鬆開發出優秀的客戶/伺服器(C/S)應用軟體。現通過編寫一個簡單的通訊錄例子和廣大VFP愛好者共同探討。
　　

　　一、伺服器端MS SQL Server資料庫設計

　　1. 在MS SQL Server中建立名為“SFXT”的資料庫。

　　2. 在SFXT資料庫中建立名為“通訊錄”的資料表，表結構如下：

　　列名（欄位名）　資料類型　　　長度
　　姓名 chr 8
　　生日 datetime 8
　　電話 chr 11
　　email chr 30
　　並將姓名設定為主鍵。

　　3. 在“SFXT”資料庫中建立查詢出所有記錄的預存程序。 SP_SearchAll

　　CREATE PROCEDURE [SP_SearchAll]
　　AS
　　select * from 通訊錄 order by 姓名
　　return

　　4. 在“SFXT”資料庫中建立插入新記錄的預存程序 SP_InsertData。
　　CREATE PROCEDURE [SP_InsertData]
　　@name [char] (10)，
　　@birthday [datetime] ，
　　@telephone [char] (11)，
　　@email [char] (30)
　　AS
　　insert into 通訊錄(姓名，生日，電話，email) values (@name，@birthday，@telephone，@email)
　　return

　　二、用戶端VFP的SQL pass-through技術設計

　　1. 建立如(^15020603b^)的VFP表單介面。

　　2. 建立名為“SFXT”的ODBC資料來源串連MS SQL Server中的SFXT資料庫。

　　可通過執行上面VFP表單的按鈕“建立OBDC資料來源”來完成；或者通過運行Windows控制台中的“OBDC資料來源”來完成。主要設定包括選擇SQL Server驅動程式，通訊協定，登入標識與密碼等。

　　“建立OBDC資料來源”按鈕.CLICK事件：

　　*函數說明SQLSTRINGCONNECT([cConnectString])

　　*省略連接字串cConnectString時顯示""SQL資料來源""對話方塊，可選擇或建立資料來源

　　sqlstringconnect()

　　3. 兩種串連MS SQL Server資料來源的方式。

 
　　使用現有資料來源名稱建立串連，“建立串連方式1”按鈕.CLICK事件。
　　public vodbc,vuser,vpwd,vconn
　　vodbc='sfxt'　　 &&串連SQL SERVER資料庫ODBC資料來源名稱
　　vuser='sa'　　　　　　　　　　 &&訪問SQL SERVER資料庫的登入使用者名稱，sa為系統使用者
　　vpwd='5213'　　　　 &&使用者登入密碼，為sa系統使用者佈建的密碼
　　vconn=SQLCONNECT(vodbc, vuser,vpwd)
　　if vconn>0
　　messagebox('串連成功！',,'ODBC資料來源')
　　else
　　messagebox('串連失敗！',,'ODBC資料來源')
　　endif
　　使用連接字串建立資料來源串連，“建立串連方式2”按鈕.CLICK事件。
　　public vconn
　　vconn=SQLSTRINGCONNECT('dsn=sfxt:uid=sa:pwd=5213')
　　if vconn>0
　　messagebox('串連成功！'，，'ODBC資料來源')
　　else
　　messagebox('串連失敗！'，，'ODBC資料來源')
　　endif

　　4. 資料來源串連的主要參數設定，“活動串連屬性設定”按鈕.CLICK事件。

　　* 註：用函數sqlgetprop()可返回設定的參數值
　　sqlsetprop(vconn，""asynchronous""，.f.) &&取假值時為結果集同步返回： 取真值時為非同步返回
　　sqlsetprop(vconn,""ConnectTimeOut"",15) &&連線逾時等待秒數設定，可取值0至600
　　sqlsetprop(vconn,""IdleTimeout"",0)　　　　　　&&空閑逾時間隔秒數，取值0為無限期逾時等待
　　sqlsetprop(vconn,""Transactions"",1)　　　　 &&取值1時為自動處理遠程事務：取值2時為手工處理

　　5. “執行預存程序查詢資料”按鈕.CLICK事件。

　　*函數說明SQLEXEC(nConnectionHandle, [cSQLCommand， [CursorName]])
　　*nConnectionHandle　　 當前資料來源活動串連控制代碼
　　*cSQLCommand　　執行SQL SERVER預存程序的SQL語句運算式
　　*CursorName　　　　返回執行結果暫存資料表的名稱
　　sqlexec(vconn,""execute SP_SearchAll"",""我的通訊錄"")
　　browse

　　6. “執行SQL語句查詢資料” 按鈕.CLICK事件。

　　*函數說明SQLEXEC(nConnectionHandle, [cSQLCommand, [CursorName]])
　　*nConnectionHandle　　 當前資料來源活動串連控制代碼
　　*cSQLCommand　　需發送SQL語句運算式
　　*CursorName　　　　返回執行結果暫存資料表的名稱
　　SQLEXEC(vconn, 'SELECT * FROM 通訊錄', '我的通訊錄')
　　browse

　　7. “向預存程序傳替參數插入新記錄” 按鈕.CLICK事件。

　　local vname,vbirthday,vtelephone,vemail,vsql
　　*隨機產生新記錄舉例
　　vname = '姓名'+sys(3)　　　　　　　　　　 &&姓名
　　vbirthday = dtoc(date()-int(rand()*10000))　　　　 &&生日
　　vtelephone = sys(3)　　　　　　　　　　　　 &&電話
　　vemail = sys(3)+'@hotmail.com'　　　　　　　　 &&電子郵箱
　　*將傳遞到預存程序的參數轉換成字串，並加引號形成SQL語句。
　　vsql=""execute SP_InsertData ""+""'""+vname+""','""+vbirthday+""','""+vtelephone+""','""+vemail+""'""
　　if sqlexec(vconn，vsql)>0　　　　 &&發送SQL語句
　　messagebox('插入新記錄成功！'，，'資訊')
　　else
　　messagebox('插入新記錄不成功！'，，'資訊')
　　endi
　　sqlexec(vconn，""execute SP_SearchAll""，""我的通訊錄"")
　　browse

　　8. “設定當前表的屬性修改資料” 按鈕.CLICK事件。
 
　　* 註：用函數cursorgetprop()可返回設定的參數值
　　cursorsetprop('BatchUpdateCount',100)　　 &&發送到緩衝表的遠端資料源的更新指令的數目
　　cursorsetprop('Buffering',3)　　　　 &&設定當前表為開放式行緩衝
　　cursorsetprop('FetchSize',-1)　　　　&&從遠端資料表中提取全部查詢記錄
　　cursorsetprop('KeyFieldList','姓名')　　　　&&指定遠端資料表的主關鍵字段
　　cursorsetprop('SendUpdates',.t.)　　　　 &&當前緩衝表更改內容時發送SQL語句更新遠端資料表
　　cursorsetprop('Tables','通訊錄')　　　　 &&指定串連的遠端資料表名
　　*本地緩衝表與遠端資料表欄位對應關係
　　cursorsetprop('UpdateNameList','姓名 通訊錄.姓名,生日 通訊錄.生日,電話 通訊錄.電話,email 通訊錄.email')
　　*指定可更新欄位列表
　　cursorsetprop('UpdatableFieldList','姓名,生日,電話,email')
　　cursorsetprop('UpdateType',1)　　　　 &&遠端資料表更新方式，替換方式
　　cursorsetprop('WhereType',3)　　　　&&更新SQL語句中where子句包含主關鍵字與被修改過的欄位
　　browse　　&&修改緩衝表資料，移動記錄指標後，自動發送SQL語句更新遠端資料表

　　9. “斷開指向資料來源的串連” 按鈕.CLICK事件。

　　sqldisconnect(vconn)

 
　　10.“關閉” 按鈕.CLICK事件。

　　thisform.release

　　以上我們利用VFP的SQL pass-through技術編寫了一個簡單的通訊錄管理程式，實現對SQL Server資料庫中資料的插入、查詢、修改等準系統，是一個典型的客戶/伺服器(C/S)結構的應用程式。希望對讀者今後開發軟體有所協助。