GDI+ 在Delphi程式的應用 — 製作浮水印效果圖片

    利用GDI+可以很方便的製作帶浮水印效果的圖片，網上介紹這方面的文章也很多，但鮮有Delphi的，本文參照網上文章http://www.codeproject.com/KB/GDI-plus/watermark.aspx介紹的方法，用Delphi 2007製作浮水印片，原代碼如下：

unit Main;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Gdiplus, StdCtrls;

type
  TMainForm = class(TForm)
    Button1: TButton;
    procedure FormPaint(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    Photo: TGpImage;
    PhWidth: Integer;
    PhHeight: Integer;
    Watermark: TGpImage;
    WmWidth: Integer;
    WmHeight: Integer;
    Bmp: TGpBitmap;
  public
    { Public declarations }
  end;

var
  MainForm: TMainForm;

implementation

uses GdipTypes;

{$R *.dfm}

procedure TMainForm.Button1Click(Sender: TObject);
var
  Clsid: TGUID;
  Parameters: TEncoderParameters;
  Quality: Integer;
begin
  // 設定映像品質編碼參數
  Parameters.Count := 1;
  Parameters.Parameter[0].Guid := EncoderQuality;
  Parameters.Parameter[0].ValueType := EncoderParameterValueTypeLong;
  Parameters.Parameter[0].NumberOfValues := 1;
  // 設定參數的值：品質等級，最高為100，影像檔大小與品質成正比
  Quality := 100;
  Parameters.Parameter[0].Value := @Quality;

  if GetEncoderClsid('image/jpeg', Clsid) then
    Bmp.Save('WatermarkPhoto.jpg', Clsid, @Parameters);
end;

procedure TMainForm.FormCreate(Sender: TObject);
const
  ColorMatrix: TColorMatrix =
  (
    (1.0, 0.0, 0.0, 0.0, 0.0),
    (0.0, 1.0, 0.0, 0.0, 0.0),
    (0.0, 0.0, 1.0, 0.0, 0.0),
    (0.0, 0.0, 0.0, 0.3, 0.0),
    (0.0, 0.0, 0.0, 0.0, 1.0)
  );
  WorkingDirectory = '....Media';
  copyright = 'Copyright  2008 - Maozefa';
var
  gp: TGpGraphics;
  imageAttr: TGpImageAttributes;
  strFormat: TGpStringFormat;
  font: TGpFont;
  x, y: Single;
begin
  // 讀取原始圖片
  Photo := TGpImage.Create(WorkingDirectory + '100_0349.jpg');
  PhWidth := Photo.Width;
  PhHeight := Photo.Height;
  // 讀取浮水印圖片
  Watermark := TGpImage.Create(WorkingDirectory + 'Watermark.bmp');
  WmWidth := Watermark.Width;
  WmHeight := Watermark.Height;
  // 建立一個新的位元影像，解析度為72
  Bmp := TGpBitmap.Create(PhWidth, PhHeight, pf32bppArgb);
  Bmp.SetResolution(72, 72);
  // 建立新位元影像的畫布，並設定映像顯示品質和文本顯示品質
  gp := TGpGraphics.Create(Bmp);
  gp.SmoothingMode := smAntiAlias;
  gp.TextRenderingHint := thAntiAlias;
  // 在畫布上畫原始圖片
  gp.DrawImage(Photo, GpRect(0, 0, PhWidth, PhHeight),
               0, 0, PhWidth, PhHeight, utPixel);
  // 建立映像顯示輔助類
  imageAttr := TGpImageAttributes.Create;
  // 設定透明顏色為浮水印圖片四角的底色，浮水印圖顯示為圓角圖片
  imageAttr.SetColorKey($ff00ff00, $ff00ff00, ctBitmap);
  // 設定浮水印圖片不透明度為0.3
  imageAttr.SetColorMatrix(ColorMatrix, cfDefault, ctBitmap);
  // 在畫布左上方畫浮水印圖
  gp.DrawImage(Watermark, GpRect({PhWidth - WmWidth - }10, 10, WmWidth, WmHeight),
               0, 0, WmWidth, WmHeight, utPixel, imageAttr);
  // 設定文本字型和顯示格式
  font := TGpFont.Create('arial', 16, [fsBold]);
  strFormat := TGpStringFormat.Create;
  strFormat.Alignment := saCenter;
  // 在畫布下方置中顯示陰影文本
  x := PhWidth / 2;
  y := PhHeight - 26;
  gp.DrawString(copyright, font, Brushs[$99000000], x + 1, y + 1, strFormat);
  gp.DrawString(copyright, font, Brushs[$99ffffff], x, y, strFormat);

  font.Free;
  strFormat.Free;
  imageAttr.Free;
  gp.Free;
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  Photo.Free;
  Watermark.Free;
  Bmp.Free;
end;

procedure TMainForm.FormPaint(Sender: TObject);
var
  g: TGpGraphics;
begin
  g := TGpGraphics.Create(Canvas.Handle);
  // 顯示原始圖片
  g.DrawImage(Photo, 0, 0, PhWidth, PhHeight);
  // 顯示浮水印原始圖片
  g.TranslateTransform(0, PhHeight + 5);
  g.DrawImage(Watermark, 0, 0, WmWidth, WmHeight);
  // 顯示帶浮水印和文本的映像
  g.TranslateTransform(PhWidth, -(PhHeight + 5));
  g.DrawImage(Bmp, 0, 0, PhWidth, PhHeight);
  g.Free;
end;

end.

 

程式運行介面：

    代碼中已經進行了注釋，不再累敘，針對本文所參考的文章內容（Addr:http://www.codeproject.com/KB/GDI-plus/watermark.aspx），作幾點說明：

    1、在參考的文章中，對文本字型、顯示位置進行了測試和計算，本文為強調主要內容，對這些代碼進行了簡化；

    2、在浮水印底色透明處理中，原文採用的是TGpImageAttributes.SetRemapTable方法，而本文採用的則是TGpImageAttributes.SetColorKey方法，效果是一樣的，具體原理可參照我的文章《GDI+ 在Delphi程式的應用 -- 映像的透明顯示技巧》；

    3、因圖片儲存為jpeg格式檔案時，GDI+自動對映像進行壓縮，導致圖片效果較差，所以本文儲存圖片時設定了映像品質編碼參數；

    4、本文採用的GDI+單元介紹和見《GDI+ for VCL基礎 -- GDI+ 與 VCL》。

    如有錯誤或者指教，請來信：maozefa@hotmail.com

後記：有朋友用C++寫本文代碼，編譯時間出現LINK Error: unresolved external '_EncoderQuality' referenced ...錯誤，其原因是EncoderQuality是用DEFINE_GUID宏定義的GUID，而編譯器誤認為外部變數，所以出現連結錯誤。解決的辦法是：在#include <gdiplus.h>前添加#include <initguid.h>。(2008.5.16  12:48)