ASP知識講座四

最後更新：2018-12-08 來源：互聯網

上載者：User

創建阿里雲帳戶，並獲得超過 40 款產品的免費試用版；而企業帳戶則可以享有總值 $1200 的免費試用版。立即註冊！

ASP內建群組件

前三講中，我們主要介紹了ASP提供的四大內建對象：
l Response對象：向瀏覽器發送資訊。
l Request對象：訪問從瀏覽器發送到伺服器的資訊（如擷取表單資料）。
l Session對象：儲存、讀取特定使用者對話資訊。
l Application對象：儲存、讀取所有使用者共用的應用程式資訊。
此外還有Server對象和ObjectContext對象我們將在以後的執行個體中學習（提示：其實不經意之間你已經可以利用所學知識編寫網路聊天室了）。本講的內容是使用ASP的ActiveX Server Components（組件）。

一、 Browser Capabilities Component（瀏覽器能力組件）：
我們知道，不同的瀏覽器也許支援不同的功能，如有些瀏覽器支援架構，有些不支援。利用這個組件，可以檢查瀏覽器的能力，使你的網頁爭對不同的瀏覽器顯示不同的頁面（如對不支援Frame的瀏覽器顯示不含Frame的網頁）。該組件的使用很簡單，需注意的是，要正確使用該組件，必須保證Browscap.ini檔案是最新的（其實每一個瀏覽器及其特性都列在這個檔案中，自己開啟看看就明白了）,否則結果可能相去甚遠，如Win98第二版所帶的IE5.0，在下例中顯示為Netscape。這個檔案一般位於Web伺服器的"\Winnt\System32\InetSrv"下，最新的版本可去http://www.asptracker.com/或http://www.cyscape.com/browscap下載。
例：wuf22.asp
<html>
<BODY>
'注意：組件的使用與對象類似，但是組件在使用前必須先建立，而使用內建對象前不必建立。
<%Set BrowsCap=Server.CreateObject("MSWC.BrowserType")%>
請稍候......
<P>
<TABLE BORDER=1 CELLPADDING=10>
<TR><TD>瀏覽器類型</TD><TD><%=BrowsCap.Browser%></TD></TR>
<TR><TD>瀏覽器版本</TD><TD><%=BrowsCap.version%></TD></TR>
<TR><TD>是否支援表格</TD><TD><%=BrowsCap.tables%></TD></TR>
<TR><TD>是否支援ActiveX控制項</TD><TD><%=BrowsCap.activexcontrols%></TD></TR>
<TR><TD>是否支援JavaApplets</TD><TD><%=BrowsCap.javaapplets%></TD></TR>
<TR><TD>是否支援JavaScript</TD><TD><%=BrowsCap.javascript%></TD></TR>
<TR><TD>是否支援Cookies</TD><TD><%=BrowsCap.Cookies%></TD></TR>
<TR><TD>是否支援Frames</TD><TD><%=BrowsCap.Frames%></TD></TR>
<TR><TD>作業系統</TD><TD><%=BrowsCap.Platform%></TD></TR>
<TR><TD>是否支援VBScript</TD><TD><%=BrowsCap.vbscript%></TD></TR>
</TABLE>
<%Set BrowsCap = Nothing%>
</BODY>
</HTML>
注意：在本例中我們也接觸了Server對象的CreateObject方法，Server.CreateObject用於建立已經註冊到伺服器上的ActiveX組件（說明：還有其他方法可以建立組件）。不過別忘了用"Set 對象 = Nothing"來及時釋放資源，這應該成為一個習慣。

二、 File Access組件
File Access組件由FileSystemObject對象和TextStream對象組成，使用FileSystemObject對象，可以建立、檢索、刪除目錄及檔案，而TextStream對象則提供讀寫檔案的功能。
執行個體wuf23.asp。強調：只有通過實踐才能加深理解，實踐和比較程式運行結果是快速掌握編程技巧的最好方法。
<%@ Language=VBScript %>
<% Option Explicit
' 注意絕對路徑: C:\Inetpub\home\asp\wuf23.asp 首頁路徑: C:\Inetpub\home
Dim Path, File, FSO, CTF, Str, StrHTML, StrNoHTML

'使用 CreateObject 方法建立 FileSystemObject 對象 FSO
Set FSO = Server.CreateObject("Scripting.FileSystemObject")

Path = Server.MapPath("test") '返回test的物理目錄(絕對路徑)
'就本例而言, 下面這句與上面這句返回的Path完全一樣
'Path = Server.MapPath("\asp\test\")
Response.Write Path & "<Br>"

