ASP程式效能測試報告

程式|效能 綱要：ASP動態產生的內容以什麼方式輸出效率最高？最好用哪種方法提取資料庫記錄集？本文測試了近20個這類ASP開發中常見的問題，測試載入器所顯示的時間告訴我們：這些通常可以想當然的問題不僅值得關注，而且還有出乎意料的秘密隱藏在內。

一、測試目的

　　 本文的第一部分考察了ASP開發中的一些基本問題，給出了一些效能測試結果以協助讀者理解放入頁面的代碼到底對效能有什麼影響。ADO是由Microsoft開發的一個通用、易用的資料庫介面，事實證明通過ADO與資料庫互動是ASP最重要的應用之一，在第二部分中，我們就來研究這個問題。

　　 ADO所提供的功能相當廣泛，因此準備本文最大的困難在於如何界定問題的範圍。考慮到提取大量的資料可能顯著地增加Web伺服器的負載，所以我們決定這一部分的主要目的是找出什麼才是操作ADO記錄集的最優配置。然而，即使縮小了問題的範圍，我們仍舊面臨很大的困難，因為ADO可以有許多種不同的方法來完成同一個任務。例如，記錄集不僅可以通過Recordset類提取，而且也可以通過Connection和Command類提取；即使得到記錄集對象之後，還有許多可能戲劇性地影響效能的操作方法。然而，與第一部分一樣，我們將儘可能地涵蓋最廣泛的問題。

　　 具體地講，這一部分的目標是收集足夠多的資訊，回答下列問題：

l是否應該通過包含引用ADOVBS.inc？
l使用記錄集時是否應該建立單獨的連線物件？
l最好用哪種方法提取記錄集？
l哪種遊標類型和記錄鎖定方式效率最高？
l是否應該使用本地記錄集？
l設定記錄集屬性用哪種方法最好？
l用哪種方法引用記錄集欄位值效率最高？
l用臨時字串收集輸出是一種好方法嗎？

二、測試環境

　　 本測試總共用到了21個ASP檔案，這些檔案可以從本文後面下載。每一個版面設定成可以運行三種不同的查詢，分別返回0、25、250個記錄。這將協助我們隔離頁面本身的初始化、運行開銷與用逐一查看記錄集的開銷。

　　 為便於測試，資料庫連接字串和SQL命令串都在Global.asa中作為Application變數儲存。由於我們的測試資料庫是SQL Server 7.0，因此串連串指定OLEDB作為串連提供者，測試資料來自SQL Server的Northwind資料庫。SQL SELECT命令從NorthWind Orders表提取7個指定的欄位。

< SCRIPT LANGUAGE=VBScript RUNAT=Server >
Sub Application_OnStart
Application("Conn") = "Provider=SQLOLEDB; " & _
"Server=MyServer; " & _
"uid=sa; " & _
"pwd=;" & _
"DATABASE=northwind"
Application("SQL") = "SELECTTOP 0OrderID, " & _
"CustomerID, " & _
"EmployeeID, " & _
"OrderDate, " & _
"RequiredDate, " & _
"ShippedDate, " & _
"Freight " & _
"FROM[Orders] "
End Sub
< /SCRIPT >

'alternate sql - 25 records
Application("SQL") = "SELECTTOP 25OrderID, " & _
"CustomerID, " & _
"EmployeeID, " & _
"OrderDate, " & _
"RequiredDate, " & _
"ShippedDate, " & _
"Freight " & _
"FROM[Orders] "

'alternate sql - 250 records
Application("SQL") = "SELECTTOP 250 OrderID, " & _
"CustomerID, " & _
"EmployeeID, " & _
"OrderDate, " & _
"RequiredDate, " & _
"ShippedDate, " & _
"Freight " & _
"FROM[Orders] "

　　 測試伺服器配置如下：450 Mhz Pentium，512 MB RAM，NT Server 4.0 SP5，MDAC 2.1（資料訪問組件），以及5.0版本的Microsoft指令碼引擎。SQL Server運行在另外一台具有類似配置的機器上。和第一部分一樣，我們仍舊使用Microsoft Web Application Stress Tool 記錄從第一個頁面請求到從伺服器接收到最後一個位元組的時間（TTLB，Time To Last Byte），時間以毫秒為單位。測試指令碼調用每個頁面1300次以上，已耗用時間約20小時，以下顯示的時間是會話的平均TTLB。請記住，和第一部分一樣，我們只關心代碼的效率，而不是它的延展性或伺服器效能。

　　 同時請注意我們啟用了伺服器的緩衝。另外，為了讓所有的檔案名稱字長度相同，有的檔案名稱字中嵌入了一個或多個底線。
三、第一次測試

