arm-linux-ld命令

標籤：

我們對每個c或者彙編檔案進行單獨編譯，但是不去串連，產生很多.o 的檔案，這些.o檔案首先是分散的，我們首先要考慮的如何組合起來；其次，這些.o檔案存在相互調用的關係；再者，我們最後產生的bin檔案是要在硬體中啟動並執行，每一部分放在什麼地址都要有仔細的說明。我覺得在寫makefile的時候，最為重要的就是ld的理解，下面說說我的經驗：

 

首先，要確定我們的程式用沒有用到標準的c庫，或者一些系統的庫檔案，這些一般是在作業系統之上開發要注意的問題，這裡並不多說，熟悉在Linux編程的人，基本上都會用ld命令；這裡，我們從頭開始,直接進行組合語言的串連。

 

我們寫一個組譯工具，控制GPIO，從而控制外接的LED，代碼如下;

 

   .text

.global _start

_start:

    LDR R0,=0x56000010 @GPBCON寄存器
    
    MOV R1,# 0x00000400
    str R1,[R0]
    
    LDR R0,=0x56000014
    MOV R1,#0x00000000
    
    STR R1,[R0]
    
    MAIN_LOOP:
            B MAIN_LOOP

 

代碼很簡單，就是一個對io口進行設定然後寫資料。我們看它是如何編譯的，注意我們這裡使用的不是arm-linux-gcc而是arm-elf-gcc，二者之間沒有什麼比較大的區別，arm-linux-gcc可能包含更多的庫檔案，在命令列的編譯上面是沒有區別。我們來看是如何編譯的：

       arm-elf-gcc -g -c -o led_On.o led_On.s  首先純編譯不串連

       arm-elf-ld  -Ttext 0x00000000 -g led_On.o -o led_on_elf

       用Ttext指明我們程式儲存的地方，這裡產生的是elf檔案，還不是我們真正的bin，但是可以藉助一些工具可以進行調試。然後：

       arm-elf-objcopy -O binary -S led_on_elf led_on.bin  

產生bin檔案。

 

-T選項是ld命令中比較重要的一個選項，可以用它直接指明代碼的程式碼片段、資料區段、博士生、

段，對於複雜的串連，可以專門寫一個指令碼來告訴編譯器如何串連。

 

    -Ttext   addr

    -Tdata  addr

    -Tbss     addr

 

arm-elf-ld  -Ttext 0x00000000 -g led_On.o -o led_on_elf  ，運行地址為0x00000000，由於沒有指明資料區段和bss，他們會預設的依次放在後面。相同的代碼 不同的Ttext，你可以對比一下他們之間會變的差異，ld會自動調整跳轉的地址。

 

第二個概念：section，section可以理解成一塊，例如像c裡面的一個子函數，就是一個section，連結器ld把object檔案中的每個section都作為一個整體，為其分配啟動並執行地址(memory layout)，這個過程就是重定位(relocation)；最後把所有目標檔案合并為一個目標檔案。

 

連結通過一個linker script來控制，這個指令碼描述了輸入檔案的sections到輸出檔案的映射，以及輸出檔案的memory layout。

因此，linker總會使用一個linker script，如果不特別指定，則使用預設的script；可以使用‘-T’命令列選項來指定一個linker script。

 

 

＊映像檔案的輸入段與輸出段

linker把多個輸入檔案合并為一個輸出檔案。輸出檔案和輸入檔案都是目標檔案(object file)，輸出檔案通常被稱為可執行檔(executable)。

每個目標檔案都有一系列section，輸入檔案的section稱為input section，輸出檔案的section則稱為output section。

一 個section可以是loadable的，即輸出檔案運行時需要將這樣的section載入到memory(類似於RO&RW段)；也可以是 allocatable的，這樣的section沒有任何內容，某些時候用0對相應的memory地區進行初始化(類似於ZI段)；如果一個 section既非loadable也非allocatable，則它通常包含的是調試資訊。

每個loadable或 allocatable的output section都有兩個地址，一是VMA(virtual memory address)，是該section的運行時域地址；二是LMA(load memory address)，是該section的載入時域地址。

可以通過objdump工具附加‘-h‘選項來查看目標檔案中的sections。

 

＊簡單的Linker script