If FSO.FolderExists(Path) = false then '判斷該檔案夾是否存在
FSO.CreateFolder(Path) '建立檔案夾
End If

File = Path & "\asptest.txt"
' 寫檔案操作
If FSO.FileExists(File) = True Then '判斷該檔案是否存在
'建立 TextStream 對象 CTF
Set CTF = FSO.OpenTextFile(File, 8, False, 0) '開啟檔案, 詳見說明
Else
Set CTF = FSO.CreateTextFile(File,False, False) '建立檔案
End If
CTF.Write "<P>第一個字串; " '寫字串
CTF.WriteLine "第二個字串; " '寫字串, 並加上一個分行符號
CTF.Write "第三個字串; "
CTF.Close '注意要關閉檔案

' 讀檔案操作
Set CTF = FSO.OpenTextFile(File, 1,,0)
Do While CTF.AtEndOfStream <> True '判別是否檔案結尾（迴圈語句）
Str = CTF.ReadLine '（每次）讀取一行
StrNoHTML = StrNoHTML & Str & "<BR>" & VbCrLf
StrHTML = StrHTML & Server.HTMLEncode(Str) & "<BR>" & VbCrLf
Loop
Response.Write StrNoHTML
Response.Write StrHTML

CTF.Close
Set CTF = Nothing '釋放對象
Set FSO = Nothing
%>
CTF = FSO.OpenTextFile(File, 8, False, 0)，括弧內第一個參數為檔案名稱；第二個參數為8，表示在原檔案後追加內容，若為1表示唯讀，為2則會重寫原檔案；第三個參數false表示，若指定檔案不存在，也不建立檔案，若為True，表示指定檔案不存在，則建立該檔案；第四個參數0表示以ASCII檔案格式開啟，若為-2，則表示以原來的格式開啟。
CTF = FSO.CreateTextFile(File,False, False)，第二個參數false表示不覆蓋已有檔案，若為True，則表示覆蓋（OverWrite）已有檔案；第三個參數為False表示檔案格式為ASCII，為True表示檔案格式為Unicode。
Server對象的MapPath方法將指定的虛擬路徑轉換為真實的檔案路徑。MapPath將"/"和"\"字元視為相同。
Server對象的HTMLEncode方法允許你對特定的字串進行HTML編碼，或者說使瀏覽器中可以正確顯示特定的字元。上例中，若未編碼，則"<P>"顯示不出來，而是被瀏覽器作為HTML標記，你可以對比一下運行結果。
實際上，File Access組件對檔案、檔案夾和磁碟機的操作還是比較強大的，也提供了較多的方法，如果需要用到這方面的知識，別忘了使用它。
另外，到現在為止，寫一個網頁計數器已經是小菜一碟了吧，難怪那麼多的網頁提供免費計數器。怎麼樣？自己寫一個圖形計數器試試看，想怎麼作弊就怎麼作弊，完全自己說了算，爽呆！（小秘密：我的首頁上有執行個體wuf24.asp）

三、 AD Rotator（廣告翻轉組件）
現在上網，恐怕最討厭的是別人首頁上的廣告條，最喜歡的是自己首頁上的廣告條，廣告條如同垃圾郵件一樣，比比皆是，防不勝防。你也可以自己動手製造這樣的垃圾，ASP的AD Rotator組件就可使每次開啟或者重新載入網頁時，隨機的顯示廣告。這個例子包括三部分：
常式wuf25.asp
<%@ Language=VBScript %>
<% Option Explicit
Dim adr
'建立 AD Rotator 對象
Set adr = Server.CreateObject("MSWC.AdRotator")
adr.Border = 2 '指定圖形檔案的邊框大小
adr.Clickable = True '指示顯示的圖片是否是一個超連結
adr.TargetFrame = "_blank" '設定超連結是否要指定Frame名稱,如: _TOP _NEW _PARENT
'擷取將要顯示的圖片及超連結設定 - 在檔案 AdrSet.txt 中設定
Response.Write adr.GetAdvertisement("AdrSet.txt")
%>
AdrSet.txt內容（後面為注釋，不是這個檔案的內容）：
REDIRECT wuf26.asp 點擊廣告後，轉由wuf26.asp來處理
WIDTH 468 廣告圖片寬度
HEIGHT 60 廣告圖片高度
* 分隔字元
http://www.soyou.com/prog/ad/468x60_1.gif 廣告圖片所在位置，也可為本地圖形檔案
http://www.163.com/ 指向連結，若沒有超連結，寫入一個"-"
網易文字說明
20 顯示該廣告的相對權重，即顯示頻率
http://fp.cache.imgis.com/images/Ad173962St1Sz1Sq1Id2.gif
http://www.sina.com.cn/
新浪網
30
http://61.139.77.73/images/canon.gif 也可以使用本地圖片，如../images/flag.gif
http://www.canon.com.cn/
佳能
50
本例中一共有三個圖片（圖片大小468X60）及連結，每個連結的描述佔四行，實際使用時，你可如法炮製，增加更多的圖片。
<% 'wuf26.asp
URL = Request.QueryString("url")
Response.Redirect(URL)
%>
wuf26.asp是一個最簡單的處理常式，你可根據實際需要在這裡加入更多的代碼。
運行一下，原來這個組件的使用也很簡單，你要做的就是得到自己的AdrSet.txt檔案。利用這個組件，你甚至可以設計一個現在已非常時髦的廣告交換首頁。