　　 在第一次測試中，我們類比Microsoft ASP ADO樣本中可找到的典型情形提取一個記錄集。在這個例子（ADO__01.asp）中，我們首先開啟一個串連，然後建立記錄集對象。當然，這裡的指令碼按照本文第一部分所總結的編碼規則作了最佳化。

< % Option Explicit % >
< !-- #Include file="ADOVBS.INC" -- >
< %
Dim objConn
Dim objRS

Response.Write( _
"< HTML >< HEAD >" & _
"< TITLE >ADO Test< /TITLE >" & _
"< /HEAD >< BODY >" _
)

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("Conn")

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = objConn
objRS.CursorType = adOpenForwardOnly
objRS.LockType = adLockReadOnly
objRS.Open Application("SQL")

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
Response.Write( _
"< TABLE BORDER=1 >" & _
"< TR >" & _
"< TH >OrderID< /TH >" & _
"< TH >CustomerID< /TH >" & _
"< TH >EmployeeID< /TH >" & _
"< TH >OrderDate< /TH >" & _
"< TH >RequiredDate< /TH >" & _
"< TH >ShippedDate< /TH >" & _
"< TH >Freight< /TH >" & _
"< /TR >" _
)
'write data
Do While Not objRS.EOF
Response.Write( _
"< TR >" & _
"< TD >" & objRS("OrderID") & "< /TD >" & _
"< TD >" & objRS("CustomerID") & "< /TD >" & _
"< TD >" & objRS("EmployeeID") & "< /TD >" & _
"< TD >" & objRS("OrderDate") & "< /TD >" & _
"< TD >" & objRS("RequiredDate") & "< /TD >" & _
"< TD >" & objRS("ShippedDate") & "< /TD >" & _
"< TD >" & objRS("Freight") & "< /TD >" & _
"< /TR > " _
)
objRS.MoveNext
Loop
Response.Write("< /TABLE >")
End If

objRS.Close
objConn.Close
Set objRS = Nothing
Set objConn = Nothing

Response.Write("< /BODY >< /HTML >")
% >

　　 下面是測試結果：

　　 我們來看一下各欄數位含義：
0返回0個記錄的頁面所需要的TTLB（毫秒）。在所有的測試中，該值被視為產生頁面本身（包括建立對象）的時間開銷，不包含逐一查看記錄集資料的時間。
25以毫秒計的提取和顯示25個記錄的TTLB
tot time/25"25"欄的TTLB除以25，它是每個記錄的總計平均時間開銷。
disp time/25"25"欄的TTLB減去"0"欄的TTLB，然後除以25。該值反映了在迴圈記錄集時顯示單個記錄所需時間。
250提取和顯示250個記錄的TTLB。
tot time/250"250"欄的TTLB除以25，該值代表單個記錄的總計平均時間開銷。
disp time/250"250"欄的TTLB減去"0"欄的TTLB，再除以250。該值反映了在迴圈記錄集時顯示單個記錄所需時間。

　　 上面的測試結果將用來同下一個測試結果比較。
四、是否應該通過包含引用ADOVBS.inc？

　　 Microsoft提供的ADOVBS.inc包含了270行代碼，這些代碼定義了大多數的ADO屬性常量。我們這個樣本只從ADOVBS.inc引用了2個常量。因此本次測試（ADO__02.asp）中我們刪除了包含檔案引用，設定屬性時直接使用相應的數值。

objRS.CursorType = 0?' adOpenForwardOnly
objRS.LockType = 1' adLockReadOnly


　　 可以看到頁面開銷下降了23%。該值並不影響單個記錄的提取和顯示時間，因為這裡的變化不會影響迴圈內的記錄集操作。有多種方法可以解決ADOVBS.inc的引用問題。我們建議將ADOVBS.inc檔案作為參考，設定時通過注釋加以說明。請記住，正如第一部分所指出的，適度地運用注釋對代碼的效率影響極小。另外一種方法是將那些需要用到的常量從ADOVBS.inc檔案拷貝到頁面內。

　　 還有一個解決該問題的好方法，這就是通過連結ADO類型庫使得所有的ADO常量直接可用。把下面的代碼加入Global.asa檔案，即可直接存取所有的ADO常量：

< !--METADATA TYPE="typelib"
FILE="C:Program FilesCommon FilesSYSTEMADOmsado15.dll"
NAME="ADODB Type Library" -- >

或者：

< !--METADATA TYPE="typelib"
UUID="00000205-0000-0010-8000-00AA006D2EA4"
NAME="ADODB Type Library" -- >

　　 因此，我們的第一條規則為：