(1) SECTIONS命令：

The SECTIONS command tells the linker how to map input sections into output sections, and how to place the output sections in memory.

命令格式如下：

SECTIONS

{

sections-command

sections-command

......

}

其中sections-command可以是ENTRY命令，符號賦值，輸出段描述，也可以是overlay描述。

(2) 地址計數器‘.’(location counter)：

該符號只能用於SECTIONS命令內部，初始值為‘0’，可以對該符號進行賦值，也可以使用該符號進行計算或賦值給其他符號。它會自動根據SECTIONS命令內部所描述的輸出段的大小來計算當前的地址。

(3) 輸出段描述(output section description)：

前面提到在SECTIONS命令中可以作輸出段描述，描述的格式如下：

section [address] [(type)] : [AT(lma)]

{

output-section-command

output-section-command

...

} [>region] [AT>lma_region] [:phdr :phdr ...] [=fillexp]

很多附加選項是用不到的。其中的output-section-command又可以是符號賦值，輸入段描述，要直接包含的資料值，或者某一特定的輸出段關鍵字。

 

＊linker script 執行個體

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

OUTPUT_ARCH(arm)

ENTRY(_start)

SECTIONS {

    . = 0xa3f00000;

    __boot_start = .;

    .start ALIGN(4) : {

        *(.text.start)

    }

    .setup ALIGN(4) : {

        setup_block = .;

        *(.setup)

        setup_block_end = .;

    }

    .text ALIGN(4) : {

        *(.text)

    }

    .rodata ALIGN(4) : {

        *(.rodata)

    }

    .data ALIGN(4) : {

        *(.data)

    }

    .got ALIGN(4) : {

        *(.got)

    }

    __boot_end = .;

    .bss ALIGN(16) : {

        bss_start = .;

        *(.bss)

        *(COMMON)

        bss_end = .;

    }

    .comment ALIGN(16) : {

        *(.comment)

    }

    stack_point = __boot_start + 0x00100000;

    loader_size = __boot_end - __boot_start;

    setup_size = setup_block_end - setup_block;

}

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝  

在SECTIONS命令中的類似於下面的描述結構就是輸出段描述：

.start ALIGN(4) : {

    *(.text.start)

}

.start 為output section name，ALIGN(4)返回一個基於location counter(.)的4位元組對齊的地址值。*(.text.start)是輸入段描述，*為萬用字元，意思是把所有被連結的object檔案中 的.text.start段都連結進這個名為.start的輸出段。

源檔案中所標識的section及其屬性實際上就是對輸入段的描述，例如.text.start輸入段在源檔案start.S中的代碼如下：

.section .text.start

.global _start

_start :

    b start

 

 

arm-elf-ld -Ttimer.lds -o timer_elf header .o

這裡就必須存在一個timer.lds的檔案。

 

對於.lds檔案，它定義了整個程式編譯之後的串連過程，決定了一個可執行程式的各個段的儲存位置。雖然現在我還沒怎麼用它，但感覺還是挺重要的，有必要瞭解一下。

先看一下GNU官方網站上對.lds檔案形式的完整描述：

 

SECTIONS {
...
secname start BLOCK(align) (NOLOAD) : AT ( ldadr )
  { contents } >region :phdr =fill
...
}

 

secname和contents是必須的，其他的都是可選的。下面挑幾個常用的看看：

1、secname：段名

2、contents：決定哪些內容放在本段，可以是整個目標檔案，也可以是目標檔案中的某段（程式碼片段、資料區段等）

3、start：本段串連（運行）的地址，如果沒有使用AT（ldadr），本段儲存的地址也是start。GNU網站上說start可以用任意一種描述地址的符號來描述。

4、AT（ldadr）：定義本段儲存（載入）的地址。

 

/* nand.lds */
SECTIONS { 
firtst 0x00000000 : { head.o init.o } 
second 0x30000000 : AT(4096) { main.o } 
}

 

    以上，head.o放在0x00000000地址開始處，init.o放在head.o後面，他們的運行地址也是0x00000000，即串連和儲存地址相同（沒有AT指定）；main.o放在4096（0x1000，是AT指定的，儲存地址）開始處，但是它的運行地址在0x30000000，運行之前需要從0x1000（載入處）複製到0x30000000（運行處），此過程也就用到了讀取Nand flash。

 

