Asp無組件產生縮圖

來源:互聯網
上載者:User
網上有不少產生縮圖的ASP組件。若你的虛擬空間不支援註冊新組件,可能會感覺自己的網站失色不少。心晴不才,結合網上資源寫了個無組件產生縮圖程式,僅供參考。

  還是先看看基礎部分吧。首先,我們知道在頁面中顯示圖片是如下代碼:

  <img src="http://edu.cnzz.cn/NewsInfo/pic.gif" border="0" width="300" height="260">
  src是圖片路徑,border控製圖片邊緣寬度,width是圖片的長度,height是圖片的高度。縮圖的產生其實就是在原始大小上縮放。但一般為了盡量少失真,我們都會按比例縮放。於是,擷取圖片的長寬尺寸也就成了產生縮圖的重點。

  下面便是編寫無組件產生縮圖的步驟:

  1.無組件擷取圖片大小

  以前剛學ASP不久時看到過一篇利用ASCII碼實現無組件擷取圖片尺寸的文章。後來試了試,發現在擷取jpg類圖片尺寸時總是不能正確顯示,在網上查了查,居然有不少網站轉載這個程式,但沒有一家指出此程式的缺陷,也就更談不上解決缺陷的辦法了。後來又google了一下,終於找到了一篇介紹利用ADODB.stream擷取圖片尺寸的文章,按其介紹的方法,修改裡面的代碼試了試,效果真的還不錯,現在將其拿出來與大家分享:

  利用ADODB.stream擷取圖片尺寸的通用類
<%
'//////////// GPS:Get Picture Size //////////////
'//////////////利用ADODB.stream擷取圖片尺寸//////////////
'/////////Cited By Leon(心晴) 2005年8月11日//////////

Class GPS
Dim aso

Private Sub Class_Initialize
Set aso=CreateObject("Adodb.Stream")
aso.Mode=3
aso.Type=1
aso.Open
End Sub

Private Sub Class_Terminate
set aso=nothing
End Sub

Private Function Bin2Str(Bin)
Dim I, Str
For I=1 to LenB(Bin)
clow=MidB(Bin,I,1)
if AscB(clow)<128 then
Str = Str & Chr(ASCB(clow))
Else
I=I+1
if I <= LenB(Bin) then Str = Str & Chr(ASCW(MidB(Bin,I,1)&clow))
end If
Next
Bin2Str = Str
End Function

Private Function Num2Str(num,base,lens)
'GPS (2005-8-11)
dim ret
ret = ""
while(num>=base)
ret = (num mod base) & ret
num = (num - num mod base)/base
wend
Num2Str = right(string(lens,"0") & num & ret,lens)
End Function

Private Function Str2Num(str,base)
'GPS (2005-8-11)
dim ret
ret = 0
for i=1 to len(str)
ret = ret *base + cint(mid(str,i,1))
next
Str2Num=ret
End Function

Private Function BinVal(bin)
'GPS (2002-8-11)
dim ret
ret = 0
for i = lenb(bin) to 1 step -1
ret = ret *256 + ascb(midb(bin,i,1))
next
BinVal=ret
End Function

Private Function BinVal2(bin)
'GPS (2002-8-11)
dim ret
ret = 0
for i = 1 to lenb(bin)
ret = ret *256 + ascb(midb(bin,i,1))
next
BinVal2=ret
End Function

