ASP的高效率的分頁演算法

一般習慣使用的有兩種分頁演算法，一是傳統的ADO分頁，二是SELECT TOP分頁演算法。對於小型資料表，比如一兩萬的資料量的表，我傾向使用ADO演算法，對於大型的資料表，則必須採用後者的演算法了。

    先來說說傳統的ADO分頁演算法。

    這種演算法，使用起來簡單容易，很容易上手，對於小心資料庫來說是首選，其執行效率很高，資料庫內建的遊標功能進行翻頁的時候也很方便。

    其通常使用的代碼如下：
<%
dim recordcountnum,page,i,j
listnum = "30"  '每頁顯示記錄數
sql="select id,title,time from table1 order by time desc"
Set rs = Server.CreateObject ("ADODB.Recordset")
rs.Open sql,conn,1,1
If rs.eof and rs.bof Then
Else
recordcountnum=Rs.recordcount
Rs.pagesize = listnum 
page = Request("page")
If  page = "" or page < 1 Then
page=1
End If
If (page-Rs.pagecount) > 0 Then
page=Rs.pagecount
End If
Rs.absolutepage=page
j=rs.recordcount
j=j-(page-1)*listnum
i=0
Do While Not rs.Eof and i<listnum
response.write "每條記錄資訊："&rs("id")&"<br>"
i=i+1
rs.movenext
loop
''翻頁代碼略……
%>

    這種ADO遊標的分頁演算法，由於每次載入頁面都要重新讀取資料表的全部資料，雖然遊標的使用非常簡單，當資料表容量不大的情況下，也是可以使用的；但當資料量非常大的情況下，使用這種分頁方法的效率無疑是極低的。

     所以，我們需要引入另外一種高效的SELECT TOP分頁演算法。代碼如下：

<%
'每頁的記錄數
dim pagesize
pagesize= "30"

'讀出總記錄數,總頁數,作者注
Dim TotalRecords,TotalPages
SQLstr="Select count(id) As RecordSum From table1"
Set Rs=conn.Execute(SQLstr,0,1)
TotalRecords=Rs("RecordSum")
if Int(TotalRecords/pagesize)=TotalRecords/pagesize then
TotalPages=TotalRecords/pagesize
else
TotalPages=Int(TotalRecords/pagesize)+1
end if
Rs.Close
Set Rs=Nothing

'當前頁碼,作者注
dim page
page=Request("page")
if isnumeric(page)=false then
response.write "<SCRIPT language=JavaScript>alert('參數錯誤！');"
response.write "window.close();</SCRIPT>"
response.end
end if
If page="" or page<1 Then page=1
If page-TotalPages>0 Then page=TotalPages
page=int(page)

if page=1 then
sql="select top "&pagesize&" id,title,time from table1 order by time desc"
else
sql="select top "&pagesize&" id,title,time from table1 where time<(SELECT Min(time) FROM (SELECT TOP "&pagesize*(page-1)&" time FROM table1 ORDER BY time desc) AS T) order by time desc"
end if
Set rs = Server.CreateObject ("ADODB.Recordset")
rs.Open sql,conn,1,1
Do While Not rs.Eof
response.write "每條記錄資訊："&rs("id")&"<br>"
rs.movenext
loop
rs.close
set rs=nothing
''翻頁代碼省略……
%>

    這是一種非常高效的分頁演算法。當資料表中的資料量成百上千萬的時候，上面的這種分頁演算法的回應時間是非常短的，通常在幾十毫秒之內。原理很簡單，就是每次分頁，我只取需要的幾十條記錄而已，使用SELECT TOP也正是基於這樣的考慮。

    上面的兩個分頁演算法的例子中，flymorn都使用了時間欄位time來進行order by排序，因為在我接觸的絕大多數系統中，我們都需要把使用者最新動向（包括新添加的記錄以及新修改過的老記錄）的內容展示在前面，如果僅僅使用自動編號的ID作為排序欄位的話，使用者編輯過的老資訊將無法展示在前面。這就是flymorn使用時間欄位的原因了。

    這裡又涉及到彙總索引的問題了。預設情況下，我們是以自動編號ID作為主鍵，並且用作彙總索引列，如果上面的演算法中，使用這樣的ID列來排序的話，效率會更高，資料庫響應的時間會更少；然而，我提到了最新動向的內容需要展示在前面的問題，所以，我們必須使用時間欄位來排序。因此，為了更高的分頁效率，我們可以在資料庫設計的時候，把這個時間欄位設計為彙總索引列。

    通過這樣的設計後，整個分頁效率就會得到非常高的提高了。

    然而，把這個時間欄位作為彙總索引列，存在又一個小問題。因為資料表在排列資料的時候，是按照彙總索引列來進行物理排序的，當使用者添加資料的時候，沒有什麼問題，在資料表的末尾添加就行了；當使用者編輯資訊的時候，資料庫需要根據這個彙總索引列，把剛編輯過的資訊也提到表的末尾，這裡就需要耗費一定的時間了。就是說，當我們以時間欄位為彙總索引列的時候，我們就需要在 UPDATE 資料的時候多耗費一點的時間。

    然而，綜合比較而言，作者認為，SELECT TOP的高效分頁演算法的關鍵是要避免全表掃描，盡量只擷取需要的欄位，排序的欄位最好是彙總索引列，實踐表明，以彙總索引列來排序的SQL語句的回應時間是最快的。這樣處理之後，對於SQL SERVER資料庫來說，即使上千萬的資料量，也不用怕分頁演算法失去響應了。

    上面是以 ASP 語言為例寫的演算法，當然同樣可以改造成其他的如ASP.NET，PHP語言所使用。為了更好的使用這樣的分頁代碼，大家也可以把上面的演算法改寫成預存程序。