ASP製做行背景顏色交替變換的表格

來源:互聯網
上載者:User
<%
  Const adInteger = 3
  Const adVarChar = 200
  ' 聲明變數
  Dim myRecordset
  Dim iLetter
  Dim Field
  Dim strAltColor
  Dim bColor
  bColor = False
  
  ' 此例利用記憶體中的recordset,你需要做的只是修改你的資料顯示的部分就可以了。
  Set myRecordset = Server.CreateObject("ADODB.Recordset")
  myRecordset.Fields.Append "ID", adInteger
  myRecordset.Fields.Append "Title", adVarChar, 25
  myRecordset.Fields.Append "Description", adVarChar, 255
  
  myRecordset.Open
  
  ' Fill RS with sample data:
  For iLetter = Asc("A") To Asc("M")
   myRecordset.AddNew
   myRecordset.Fields("ID").Value = iLetter - 64
   myRecordset.Fields("Title").Value = "字母:" & Chr(iLetter)
   myRecordset.Fields("Description").Value = "這裡測試字母:" & Chr(iLetter) & "."
   myRecordset.Update
  Next 'iLetter
  
  '移動到頭部開始位置,以便下面的迴圈開始.
  myRecordset.MoveFirst
  
  
  ' 在表格中顯示資料
  
  Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & VBCrLf
  
  '表頭
  Response.Write vbTab & "<tr>" & vbCrLf
  For Each Field in myRecordset.Fields
   Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
   Response.Write Field.Name
   Response.Write "</strong></td>" & vbCrLf
  Next 'Field
  Response.Write vbTab & "</tr>" & vbCrLf
  
  Do While Not myRecordset.EOF
   ' 迴圈改變儲存格的背景顏色
   bColor = Not bColor
   If bColor Then
   strAltColor = "#FFFFFF"
   Else
   strAltColor = "#FF8040"
   End If
  
   '迴圈改變儲存格的背景顏色
   Response.Write vbTab & "<tr>" & vbCrLf
   For Each Field in myRecordset.Fields
   Response.Write vbTab & vbTab & "<td bgcolor="""
   Response.Write strAltColor
   Response.Write """>" & Field.Value & "</td>" & vbCrLf
   Next 'Field
   Response.Write vbTab & "</tr>" & vbCrLf
  
   myRecordset.MoveNext
  Loop
  
  ' End the table
  Response.Write "</table>" & vbCrLf
  
  ' 關閉對象、釋放資源
  myRecordset.Close
  Set myRecordset = Nothing



相關文章

Beyond APAC's No.1 Cloud

19.6% IaaS Market Share in Asia Pacific - Gartner IT Service report, 2018

Learn more >

Apsara Conference 2019

The Rise of Data Intelligence, September 25th - 27th, Hangzhou, China

Learn more >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。