這就是儲存地址和串連（運行）地址的不同，稱為載入時域和運行時域，可以在.lds串連指令檔中分別指定。

編寫好的.lds檔案，在用arm-linux-ld串連命令時帶-Tfilename來調用執行，如
arm-linux-ld –Tnand.lds x.o y.o –o xy.o。也用-Ttext參數直接指定串連地址，如
arm-linux-ld –Ttext 0x30000000 x.o y.o –o xy.o。

 

既然程式有了兩種地址，就涉及到一些跳轉指令的區別，這裡正好寫下來，以後萬一忘記了也可查看，以前不少東西沒記下來現在忘得差不多了。

ARM彙編中，常有兩種跳轉方法：b跳轉指令、ldr指令向PC賦值。

我自己經過歸納如下：

 

b step1 ：b跳轉指令是相對跳轉，依賴當前PC的值，位移量是通過該指令本身的bit[23:0]算出來的，這使得使用b指令的程式不依賴於要跳到的代碼的位置，只看指令本身。

 

ldr pc, =step1 ：該指令是從記憶體中的某個位置（step1）讀出資料並賦給PC，同樣依賴當前PC的值，但是位移量是那個位置（step1）的串連地址（運行時的地址），所以可以用它實現從Flash到RAM的程式跳轉。

 

此外，有必要回味一下adr偽指令，U-boot中那段relocate代碼就是通過adr實現當前程式是在RAM中還是flash中。仍然用我當時的注釋

 

  adr r0, _start /* r0是代碼的當前位置 */ 
/* adr偽指令，彙編器自動通過當前PC的值算出 如果執行到_start時PC的值，放到r0中：
當此段在flash中執行時r0 = _start = 0；當此段在RAM中執行時_start = _TEXT_BASE(在board/smdk2410/config.mk中指定的值為0x33F80000，即u-boot在把代碼拷貝到RAM中去執行的程式碼片段的開始) */

 

  ldr r1, _TEXT_BASE /* 測試判斷是從Flash啟動，還是RAM */ 
/* 此句執行的結果r1始終是0x33FF80000，因為此值是又編譯器指定的(ads中設定，或-D設定編譯器參數) */
    cmp r0, r1 /* 比較r0和r1，調試的時候不要執行重定位 */

 

   下面，結合u-boot.lds看看一個正式的串連指令檔。這個檔案的準系統還能看明白，雖然上面分析了好多，但其中那些GNU風格的符號還是著實讓我感到迷惑。

 

OUTPUT_FORMAT("elf32­littlearm", "elf32­littlearm", "elf32­littlearm")
  ;指定輸出可執行檔是elf格式,32位ARM指令,小端
OUTPUT_ARCH(arm)
  ;指定輸出可執行檔的平台為ARM
ENTRY(_start)
  ;指定輸出可執行檔的起始程式碼段為_start.
SECTIONS
{
        . = 0x00000000 ; 從0x0位置開始
        . = ALIGN(4) ; 代碼以4位元組對齊
        .text : ;指定程式碼片段
        {
          cpu/arm920t/start.o (.text) ; 代碼的第一個代碼部分
          *(.text) ;其它代碼部分
        }
        . = ALIGN(4) 
        .rodata : { *(.rodata) } ;指定唯讀資料區段
        . = ALIGN(4);
        .data : { *(.data) } ;指定讀/寫資料區段
        . = ALIGN(4);
        .got : { *(.got) } ;指定got段, got段式是uboot自訂的一個段, 非標準段
        __u_boot_cmd_start = . ;把__u_boot_cmd_start賦值為當前位置, 即起始位置
        .u_boot_cmd : { *(.u_boot_cmd) } ;指定u_boot_cmd段, uboot把所有的uboot命令放在該段.
        __u_boot_cmd_end = .;把__u_boot_cmd_end賦值為當前位置,即結束位置
        . = ALIGN(4);
        __bss_start = .; 把__bss_start賦值為當前位置,即bss段的開始位置
        .bss : { *(.bss) }; 指定bss段
        _end = .; 把_end賦值為當前位置,即bss段的結束位置
}

 

 

轉載

arm-linux-ld命令