Asp深度揭密（上）

一、Asp基本知識

1．Asp是Active Server Pages的簡稱，是解釋型的指令碼語言環境；
2．Asp的運行需要Windows作業系統，9x下需要安裝PWS；而NT/2000/XP則需要安裝Internet Information Server（簡稱IIS）；
3．Asp和JSP的指令碼標籤是“<%%>”，PHP的則可以設定為多種；
4．Asp的注釋符號是“'”；
5.使用附加組件，可以擴充Asp的功能。

例子：

HelloWorld_1.asp
<%="Hello,world"%>

效果：
Hello,world

HelloWorld_2.asp
<%
for i=1 to 10
response.write "Hello,world"
next
%>

效果：
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world

注意：Asp不區分大小寫；變數無需定義也可使用，轉換方便；語法檢查很松。

二、Asp內建對象的使用：

可以使用下面的任何ASP內建對象，而不必在ASP指令碼中特別聲明。

1． Request：

定義：可用來訪問從瀏覽器發送到伺服器的請求資訊，可用此對象讀取已輸入HTML表單的資訊。

集：
Cookies：含有瀏覽器cookies的值
Form：含有HTML表單域中的值
QueryString：含有查詢字串的值
ServerVariables：含有頭和環境變數中的值

例子：

request_url.asp
<%
'擷取使用者輸入，並存入變數
user_id=request.querystring("user_id")
user_name=request.querystring("user_name")

'判斷使用者輸入是否正確
if user_id="" then
response.write "User_id is null,please check it"
response.end
end if
if user_name="" then
response.write "User_name is null,please check it"
response.end
end if

'列印變數
response.write user_id&"<br>"
response.write user_name
%>

效果：
當訪問http://10.1.43.238/course/request_url.asp?user_name=j時：
User_id is null,please check it
當訪問http://10.1.43.238/course/request_url.asp?user_name=j&user_id=my_id時：
my_id
j

思考：變數是如何在URL中傳遞和被Asp頁面擷取的？