'///以下是調用代碼///
Function getImageSize(filespec)
'GPS (2002-8-11)
dim ret(3)
aso.LoadFromFile(filespec)
bFlag=aso.read(3)
select case hex(binVal(bFlag))
case "4E5089":
aso.read(15)
ret(0)="PNG"
ret(1)=BinVal2(aso.read(2))
aso.read(2)
ret(2)=BinVal2(aso.read(2))
case "464947":
aso.read(3)
ret(0)="GIF"
ret(1)=BinVal(aso.read(2))
ret(2)=BinVal(aso.read(2))
case "535746":
aso.read(5)
binData=aso.Read(1)
sConv=Num2Str(ascb(binData),2 ,8)
nBits=Str2Num(left(sConv,5),2)
sConv=mid(sConv,6)
while(len(sConv)<nBits*4)
binData=aso.Read(1)
sConv=sConv&Num2Str(ascb(binData),2 ,8)
wend
ret(0)="SWF"
ret(1)=int(abs(Str2Num(mid(sConv,1*nBits+1,nBits),2)-Str2Num(mid(sConv,0*nBits+1,nBits),2))/20)
ret(2)=int(abs(Str2Num(mid(sConv,3*nBits+1,nBits),2)-Str2Num(mid(sConv,2*nBits+1,nBits),2))/20)
case "FFD8FF":
do
do: p1=binVal(aso.Read(1)): loop while p1=255 and not aso.EOS
if p1>191 and p1<196 then exit do else aso.read(binval2(aso.Read(2))-2)
do:p1=binVal(aso.Read(1)):loop while p1<255 and not aso.EOS
loop while true
aso.Read(3)
ret(0)="JPG"
ret(2)=binval2(aso.Read(2))
ret(1)=binval2(aso.Read(2))
case else:
if left(Bin2Str(bFlag),2)="BM" then
aso.Read(15)
ret(0)="BMP"
ret(1)=binval(aso.Read(4))
ret(2)=binval(aso.Read(4))
else
ret(0)=""
end if
end select
ret(3)="width=""" & ret(1) &""" height="""
& ret(2) &""""
getimagesize=ret
End Function
End Class
%>
  將以上代碼複製產生GPS.asp檔案,這樣無組件擷取圖片尺寸的通用類就OK了。


  2.擷取圖片路徑

  由於不只一張圖片,以及圖片需分類存放,我們在資料庫中設計了一個存放圖片相對路徑的欄位ImgURL。我們把上傳的圖片都放在一個名為images的檔案夾中(至於如何無組件上傳圖片心晴就不在多說了)。現在我們先設計一個ShowImg.asp頁面用來顯示縮圖及相關資訊。具體設計如下:

  圖片:

  圖片格式:

  圖片尺寸:

  圖片大小:

  點擊次數:

  下面,我們擷取圖片的絕對路徑。代碼如下:
<%
'/////擷取ShowImg.asp的絕對路徑/////
Dim curFile
curFile=Server.mappath(Request.servervariables("PATH_INFO"))
Dim curfilename,filename

'/////圖片相對路徑(存於資料庫中)
cufilename=rs("ImgURL")

'/////因為ShowImg.asp與images在同一目錄,所以我們用instrrev擷取images的路徑/////
filename=left(curFile,instrrev(curFile,"\"))&cufilename

'/////建立GPS類實體/////
Dim GetPicSize
Set GetPicSize=new GPS
Set fs=Server.CreateObject("Scripting.FileSystemObject")

'/////擷取圖片類型/////
Dim PicSuffixName
PicSuffixName=fs.GetExtensionName(filename)
Dim PD '//Picture Dimension
Dim PWidth,PHeight
Select Case PicSuffixName
Case "gif","bmp","jpg","png":

'/////調用GPS通用類中的GetImageSize函數擷取圖片尺寸/////
PD=GetPicSize.GetImageSize(filename)
PWidth=PD(1) '//擷取圖片寬度
PHeight=PD(2) '//擷取圖片高度
Case "swf"
PD=GetPicSize.GetImageSize(filename)
PWidth=PD(1) '//擷取Flash寬度
PHeight=PD(2) '//擷取Flash高度
Case Else
End Select
Set fs=Nothing
Set GetPicSize=Nothing
%>

  將上面的代碼複製到<body>的上面就OK了!

  當然,有人會說,擷取路徑不一定要用PATH_INFO,直接用server.mappath()不就可以了嘛,呵呵,蘿蔔青菜各有所愛,主要是我用PATH_INFO可以實現FSO的一些功能而用server.mappath()沒有搞定,所以一直使用這個。
 3.定義縮圖尺寸

  這部分代碼就是仁者見仁,智者見智了。首先,我們需要規定縮圖顯示尺寸範圍,譬如:300X260,代碼可以這樣寫:
<%
Dim PXWidth,PXHeight
Dim Pp '//Proportion
If PWidth=0 Or PWidth="" Then
PXWidth=0
PXHeight=0
Else
Pp=FormatNumber(PWidth/PHeight,2) '//長寬比
End If
If PWidth>=PHeight Then
If PWidth>=300 Then
PXWidth=300
PXHeight=FormatNumber(300/Pp,0)
Else
PXWidth=PWidth
PXHeight=PHeight
End If
Else
If PHeight>=260 Then
PXHeight=260
PXWidth=FormatNumber(260*Pp,0)
Else
PXWidth=PWidth
PXHeight=PHeight
End If
End If
%>

  將上面的代碼緊接第二步寫下即可。調用時代碼如下:
<img src=<%=curfilename%> border="0" width=<%=PXWidth%>
height=<%=PXHeight%>>

  至於圖片格式可以用得到,圖片尺寸可以寫成
<%
response.write PXWidth&"X"&PXHeight
%>

  圖片大小可以用FSO.GetFileSize(filename)來實現,而點擊次數可以簡單地用SQL語句實現,具體編碼就不再累述了。

  這樣,一個無組件產生縮圖程式就寫好了,可能有點拿來主義,不過只要大家能將方法掌握相信還是有很大提高的。



相關文章

E-Commerce Solutions

Leverage the same tools powering the Alibaba Ecosystem

Learn more >

Apsara Conference 2019

The Rise of Data Intelligence, September 25th - 27th, Hangzhou, China

Learn more >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。