四、 Content Linking組件
顯然這個組件與連結有關係，如果想馬上知道這個組件的具體用途，恐怕還操之過急，不妨先引用一個經典的例子：假設在網上閱讀一本書，你對以下這些連結一定不會陌生：第1章、第2章、…、上一章、下一章（或前一頁、後一頁）等等。我們現在要做的就是如何在這些連結之間方便快速地設定跳轉。
首先建一個連結清單文字檔，如urllist.txt
wuf23.asp 第1章：檔案操作（File Access組件）
wuf28.asp 第2章：Content Linking組件使用樣本
wuf22.asp 第3章：瀏覽器能力組件
連結url地址和描述之間用 Tab 鍵分隔。下面wuf27.asp用來列出urllist.txt中的所有連結。
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html><head><title>Content Linking組件使用</title></head>
<body>
<h2>目錄列表: 注意核心連結是第2章, 你一定要點擊它</h2>
<ul>
<%
Dim NextLink, Count
'建立 Content Linking 組件
Set NextLink = Server.CreateObject("MSWC.NextLink")

'擷取檔案 urllist.txt 中連結數目
Count = NextLink.GetListCount("urllist.txt")

Dim url, Dscr, I
For I = 1 To Count
url = NextLink.GetNthURL ("urllist.txt", I) '取得超連結
Dscr = NextLink.GetNthDescription ("urllist.txt", I) '取得文字描述
Response.Write "<li><a href = """ & url & """>" & Dscr & "</a>" & vbcrlf
Next
%>
</ul></body></html>
然後，以wuf28.asp為例說明如何自動實現上一章和下一章跳轉。
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html><head><title>這個連結要注意</title></head>
<body>

<% '每個檔案都包含下面這句, 就實現了自動連結%>

</body></html>
這裡最後一句加上去就可以實現自動跳轉，核心在wuf29.asp中。
<%
Dim NextLink, rank
Set NextLink = Server.CreateObject ("MSWC.NextLink")
'當前的連結在 urllist.txt 中位於第幾個
rank = NextLink.GetListIndex ("urllist.txt")
Response.Write "<hr>"

If (rank > 1) Then 'rank = 1 不存在前一頁
Response.Write "|<a href=""" & NextLink.GetPreviousURL("urllist.txt") & """>上一章</a>|"
End If

If (rank < NextLink.GetListCount("urllist.txt")) Then 'rank在最後, 則沒有下一頁
Response.Write "|<a href=""" & NextLink.GetNextURL("urllist.txt") & """>下一章</a>|"
End If
%>
運行這個例子後，你馬上能真正理解這個組件的作用，簡而言之，就是不需要在每頁都寫一個"上一章"、"下一章"，完全通過wuf29.asp一下搞定，是不是很方便？！不然你要是手工修改連結的話，不是太麻煩了幾點嗎？
現在你應該明白了，網上大量的免費計數器、免費留言板、免費聊天室、廣告交換網等等……，其原理都不過如此，大可不必崇拜。

本文章原先以中文撰寫並發佈於 aliyun.com，亦設英文版本，僅作資訊用途。本網站不對文章的準確性，完整性或可靠性或其任何翻譯作出任何明示或暗示的陳述或保證。如對該文章有任何疑慮或投訴，請傳送電郵至 info-contact@alibabacloud.com 並提供相關疑慮或投訴的詳細說明。職員會於 5 個工作天內與您聯絡，一經驗證之後，即會刪除該侵權內容。

A Free Trial That Lets You Build Big!

Start building with 50+ products and up to 12 months usage for Elastic Compute Service

Get Started for Free

Sales Support

1 on 1 presale consultation

Chat Contact Sales
After-Sales Support

24/7 Technical Support 6 Free Tickets per Quarter Faster Response

Open a Ticket
Alibaba Cloud offers highly flexible support services tailored to meet your exact needs.

Learn More