l避免包含ADOVBS.inc檔案，通過其他方法訪問和使用ADO常量。
五、使用記錄集時是否應該建立單獨的連線物件？

　　 要正確地回答這個問題，我們必須分析兩種不同條件下的測試：第一，頁面只有一個資料庫事務；第二，頁面有多個資料庫事務。

　　 在前例中，我們建立了一個單獨的Connection對象並將它賦給Recordset的ActiveConnection屬性。然而，如ADO__03.asp所示，我們也可以直接把串連串賦給ActiveConnection屬性，在指令碼中初始化和配置Connection對象這一額外的步驟可以省去。

objRS.ActiveConnection = Application("Conn")

　　 雖然Recordset對象仍舊要建立一個串連，但此時的建立是在高度最佳化的條件下進行的。因此，與上一次測試相比，頁面開銷又下降了23%，而且如預期的一樣，單個記錄的顯示時間沒有實質的變化。

　　 因此，我們的第二個規則如下：

l如果只使用一個記錄集，直接把串連串賦給ActiveConnection屬性。

　　 接下來我們檢查頁面用到多個記錄集時，上述規則是否仍舊有效。為測試這種情形，我們引入一個FOR迴圈將前例重複10次。在這個測試中，我們將研究三種變化：

　　 第一，如ADO__04.asp所示，在每一個迴圈中建立和拆除Connection對象：

Dim i
For i = 1 to 10

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("Conn")

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = objConn
objRS.CursorType = 0 'adOpenForwardOnly
objRS.LockType = 1 'adLockReadOnly
objRS.Open Application("SQL")
If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
'write data
...
End If

objRS.Close
Set objRS = Nothing
objConn.Close
Set objConn = Nothing

Next

　　 第二，如ADO__05.asp所示，在迴圈外面建立Connection對象，所有記錄集共用該對象：

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("Conn")

Dim i
For i = 1 to 10
Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = objConn
objRS.CursorType = 0 'adOpenForwardOnly
objRS.LockType = 1 'adLockReadOnly
objRS.Open Application("SQL")

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
'write data
...
End If

objRS.Close
Set objRS = Nothing

Next
objConn.Close
Set objConn = Nothing

　　 第三，如ADO__06.asp所示，在每一個迴圈內把串連串賦給ActiveConnection屬性：

Dim i
For i = 1 to 10

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = Application("Conn")
objRS.CursorType = 0 'adOpenForwardOnly
objRS.LockType = 1 'adLockReadOnly
objRS.Open Application("SQL")

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
'write data
...
End If

objRS.Close
Set objRS = Nothing
Next


　　 就象我們可以猜想到的一樣，在迴圈內建立和拆除連線物件是效率最差的方法。不過，令人驚異的是，在迴圈內直接把串連串賦給ActiveConnection屬性只比共用單個連線物件稍微慢了一點。

　　 儘管如此，第三規則應該為：

l同一頁面內用到多個記錄集時，建立單一的連線物件並通過ActiveConnection屬性共用它。
六、哪種遊標類型和記錄鎖定方式效率最高？

　　 迄今為止的所有測試中我們只使用了“只能向前”的遊標來訪問記錄集。ADO為記錄集提供的遊標還有三種類型：靜態可滾動的遊標，動態可滾動的遊標，鍵集遊標。每種遊標都提供不同的功能，比如訪問前一記錄和後一記錄、是否可以看到其他程式對資料的修改等。不過，具體討論每一種遊標類型的功用已經超出了本文的範圍，下表是各種遊標類型的一個比較性的分析。

　　 和“只能向前”類型的遊標相比，所有其它的遊標類型都需要額外的開銷，而且這些遊標在迴圈內一般也要慢一些。因此，我們願與您共用如下告誡：永遠不要這樣認為——“唔，有時候我會用到動態資料指標，那麼我就一直使用這種遊標吧。”

　　 同樣的看法也適用於記錄鎖定方式的選擇。前面的測試只用到了唯讀加鎖方式，但還存在其他三種方式：保守式、開放式、開放式批處理方式。和遊標類型一樣，這些鎖定方式為處理記錄集資料提供了不同的功能和控制能力。

　　 我們得出如下規則：

l使用適合於處理任務的最簡單的遊標類型和記錄鎖定方式。
七、最好用哪種方法提取記錄集？

　　 到目前為止我們一直通過建立Recordset對象提取記錄集，但是ADO也提供了間接的記錄集提取方法。下面的測試比較ADO__03.asp和直接從Connection對象建立記錄集（CONN_01.asp）這兩種方法：

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("Conn")

Set objRS = objConn.Execute(Application("SQL"))

