所謂緩衝其實就是在記憶體中開闢一個用來儲存資料的空間，使用緩衝你就不用頻繁的訪問你儲存在硬碟上的資料了，因為這些資料我們希望每個使用者都能看到效果一 樣,考慮使用的是application對象,因為它是所有訪問者的共用的對象,儲存的資訊和定義的事件能夠為所有者訪問者使用,這裡要使用asp內建對 象APPLICATION了,關於application,有2個方法[lock和unlock],2個集合[content和 staticobjects],2個事件[開始的application_onstart和application_end],application變 量不會因為使用者的離開而消失,一旦建立,一直等到網站關閉和程式卸載為止,正因為如此,使用的時候要特別小心!,否則會佔用記憶體,我在這裡不用多說,有興 趣的查閱相關資料吧,大體是這樣.我們是把資料寫入一個自訂的application裡面,在制定的時間讀取重新整理的,大體思路就是這樣.
執行個體示範.先建立一個簡單的資料庫,寫個function讀取一下,寫入一個dim變數temp中:
以下是引用片段：
複製代碼 代碼如下:
Function DisplayRecords()
'這個函數原來給一個變數temp付上記錄的值
Dim sql, conn, rs
'合格sql語句
sql = "SELECT id, [szd_f], [szd_t] FROM admin"
'開啟資料庫連接
Set conn = Server.CreateObject("ADODB.Connection")
conn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ="&Server.MapPath("db.mdb")
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open sql, conn, 1, 3
'當符合sq語句l的資料沒有顯示完畢時
If Not rs.EOF Then
'給temp變數賦值
Dim temp
temp = "<table width=""90%"" align=""center"""
temp = temp & " border=""1"" bordercolor=""silver"""
temp = temp & " cellspacing=""2"" cellpadding=""0"">"
temp = temp & "<tr bgcolor=""#CCDDEE""><td width=""5%"""
temp = temp & ">ID</td><td>操作</td>"
temp = temp & "<td>數值</td></tr>"
While Not rs.EOF
temp = temp & "<tr><td bgcolor=""#CCDDEE"">"
temp = temp & rs("ID") & "</td><td>" & rs("szd_f")
temp = temp & "</td><td>" & rs("szd_t")
temp = temp & "</td></tr>"
rs.MoveNext
Wend
temp = temp & "</table>"
'temp賦值完畢,把它再返回給函數
DisplayRecords = temp
Else
DisplayRecords = "Data Not Available."
End If
'釋放記憶體
rs.Close
conn.Close
Set rs = Nothing
Set conn = Nothing
End Function
ok,上面的函數改造完畢,調用的時候就是DisplayRecords.
下面是application大顯身手了:
複製代碼 代碼如下:
'該函數是寫入緩衝
Function DisplayCachedRecords(Secs)
Dim retVal, datVal, temp1
'Secs是每次要重新整理資料的時間, retVal是資料,datVal是剩餘時間
retVal = Application("cache_demo") '取得appliction的值
datVal = Application("cache_demo_date") '取得appliction的值
'判斷datVal 的值,也就是要計算時間過去了沒
If datVal = "" Then
'如果是空,datVal值為目前時間按秒加上secs定義的時間
datVal = DateAdd("s",Secs,Now)
End If
'temp1是判斷目前時間和datVal的秒差
temp1 = DateDiff("s", Now, datVal)
'如果retVal已經是上面函數的傳回值且時間大於0
If temp1 > 0 And retVal <> "" Then
'本函數返回記錄數
DisplayCachedRecords = retVal
Response.Write "<b><font color=""green"">利用緩衝讀取資料"
Response.Write " ... (" & temp1 & " 秒剩餘)</font></b>"
Response.Write "<br><br>"
Else
'retVal 是空的話,就賦予DisplayRecords的值給變數temp2
Dim temp2
temp2 = DisplayRecords()
'儲存到Application.------------------>重點
Application.Lock
Application("cache_demo") = temp2
Application("cache_demo_date") = DateAdd("s",Secs,Now)
Application.UnLock
DisplayCachedRecords = temp2
' 這裡隨便寫上了記錄的緩衝的過去時間,相對總秒數倒差 :
Response.Write "<b><font color=""red"">重新整理緩衝顯示 ..."
Response.Write "</font></b><br><br>"
End If
End Function
%>
說明完畢.
以下為完整無注釋代碼
調用方法:<%=DisplayCachedRecords(20)%>
寫在後面的話:如果你感覺你的伺服器記憶體不夠大的話,不要大量使用緩衝.