request_form.htm
<style type="text/css">
<!--
.input {background-color: #FFFFFF; border-bottom: black 1px solid;border-left: black 1px solid; border-right: black 1px solid;border-top: black 1px solid; color: #000000;font-family: Georgia; font-size: 9pt;color: midnightblue;}
a:link {color: #1B629C; text-decoration: none}
a:hover {color: #FF6600; text-decoration: underline}
a:visited {text-decoration: none}
-->
</style>

<center>
<form name="course" action="request_form.asp" method="post">
User_id：<input type="text" name="user_id" maxlength="20" class="input"><br><br>
User_name：<input type="text" name="user_name" maxlength="30" class="input">
</form>
<br><br>
<a href="javascript:document.course.submit();"> 提 交 </a>
</center>

request_form.asp
<%
'擷取使用者輸入，並存入變數
user_id=request.form("user_id")
user_name=request.form("user_name")

'判斷使用者輸入是否正確
if user_id="" then
response.write "User_id is null,please check it"
response.end
end if
if user_name="" then
response.write "User_name is null,please check it"
response.end
end if

'列印變數
response.write user_id&"<br>"
response.write user_name
%>

注意：form的action的指向，request_form.asp和request_url.asp在原始碼上的區別？

2． Response：

定義：用來向瀏覽器回傳資訊，可用此對象從指令碼向瀏覽器發送輸出。

集：
Cookies：在瀏覽器中加入一個cookie

方法：
End：結束指令碼的處理
Redirect：將瀏覽器引導至新頁面
Write：向瀏覽器發送一個字串

屬性：
Buffer：緩衝一個ASP
CacheControl：由Proxy 伺服器控制緩衝
ContentType： 規定響應的內容類型
Expires：瀏覽器用相對時間控制緩衝
ExpiresAbsolute：瀏覽器用絕對時間控制緩衝

例子：

response_redirect.asp
<%
'去google看看吧
response.redirect "http://www2.google.com";
response.end
%>

response_cookies.asp
<%
'設定和讀取cookies
response.cookies("time_now")=now()
response.write request.cookies("time_now")
%>

效果：
當訪問http://10.1.43.238/course/response_cookies.asp時：
2002-9-1 16:20:40

response_buffer.asp
<%'response.buffer=true%>
<a href="a">a</a>
<%response.redirect "request_form.htm"%>

效果：
①．當關閉IIS的緩衝功能，訪問該頁面時出錯
a 
回覆對象 錯誤 'ASP 0156 : 80004005' 
頭錯 
/course/response_buffer.asp，行3 
HTTP 頭已經寫入到 客戶瀏覽器。任何 HTTP 頭的修改必須在寫入頁內容之前。 
②．當關閉IIS的緩衝功能，去掉檔案第一行的注釋，則頁面重新導向成功
③．當開啟IIS的緩衝功能，無論是否去掉檔案第一行的注釋，頁面重新導向都成功

3． Server

定義：可在伺服器上使用不同實體函數，如在時間到達前控制指令碼執行的時間。還可用來建立其他對象。

方法：
CreateObject：建立一個對象執行個體
HTMLEncode：將字串轉化為使用特別的HTML字元
MapPath：把虛擬路徑轉化成實體路徑
URLEncode：把字串轉化成URL編碼的
ScriptTimeout：在終止前，一個指令碼允許啟動並執行秒數

例子：

server_htmlencode.asp
<%
'html encode
response.write server.htmlencode("a""time_now")
%>

效果：
a"time_now
查看源檔案時顯示為：a"time_now

思考：為什麼不是a""time_now這種效果？源檔案是怎麼了？

server_mappath.asp
<%
'mappath
response.write server.mappath("server_mappath.asp")
%>

效果：
G:\asp_www\test\course\server_mappath.asp

思考：如何擷取網站根目錄的實際路徑？如何擷取某個目錄的實際路徑？

server_urlencode.asp
<%
'url encode
response.write server.urlencode("a\time_now")
%>

效果：
a%5Ctime%5Fnow

4． Application

定義：用來儲存、讀取使用者共用的應用程式資訊，如可以用此對象在網站的使用者間傳送資訊，當伺服器重啟後資訊丟失。

方法：
Lock：防止其它使用者訪問Application集
Unlock：使其它使用者可以訪問Application集

事件：
OnEnd：由終止網路伺服器、改變Global.asa檔案觸發
OnStart：由應用程式中對網頁的第一次申請觸發

例子：

application_counter.asp
<%
'一個使用Application製作的簡單計數器
Application.lock
Application("clicks")=Application("clicks") 1
Application.unlock

response.write "您是本站第 "&Application("clicks")&" 位訪客！"
response.write "<br><br>您來自 "&request.servervariables("remote_addr")
%>

效果：
您是本站第 1 位訪客！

您來自 10.1.43.238

思考：本例中lock和unlock有何作用？

5． Session

定義：儲存、讀取特定使用者對話資訊，如可儲存使用者對網站的訪問資訊，當伺服器重啟後資訊丟失。

方法：
Abandon：處理完當前頁面後，結束一個使用者會話

屬性：
Timeout：使用者會話期間（分鐘數）

事件：
OnEnd：在Session Timeout時間以外，使用者不再申請頁面觸發該事件
OnStart：由使用者對網頁的第一次申請時觸發

例子：

session_counter.asp
<%
'一個使用Session製作的簡單計數器
session("clicks")=session("clicks") 1

response.write "您是本站第 "&session("clicks")&" 位訪客！"
response.write "<br><br>您來自 "&request.servervariables("remote_addr")
%>

效果：
您是本站第 1 位訪客！

您來自 10.1.43.238

思考：既然session和application都能做到計數，那它們之間有什麼區別？如果要做到滿100重新開始計數如何?？

三、使用Asp操作資料庫：

1．通過ODBC或者OLE方式串連的區別？

現在有兩種串連資料庫的方法。一方面，可以用ODBC產生一個串連，這種串連與任何有ODBC磁碟機的資料庫（即基本上是市場上所有的資料庫）相容；另一方面，可以用原始OLE DB供應商產生一個串連。

該用哪個供應商？儘可能用原始OLE DB供應商，因為它提供了對資料更有效訪問。Microsoft正逐步用OLE DB取代ODBC標準，應該僅僅在沒有原始OLE DB供應商時使用ODBC。

⑴．用ODBC方式串連SQL Server：
①．配置ODBC
②．串連代碼：
conn_odbc.asp
<%
Set Conn = Server.CreateObject("ADODB.Connection")
'Conn.Open "DSN=course_dsn;UID=course_user;PWD=course_password;DATABASE=course"
Conn.Open "course_dsn","course_user","course_password"
%>
注意：在配置MyDSN時若指定預設資料庫為course則上述代碼作用想同，否則第二行的串連方式更有靈活性，可以指定串連某個資料庫（當然，前提是course_user對這個資料庫有操作許可權）。

⑵．用OLE方式串連SQL Server：
conn_ole.asp
<%
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "PROVIDER=SQLOLEDB;DATA SOURCE=10.1.43.238,2433; UID=course_user;PWD=course_password;DATABASE=course"
%>

2．操作資料庫：Connection和Recordset

聯合使用connection和recordset操作資料庫，或者只使用connection操作資料庫。

例子：

⑴．聯合使用connection和recordset操作資料庫

use_db_1.asp
<%
Set conn=Server.CreateObject("ADODB.Connection") '建立串連資料庫的對象
conn.Open "course_dsn","course_user","course_password" '使用該對象串連資料庫
Set rs=Server.CreateObject("ADODB.RecordSet") '建立記錄集對象
rs.Open "select * from user_info",conn,1,1 '使用記錄集對象開啟資料庫
if rs.recordcount>0 then '如果有記錄
response.write "User_id User_name<br>"
for i=1 to rs.recordcount '迴圈讀取所有紀錄
response.write rs("id")&" "&rs("user_name")&"<br>"
'向瀏覽器輸出紀錄的欄位
rs.movenext '指標下移一行
if rs.eof then exit for '如果到達記錄集底部則退出迴圈
next
end if
%>

效果：
User_id User_name
1 ahyi
3 test

⑵．只使用connection操作資料庫：

use_db_2.asp
<%
Set conn=Server.CreateObject("ADODB.Connection") '建立串連資料庫的對象
conn.Open "course_dsn","course_user","course_password" '使用該對象串連資料庫
conn.execute "delete from user_info"
%>

效果：
user_info表中所有資料被刪除

思考：兩種方式瀉頹穡扛饔τ糜謔裁闖『希?/P>

3．如何使用交易處理、預存程序和視圖？

⑴．使用預存程序

①．定義好預存程序

CREATE PROCEDURE [output_1]
@sid int output
AS
set @sid=2

CREATE PROCEDURE [return_1]
(@user_name varchar(40),@password varchar(20))
AS
if exists(select id from user_info where user_name=@user_name and password=@password)
return 1
else
return 0

CREATE PROCEDURE [user_info_1]
(@user_name varchar(40),@password varchar(20))
AS
select id from user_info where user_name=@user_name and password=@password

CREATE PROCEDURE [user_info_2]
(@user_name varchar(40),@password varchar(20))
AS
SET XACT_ABORT ON
BEGIN TRANSACTION
delete from user_info where user_name=@user_name and password=@password
COMMIT TRANSACTION
SET XACT_ABORT OFF

CREATE PROCEDURE [user_info_3] AS
select * from user_info

②．在Asp中調用

use_proc.asp
<!-- #include virtual="/adovbs.inc" -->
<%
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"

'使用recordset調用帶兩個輸入參數和返回紀錄集的預存程序
'CREATE PROCEDURE [user_info_1]
'(@user_name varchar(40),@password varchar(20))
'AS
'select id from user_info where user_name=@user_name and password=@password
response.write "普通的調用方法：<br>"
set rs=server.createobject("adodb.recordset")
sql="user_info_1 '"&request.querystring("user_name")&"','"&request.querystring("password")&"'"
rs.open sql,conn,1,1
response.write rs("id")&"<br>"
rs.close

'使用recordset調用無輸入參數，返回紀錄集的預存程序，可以使用recordcount等屬性
'CREATE PROCEDURE [user_info_3] AS
'select * from user_info
response.write "<br>返回紀錄集，可以使用recordcount等屬性："
sql="exec user_info_3"
rs.open sql,conn,1,1
for i=1 to rs.recordcount
response.write "<br>"&rs("user_name")
rs.movenext
next
rs.close
set rs=nothing

'使用command調用帶輸出參數的預存程序
'CREATE PROCEDURE [output_1]
'@sid int output
'AS
'set @sid=2
response.write "<br><br>調用帶輸出參數的預存程序：<br>"
set cmd=server.createobject("adodb.command")
cmd.activeconnection=conn
cmd.commandtext = "output_1"
cmd.parameters.append cmd.createparameter("@sid",adinteger,adparamoutput)
cmd("@sid")=10
cmd.execute()
bbb=cmd("@sid")
response.write bbb&"<br>"
set cmd=nothing

'使用command調用帶兩個輸入參數和傳回值的預存程序
'CREATE PROCEDURE [return_1]
'(@user_name varchar(40))
'AS
'if exists(select id from user_info where user_name=@user_name)
'return 1
'else
'return 0
response.write "<br>調用帶兩個輸入參數和傳回值的預存程序：<br>"
set cmd=server.createobject("adodb.command")
cmd.activeconnection=conn
cmd.commandtype = adcmdstoredproc
cmd.commandtext = "return_1"
cmd.parameters.append cmd.createparameter("@return_value",adinteger,adparamreturnvalue)
cmd.parameters.append cmd.createparameter("@user_name",advarchar,adparaminput,40)
cmd.parameters.append cmd.createparameter("@password",advarchar,adparaminput,20)
cmd("@user_name")="tuth"
cmd("@password")="yyuyu"
cmd.execute()
rrr=cmd("@return_value")
response.write rrr
set cmd=nothing

conn.close
set conn=nothing
%>

效果：
訪問http://10.1.43.238/course/use_proc.asp?user_name=ahyi&password=ttt時，出現如下

普通的調用方法：
12

返回紀錄集，可以使用recordcount等屬性：
ahyi
tet
tuth

調用帶輸出參數的預存程序：
2

調用帶兩個輸入參數和傳回值的預存程序：
1

注意：若預存程序無參數，則調用的sql語句直接為預存程序名，一個參數為“預存程序名 參數”，若是多個參數，則“預存程序名 參數1，參數2，……，參數n”；如果在sql語句中加入exec，則在返回的記錄集中可以使用recordcount等屬性；如果想獲得預存程序的傳回值或輸出參數，可以使用command對象。

⑵．使用交易處理

①．Asp內嵌的事務支援

例子：
use_transaction_1.asp
<%
'Asp中使用事務
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"
conn.begintrans '開始事務

sql="delete from user_info"
set rs=server.createobject("adodb.recordset")
rs.open sql,conn,3,3
if conn.errors.count>0 then '有錯誤發生
conn.rollbacktrans '復原
set rs=nothing
conn.close
set conn=nothing
response.write "交易失敗，復原至修改前的狀態！"
response.end
else
conn.committrans '提交事務
set rs=nothing
conn.close
set conn=nothing
response.write "交易成功！"
response.end
end if
%>

②．資料庫級的事務

i．建立預存程序

CREATE PROCEDURE [user_info_2]
(@user_name varchar(40),@password varchar(20))
AS
SET XACT_ABORT ON
BEGIN TRANSACTION
delete from user_info where user_name=@user_name and password=@password
COMMIT TRANSACTION
SET XACT_ABORT OFF

ii．在Asp中調用

use_transaction_2.asp
<%
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"

sql="user_info_2 '"&request.querystring("user_name")&"','"&request.querystring("password")&"'"

set rs=server.createobject("adodb.recordset")
rs.open sql,conn,1,1
set rs=nothing
conn.close
set conn=nothing
%>

討論：兩種方式的優劣？

⑶．使用視圖
在資料庫中定義好視圖之後，在Asp中如同使用一個表一樣來使用視圖

4．一個資料庫分頁的例子

db_page.asp
<%
on error resume next
Set conn=Server.CreateObject("ADODB.Connection") '建立串連資料庫的對象
conn.Open "course_dsn","course_user","course_password" '使用該對象串連資料庫
set rs=server.createObject("adodb.recordset")
sql="select * from user_info order by id desc"
rs.open sql,conn,1,1

if rs.recordcount>0 then '如果有記錄
rs.pagesize=2 '每頁最多顯示2條紀錄
'從URL擷取當前要顯示的頁
page=cint(request("page"))
'頁面參數異常處理
if page="" then page=1
if page<1 then page=1
if page>= rs.pagecount then page=rs.pagecount
rs.absolutepage=page '當前頁為page參數指定的頁
for i=1 to rs.pagesize '根據pagesize參數的大小迴圈顯示當前頁中的紀錄
response.write "User_id："&rs("id")&"<br>"
response.write "User_name："&rs("user_name")&"<br><br>"
rs.movenext '紀錄指標下移
if rs.eof then exit for '如果到達紀錄集底部則退出迴圈
next
end if

'顯示翻頁按鈕
if page>1 then
response.write "<a href="&request.servervariables("document_name")&"?page=1>第一頁</a>　"
response.write "<a href="&request.servervariables("document_name")&"?page="&(page-1)&">上一頁</a>　" 
end if
if page<>rs.pagecount then
response.write "<a href="&request.servervariables("document_name")&"?page="&(page 1)&">下一頁</a>　" 
response.write "<a href="&request.servervariables("document_name")&"?page="&rs.pagecount&">最後一頁</a>　" 
end if
response.write"頁碼："&page&"/"&rs.pagecount

'關閉對象，釋放記憶體
rs.close
set rs=nothing
conn.close
set conn=nothing
%>

思考：分頁過程中使用了哪些額外的屬性？