　　 可以看到頁面開銷略有增加，單個記錄的顯示時間沒有變化。

　　 下面我們再來看看從Command對象直接建立記錄集對象（CMD__02.asp）：

Set objCmd = Server.CreateObject("ADODB.Command")
objCmd.ActiveConnection = Application("Conn")
objCmd.CommandText = Application("SQL")

Set objRS = objCmd.Execute

　　 同樣，頁面開銷也略有增加，而單個記錄的顯示時間沒有本質的變化。後面這兩種方法在效能上的差異很小，但我們還有一個重要的問題需要考慮。

　　 通過Recordset類建立記錄集時，我們能夠以最大的靈活性控制記錄集的處理方式。既然後面兩種方法未能有壓倒性的效能表現，我們主要還是考慮預設返回的遊標類型和記錄鎖定方式，對於某些場合來說預設值並不一定是最理想的。

　　 因此，除非由於特殊的原因需要選擇後面兩種方法，否則我們建議考慮下面的規則：

l通過ADODB.Recordset類執行個體化記錄集，以獲得最好的效能和靈活性。

八、是否應該使用本地記錄集？

　　 ADO允許使用本地（用戶端）記錄集，此時查詢將提取記錄集內的所有資料，查詢完成後串連可以立即關閉，以後使用本地的遊標訪問資料，這為釋放串連帶來了方便。使用本地記錄集對於訪問那些要求資料離線使用的遠端資料服務非常重要，那麼，對於普通的應用它是否同樣有所協助？

　　 下面我們加入CursorLocation屬性，並在開啟記錄集之後關閉了串連（CLIENT1.asp）：

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.CursorLocation = 2' adUseClient
objRS.ActiveConnection = Application("Conn")
objRS.LockType = 1?' adLockReadOnly
objRS.Open Application("SQL")
objRS.ActiveConnection = Nothing

　　 理論上，這種方法由於以下兩個原因會對效率有所好處：第一，它避免了在記錄之間移動時重複地通過串連請求資料；第二，由於能夠方便地釋放串連，它減輕了資源需求。然而，從上表看起來使用本地記錄集對提高效率顯然沒有什麼協助。這或許是因為使用本地記錄集時，不管程式設定的是什麼，遊標總是變成靜態類型。

　　 第6個規則如下：

l除非確實要求記錄集本地化，否則應避免使用。
十、用哪種方法引用記錄集欄位值效率最高？

　　 10.1 測試

　　 至此為止我們一直通過名字引用記錄集中的欄位值。由於這種方法要求每次都必須尋找相應的欄位，它的效率並不高。為證明這一點，下面這個測試中我們通過欄位在集合中的索引引用它的值（ADO__08.asp）：

'write data
Do While Not objRS.EOF
Response.Write( _
"< TR >" & _
"< TD >" & objRS(0) & "< /TD >" & _
"< TD >" & objRS(1) & "< /TD >" & _
"< TD >" & objRS(2) & "< /TD >" & _
"< TD >" & objRS(3) & "< /TD >" & _
"< TD >" & objRS(4) & "< /TD >" & _
"< TD >" & objRS(5) & "< /TD >" & _
"< TD >" & objRS(6) & "< /TD >" & _
"< /TR > " _
)
objRS.MoveNext
Loop


　　 和預期的一樣，頁面開銷也有小小的變化（這或許是因為代碼略有減少）。然而，這種方法在顯示時間上的改善是相當明顯的。

　　 在下一個測試中，我們把所有的欄位分別綁定到變數（ADO__09.asp）：

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
Dim fld0
Dim fld1
Dim fld2
Dim fld3
Dim fld4
Dim fld5
Dim fld6
Set fld0 = objRS(0)
Set fld1 = objRS(1)
Set fld2 = objRS(2)
Set fld3 = objRS(3)
Set fld4 = objRS(4)
Set fld5 = objRS(5)
Set fld6 = objRS(6)
'write data
Do While Not objRS.EOF
Response.Write( _
"< TR >" & _
"< TD >" & fld0 & "< /TD >" & _
"< TD >" & fld1 & "< /TD >" & _
"< TD >" & fld2 & "< /TD >" & _
"< TD >" & fld3 & "< /TD >" & _
"< TD >" & fld4 & "< /TD >" & _
"< TD >" & fld5 & "< /TD >" & _
"< TD >" & fld6 & "< /TD >" & _
"< /TR >" _
)
objRS.MoveNext
Loop
Set fld0 = Nothing
Set fld1 = Nothing
Set fld2 = Nothing
Set fld3 = Nothing
Set fld4 = Nothing
Set fld5 = Nothing
Set fld6 = Nothing
Response.Write("< /TABLE >")
End If

