ASP頁面靜態化批量產生代碼分享(多種方法)

1、ASP兩種簡單的產生靜態首頁的方法

為什麼要產生靜態首頁？
1、如果你首頁讀取的資料庫次數比較多，速度很慢，而且佔用很多伺服器資源。使用靜態頁面訪問速度當然快多了
2、搜尋引擎容易搜尋到
3、如果程式出問題，也能保證首頁能訪問。
4、其他的太多，自己想：）
應用方式：
如果你的首頁是index.asp,你可以產生index.htm （預設訪問順序必須是index.htm,index.asp）。這樣訪問者第一次訪問到你的網站的時候開啟的是index.htm 。你可以把網站首頁的連結做成index.asp，這樣從網站任何一個頁面點擊首頁的連結出現的就是index.asp,這樣保證的資訊更新的及時性（畢竟index.htm需要每次手動更新）。
方法一：
直接將首頁檔案包含在表單文字框中，將首頁代碼最為資料提交，然後產生靜態頁面。
代碼如下： 複製代碼 代碼如下:<%
'------------------------------------------------------------
'使用表單提交產生靜態首頁的代碼
'確保你的空間支援FSO，且首頁代碼內容較少
'------------------------------------------------------------
dim content
content=Trim(Request.Form("content"))
if content<>"" then
call makeindex()
end if
sub makeindex()
Set Fso = Server.CreateObject("Scripting.FileSystemObject")
Filen=Server.MapPath("index.htm")
Set Site_Config=FSO.CreateTextFile(Filen,true, False)
Site_Config.Write content
Site_Config.Close
Set Fso = Nothing
Response.Write("<script>alert('已經成功產生首頁！')</script>")
end sub
%>
<form name="form1" method="post" action="">
<textarea name="content">
<!-- ＃i nclude file="index.asp" -->
</textarea>
<br>
<input type="submit" name="Submit" value="提交">
</form>

缺點：
1、如果首頁中包括<@ ..>標記，會提示出錯。
2、如果首頁代碼較長，用表單無法提交過去（表單資料長度有一定的限制）。
解決方案：
1、去掉index.asp中的<@ >標記
2、使用eWebEditor，提交支援大資料（能自動分割）
優點：
可以在產生時對內容即時修改。
方法二：
直接使用XMLHTTP擷取index.asp的代碼

複製代碼 代碼如下:<%
'----------------------------------------------------------
'使用XMLHTTP產生靜態首頁的代碼
'Curl 為你的首頁地址，確保你的空間支援FSO
'-----------------------------------------------------------
dim read,Curl,content
Curl="http://www.xx0123.com/index.asp"
read=getHTTPPage(Curl)
if read<>"" then
content=read
call makeindex()
end if
sub makeindex()
Set Fso = Server.CreateObject("Scripting.FileSystemObject")
Filen=Server.MapPath("index.htm")
Set Site_Config=FSO.CreateTextFile(Filen,true, False)
Site_Config.Write content
Site_Config.Close
Set Fso = Nothing
Response.Write("<script>alert('已經成功產生首頁！')</script>")
end sub
Function getHTTPPage(url)
dim http
set http=Server.createobject("Microsoft.XMLHTTP")
Http.open "GET",url,false
Http.send()
if Http.readystate<>4 then
exit function
end if
getHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
set http=nothing
if err.number<>0 then err.Clear
End function
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function
%>

2、模板分離批量產生

模板檔案中要替換的內容均以{...}括起來
為力求簡潔，去掉了錯誤處理代碼（replace中要來替換的字串參數不能為null值，當然fso也應該做錯誤檢查）。 複製代碼 代碼如下:<%
' ---------------------------------------------------------------------------------------------------------------------
' 出自: kevin fung http://www.yaotong.cn
' 作者: kevin fung 落伍者ID:kevin2008,轉載時請保持原樣
' 時間: 2006/07/05落伍者論壇首發
' ----------------------------------------------------------------------------------------------------------------------
Dim start '該變數為指標將要指向的記錄集位置，通過參數動態獲得
Dim Template '模板檔案將以字串讀入該變數
Dim content '替換後的字串變數
Dim objConn '連線物件
Dim ConnStr '連接字串
Dim sql '查詢語句
Dim cnt:cnt = 1 '本輪迴圈計數器初始化
start = request("start") '擷取本輪指標的開始位置
If IsNumeric(start) Then start = CLng(start) Else start=1
If start=0 Then start = 1 '如果start
ConnStr = "Provider = Microsoft.Jet.OLEDB.4.0;Data Source = " & Server.MapPath("DataBase.mdb")
sql = "select * from table_name"
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open ConnStr
set rs = Server.CreateObject("ADODB.Recordset")
rs.open sql,objConn,1,1 '開啟資料集
rs.AbsolutePosition = start '最關鍵的一步,將指標指向start，start通過參數動態獲得
Template = getTemplate(Server.MapPath("template.html"))' template.html為模板檔案，通過函數getTemplate讀入到字串,模板檔案中要替換的內容均以{...}括起來
While Not rs.eof And cnt<= 500 '500是設定一次請求產生頁面的迴圈次數，根據實際情況修改，如果太高了，記錄集很多的時候會出現逾時錯誤
content = Replace(Template,"{filed_name_1}",rs("filed_name_1")) '用欄位值替換模板內容
content = Replace(content,"{filed_name_2}",rs("filed_name_2"))
......
content = Replace(content,"{filed_name_n}",rs("filed_name_n"))
genHtml content,Server.MapPath("htmfiles/"&rs("id")&".html") '將替換之後的Template字串產生HTML文檔，htmfiles為儲存靜態檔案的目錄,請手動建立
cnt = cnt + 1 '計數器加1
start = start + 1 '指標變數遞增
rs.movenext
wend
If Not rs.eof Then '通過重新整理的方式進行下一輪請求,並將指標變數start傳遞到下一輪
response.write "<meta http-equiv='refresh' content='0;URL=?start="&start&"'>"
Else
response.write "產生HTML檔案完畢！"
End if
rs.Close()
Set rs = Nothing
objConn.Close()
Set objConn = Nothing
Function getTemplate(template)'讀模數板的函數，返回字串,template為檔案名稱
Dim fso,f
set fso=CreateObject("Scripting.FileSystemObject")
set f = fso.OpenTextFile(template)
getTemplate=f.ReadAll
f.close
set f=nothing
set fso=Nothing
End Function
Sub genHtml(content,filename)'將替換後的內容寫入HTML文檔,content為替換後的字串,filename為產生的檔案名稱
Dim fso,f
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set f = fso.CreateTextFile(filename,true)'如果檔案名稱重複將覆蓋舊檔案
f.Write content
f.Close
Set f = Nothing
set fso=Nothing
End Sub
%>