ASP郵件發送外掛程式Jmail全部方法屬性的介紹

Jmail的主要參數列表

首先應該建立一個jmail.message對像：

set JMail = Server.CreateObject("JMail.Message")

再對jmail對像的其它參數進行操作。

(1) Body (信件本文) : 字串
如：JMail.Body = “這裡可以是使用者填寫的表單內容，可以取自From。”
(2) Charset (字元集，預設為”US-ASCII”) : 字串
如：JMail.Charset = “US-ASCII”
(3) ContentTransferEncoding : 字串
指定內容傳送時的編碼方式，預設是”Quoted-Printable”
如：JMail.ContentTransferEncoding = “base64”
(4) ContentType (信件的contentype. 預設是”text/plain”) : 字串
如果你以HTML格式發送郵件, 改為”text/html”即可。
如：JMail.ContentType = “text/html”
(5) Encoding : 字串
設定附件編碼方式 (預設是”base64) 。 可以選擇使用的是”base64″, “uuencode” or “quoted-
printable”
如：JMail.Encoding = “base64”
(6) Log (Jmail建立的日誌，前提loging屬性設定為true，見下面) : 字串
如：使用Response.Write ( JMail.Log ) 語句列出日誌資訊。
(7) Logging (是否使用日誌) : 布爾型
如：JMail.Logging = true
(8) Recipients : 字串
唯讀屬性，返回所有收件者
如：Response.Write ( “” + JMail.Recipients + “” ) ;
(9) ReplyTo (指定別的回信地址) : 字串
如：JMail.ReplyTo = “anyother@mailhost.com”
(10) Sender ( 寄件者的郵件地址) : 字串
如：JMail.Sender = “sender@mailhost.com”
(11) SenderName (寄件者的姓名) : 字串
如：JMail.SenderName = “一克”
(12) ServerAddress (郵件伺服器的地址) : 字串
你可以指定多個伺服器，用分號點開。可以指定連接埠號碼。
如果serverAddress保持空白，JMail會嘗試遠程郵件伺服器，然後直接發送到伺服器上去。
如：JMail.ServerAddress = “mail.263.net.cn”
(13) Subject (設定郵件的標題，可以取自From。) ：字串
如：JMail.Subject = “客戶回函表單”
(14) 添加檔案附件到郵件，（註：C盤下的檔案，安全性需要改為網路使用者，才可以識別）
如：JMail.AddAttachment ( “c:\anyfile.zip” )
(15) AddCustomAttachment ( FileName, Data )
添加自訂附件.
如：JMail.AddCustomAttachment ( “anyfile.txt”, “Contents of file” ) ;
(16) AddHeader ( Header, Value )
添加使用者定義的信件標題。
如：JMail.AddHeader ( “Originating-IP”,”192.168.10.10″ ) ;
(17) AddRecipient (收件者) ：字串
如：JMail.AddRecipient ( “info@dimac.net” ) ;
(18) AddRecipientBCC ( Email ) ，密件收件者：
如：JMail.AddRecipientBCC ( “anyone@mailhost.com” ) ;
(19) AddRecipientCC ( Email ) ，抄送收件者：
如：JMail.AddRecipientCC ( “anyone@mailhost.com” )
(20) AddURLAttachment ( URL, 文檔名)
下載並添加一個來自url的附件. 第二個參數”文檔名”, 用來指定信件收到後的檔案名稱。
如：JMail.AddURLAttachment ( “http://www.chinabs.net/jmail.zip”, “jmail” )
(21) AppendBodyFromFile ( 檔案名稱) ，將檔案作為信件本文：
如：JMail.AppendBodyFromFile ( “c:\anyfile.txt” )
(22) AppendText ( Text )
追加信件的本文內容，比如增加問候語或者其它資訊。
如：JMail.AppendText ( “歡迎訪問本站！” )
(23) Close () ，強制JMail關閉緩衝的與郵件伺服器的串連：
如：JMail.Close ()
(24) Execute () ，執行郵件的發送
如：JMail.Execute ()

以下的代碼已在asp中調試通過。

<%

Dim nReturnValue '發送函數
nReturnValue = SendMail_JMail("mail.qcmw.com", "laifangsong#qcmw.com", "傾城wap自動建站系統", "laifangsong#qcmw.com", "#123456#", "laifangsong#126.com", "註冊成功提示", "您在我們網站上註冊成功！")
Select Case nReturnValue
Case 0
Response.Write "郵件發送成功！"
Case 1
Response.Write "建立JMail組件失敗！"
Case 2
Response.Write "郵件發送失敗！"
End Select

'JMail發送郵件(4.4)
'參數：發送郵件SMTP伺服器， 寄件者郵箱地址， 寄件者姓名， 發送郵件伺服器登入名稱， 發送郵件伺服器登入密碼， 接收人郵件地址， 郵件標題， 郵件內容

Function SendMail_JMail(s_SMTPServer, s_FromMail, s_FromName, s_MailServerUserName, s_MailServerPassword, s_ToEmail, s_Subject, s_Body)
On Error Resume Next
Set jmail = Server.CreateObject("JMAIL.Message") '建立發送郵件的對象
If Err.Number <> 0 Then
SendMail_JMail = 1
Exit Function
End If

jmail.silent = True '屏蔽例外錯誤，返回FALSE跟TRUE兩值
jmail.logging = False '啟用郵件日誌
jmail.Charset = "GB2312" '郵件的文字編碼為中文
jmail.ISOEncodeHeaders = False '防止郵件標題亂碼
jmail.ContentType = "text/html" '郵件的格式為HTML格式
jmail.AddRecipient s_ToEmail '郵件收件者的地址
jmail.From = s_FromMail '寄件者的E-MAIL地址
jmail.FromName = s_FromName '寄件者姓名
jmail.MailServerUserName = s_MailServerUserName '登入郵件伺服器所需的使用者名稱
jmail.MailServerPassword = s_MailServerPassword '登入郵件伺服器所需的密碼
jmail.Subject = s_Subject '郵件的標題
jmail.Body = s_Body '郵件的內容
jmail.Priority = 1 '郵件的緊急程式，1 為最快，5 為最慢， 3 為預設值
jmail.Send(s_SMTPServer) '執行郵件發送（通過郵件伺服器地址）
jmail.Close() '關閉對象

If jmail.ErrorCode <> 0 Then
SendMail_JMail = 2
Else
SendMail_JMail = 0
End If

End Function

'IIS中SMTP郵件伺服器發送組件
Function SendMail_IISSMTP(s_FromMail, s_ToEmail, s_Subject, s_Body)
Set cdomail = Server.CreateObject("CDONTS.NewMail") '建立郵件對象
cdomail.Subject = s_Subject '郵件標題
cdomail.From = s_FromMail '寄件者的地址
cdomail.To = s_ToEmail '收件者的地址
cdomail.Body = s_Body '郵件的內容
cdomail.Send '執行發送
End Function

%>