　　 這是目前為止最好的記錄。請注意單個記錄的顯示時間已經降低到0.45毫秒以下。

　　 上述指令碼都要求對結果記錄集的構造有所瞭解。例如，我們在欄位標題中直接使用了欄位名字，單獨地引用各個欄位值。下面這個測試中，不僅欄位資料通過遍曆欄位集合得到，而且欄位標題也用同樣的方式得到，這是一種更為動態方案（ADO__10.asp）。

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings Response.Write("< TABLE BORDER=1 >< TR >")
For Each objFld in objRS.Fields
Response.Write("< TH >" & objFld.name & "< /TH >")
Next
Response.Write("< /TR >")
'write data
Do While Not objRS.EOF
Response.Write("< TR >")
For Each objFld in objRS.Fields
? Response.Write("< TD >" & objFld.value & "< /TD >")
Next
Response.Write("< /TR >")
objRS.MoveNext
Loop
Response.Write("< /TABLE >")
End If

　　 可以看到，代碼效能有所下降，但它仍舊要比ADO__07.asp要快。

　　 下一個測試樣本是前面兩個方法的折衷。我們將繼續保持動態特徵，同時通過在動態分配的數組中儲存欄位引用提高效能：

If objRS.EOF Then
Response.Write("No Records Found")
Else
Dim fldCount
fldCount = objRS.Fields.Count
Dim fld()
ReDim fld(fldCount)
Dim i
For i = 0 to fldCount-1
Set fld(i) = objRS(i)
Next

'write headings
Response.Write("< TABLE BORDER=1 >< TR >") For i = 0 to fldCount-1
Response.Write("< TH >" & fld(i).name & "< /TH >")
Next
Response.Write("< /TR >")
'write data
Do While Not objRS.EOF
Response.Write("< TR >")
For i = 0 to fldCount-1
Response.Write("< TD >" & fld(i) & "< /TD >")
Next
Response.Write("< /TR >")
objRS.MoveNext
Loop
For i = 0 to fldCount-1
Set fld(i) = Nothing
Next
Response.Write("< /TABLE >")
End If


　　 雖然還不能超過以前最好的成績，但它比開頭的幾個樣本要快，同時它具有動態地處理任何記錄集這一優點。

　　 與前面的測試代碼相比，下面的測試代碼有了根本性的改動。它使用記錄集對象的GetRows方法填充數組以供逐一查看資料，而不是直接存取記錄集本身。注意在調用GetRows之後立即把Recordset設定成了Nothing，也就是儘快地釋放了系統資源。另外，請注意數組的第一維代表欄位，第二維代表行（ADO__12.asp）。

If objRS.EOF Then
Response.Write("No Records Found")
objRS.Close
Set objRS = Nothing
Else
'write headings
...

'set array
Dim arrRS
arrRS = objRS.GetRows
'close recordset early
objRS.Close
Set objRS = Nothing

'write data
Dim numRows
Dim numFlds
Dim row
Dim fld
numFlds = Ubound(arrRS, 1)
numRows = Ubound(arrRS, 2)
For row= 0 to numRows
Response.Write("< TR >")
For fld = 0 to numFlds
Response.Write("< TD >" & arrRS(fld, row) & "< /TD >")
Next
Response.Write("< /TR >")
Next

Response.Write("< /TABLE >")
End If

　　 使用GetRows方法時，整個記錄集都被提取到了數組。雖然記錄集極端龐大時可能產生資源問題，但是用逐一查看資料的速度確實更快了，這是由於取消了MoveNext和檢查EOF之類的函數調用。

　　 速度是要付出代價的，現在記錄集的中繼資料已經丟失了。為解決這個問題，我們可以在調用GetRows之前從屬記錄集對象提取標題資訊；此外，資料類型和其他資訊也可以預先提取。另外還要注意的是，測試中效能上的優勢只有在記錄集較大的時候才會出現。

　　 這一組的最後一個測試中，我們使用了記錄集的GetString方法。GetString方法將整個記錄集提取成為一個大的字串，並允許指定分隔字元（ADO__13.asp）：

If objRS.EOF Then
Response.Write("No Records Found")
objRS.Close
Set objRS = Nothing
Else
'write headings
...
'set array
Dim strTable
strTable = objRS.GetString (2, , "</TD><TD>", "</TD></TR><TR><TD>")
'close recordset early
objRS.Close
Set objRS = Nothing
Response.Write(strTable & "</TD></TR></TABLE>")
End If

　　 雖然這種方法在速度上的好處非常明顯，但它只適用於最簡單的操作，根本無法適應稍微複雜的資料操作要求。