ASP 類成員變數、成員函數、構造解構函式

class CFoo
    dim publicParam '用 dim 申明公有成員變數
    private privateParam '用 private 申明私人成員變數
    'publicParam = "公有" '不能在 class 標記以內、類函數以外為成員變數賦值
    'const MAX_LEN = 5 '不能在 class 標記以內、類函數以外使用 const
   
    '該函數為建構函式，在使用 set new 建立對象時，自動執行
    private sub class_initialize()
        publicParam = "公有" '可以在這裡為成員變數賦值
        privateParam = "私人"
    end sub
   
    '該函數為解構函式，在使用 set nothing 釋放對象時，自動執行
    private sub class_terminate()
        response.Write "釋放對象"
    end sub
   
    '公有成員函數（過程）
    '成員函數（過程）不需要也不能申明
    sub PrintParam(index)
        if index = 1 then
            call PrintPublicParam()
        elseif index = 2 then
            call PrintPrivateParam()
        end if
    end sub
   
    '私人成員函數（過程）
    '只是比公有成員函數（過程）多一個 private
    private sub PrintPublicParam()
        response.Write publicParam
    end sub
   
    private sub PrintPrivateParam()
        response.Write privateParam
    end sub
end class

dim obj
set obj = new CFoo '自動調用 class_initialize 函數，為 publicParam、privateParam 賦值
obj.publicParam = "新的公有"
obj.privateParam = "新的私人" '將發生錯誤，因為 privateParam 是私人變數
call obj.PrintParam(1) '顯示 publicParam 的值
call obj.PrintPublicParam() '將發生錯誤，因為 PrintPublicParam 是私人函數
set obj = nothing '自動調用 class_terminate 函數，顯示“釋放對象”