首頁 > 開發者 > ASP

ASP編程入門進階（十）：Global.asa檔案

來源：互聯網
上載者：User
創建阿里雲帳戶，並獲得超過 40 款產品的免費試用版；而企業帳戶則可以享有總值 $1200 的免費試用版。立即註冊！

我們已經知道Application和Session對象的OnStart、OnEnd事件的指令碼，都必須是在 Global.asa 檔案中聲明的。那究竟Global.asa是什麼樣的一個檔案？它的作用有何？又該如何運用呢？且聽我慢慢道來。

首先.asa是檔案尾碼名，它是Active Server Application的首字母縮寫。Global.asa檔案可以管理在ASP應用中兩個非常苛刻的對象：Application、Session。

它其實是一個可選檔案，程式編寫者可以在該檔案中指定事件指令碼，並聲明具有會話和Application 領域的對象。該檔案的內容不是用來給使用者顯示的，而是用來儲存事件資訊和由應用程式全域使用的對象。該檔案必須存放在應用程式的根目錄內。每個應用程式只能有一個Global.asa檔案。

關於Global.asa檔案最常見的錯誤概念是它能為一般的使用的函數和子程式用作書庫。Global.asa檔案僅能用於建立對象的引用和俘獲啟動，以及結束Application對象和Session對象。

Global.asa檔案主要基於會話級事件被訪問，在以下三種情況下被調用：
1，當Application_OnStart或Application_OnEnd事件被觸發。
2，當Session_OnStart或Session_OnEnd事件被觸發。
3，當引用一個在Global.asa檔案裡被執行個體化的對象（Object）。
Global.asa的標準檔案格式如下：

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
Sub Application_OnStart
'Application_OnStart 當任何客戶首次訪問該應用程式的首頁時運行
End Sub

Sub Session_OnStart
'Session_OnStart 當客戶首次運行 ASP 應用程式中的任何一個頁面時運行
End Sub

Sub Session_OnEnd
'Session_OnEnd 當一個客戶的會話逾時或退出應用程式時運行
End Sub

Sub Application_OnEnd
'Application_OnEnd 當該網站的 WEB 伺服器關閉時運行
End Sub
</SCRIPT>

一、Session_onStart
先看一個控制使用者進入頁面的代碼：
1，Global.asa（放在被調試的虛擬目錄的根目錄下面）

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
Sub Session_OnStart '只要是使用者第一次登入本站，則會跳轉到首頁
response.redirect("htp://www.cnbruce.com/")
End Sub
</SCRIPT>

然後調試當前虛擬目錄下的任何檔案，你會發現所有頁面都跳轉向htp://www.cnbruce.com/
通過此“強制進入某頁”的例子，可以想象當首頁需要被關注的時候是非常有必要的。

下面就以一個“線上人數”的例子來繼續觀察Session_OnStart和Session_OnEnd事件

二、Session_onEnd
2，Global.asa（放在被調試的虛擬目錄的根目錄下面）

<SCRIPT LANGUAGE=VBScript RUNAT=Server>
Sub Application_onStart '初始值為0
Application("OnLine") = 0
End Sub

Sub Session_onStart '一個使用者訪問進行記數加1
Application.Lock
Application("OnLine") = Application("OnLine") + 1
Application.Unlock
End Sub

Sub Session_OnEnd '一個使用者進程的結束，記數減1 （P.S.如果沒有該事件程式，則執行的就是頁面訪問程式了。）
Application.Lock
Application("OnLine") = Application("OnLine") - 1
Application.Unlock
End Sub
</SCRIPT>

3，online.asp

<%
if request.querystring("logout")="true" then
session.Abandon()
response.end
end if
%>
當前共有<%=Application("OnLine")%>線上
<a href="online.asp?logout=true">退出</a>

你發現在該頁中只有一個Application("OnLine")，而且還是被顯示引用的。那麼其值來自何方？這正是Global.asa檔案的關鍵所在。
你可以在本機依次開啟個視窗，進行進行關閉視窗或退出兩種方法的調試。

三、繼續細化一下
上面的程式你會發現：當進行“退出”串連後關閉視窗和直接關閉視窗效果是不一樣的。因為Session存在時間的緣故，當直接進行關閉視窗，並不能觸發Session_OnEnd事件，所以該如何?這個幾乎不可能的想法呢？

大家都知道，當網頁進行關閉的時候可以連帶一個onunload事件，那麼該onunload只要能執行Session的登出功能不就我們需要的嗎？廢話少說，將online.asp進行修改

3，online.asp

<%
if request.querystring("logout")="true" then
session.Abandon()
response.end
end if
%>
<body onunload=javascript:window.open("exit.asp")>
當前共有<%=Application("OnLine")%>線上
<a href="online.asp?logout=true">退出</a>

注意，online.asp進行onunload的時候會開啟exit.asp，那隻要在exit.asp中再設定session.Abandon()不就OK了。

4，exit.asp

<%session.Abandon()%>
<script>
self.close()
</script>

當然，加了段Script指令碼，目的是進行Session的登出以後立即進行關閉本身。
那現在基本一個線上統計的Web應用就可以了。

四、深入研究Global.asa
從上面的調試中，舉一反三的你，一定會提出一個問題：如何控制註冊使用者線上人數？
那下面幾個檔案一個一個看：

5，Global.asa（放在被調試的虛擬目錄的根目錄下面）

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
Sub Application_OnStart
application("online")=0
End Sub

Sub Session_OnStart
End Sub

Sub Session_OnEnd
if session.contents("pass") then '判斷是否為登入使用者的Session_OnEnd
application.lock
application("online")=application("online")-1
application.unlock
end if
End Sub

Sub Application_OnEnd
End Sub
</SCRIPT>

注意本Global.asa中的Session_OnStart塊不做任何事件。

因為一旦有使用者訪問伺服器而不管使用者是否登入，都會產生OnStart事件，而現在需要的只是登入使用者的線上，所以不能在OnStart事件裡使Applicaiton("online")加1。

又因為不管是否是登入使用者的會話結束都會產生OnEnd事件（假如有訪客訪問了伺服器但並不登入，他的會話結束後也會產生OnEnd事件），所以在Session_OnEnd事件裡用了句if語句來判斷是否為已登入使用者的OnEnd事件，如果是才將線上人數減1。

並且值得注意的是：session.contents("pass")的使用，因為在OnEnd事件裡禁止使用Session對象，但是可以用Session對象的集合來調用session變數。也就是說不能直接寫session("pass")，而是需要寫session.contents("pass")。

6，login.asp

<%
if request.querystring("logout")="true" then
session.Abandon()
end if
submitname=request.form("submit")
if submitname="submit" then
name=request.form("name")
pwd=request.form("pwd")
if name="cnbruce" and pwd="cnrose" then
session("name")=name
session("pass")=true
else
response.write "Error Name Or Pwd.<a href='login.asp'>Back</a>"
response.end
end if
application.lock
application("online")=application("online")+1
application.unlock
%>
當前註冊會員<%=application("online")%>人。
<a href="login.asp?logout=true">退出</a>
<%else%>
<form action="login.asp" method="post">
<input type="text" name="name"><br>
<input type="password" name="pwd"><br>
<input type="submit" name="submit" value="submit">
<%end if%>

只是簡單地檢測用名是cnbruce，密碼是cnrose的時候，產生一個session("pass")=true，就是放在Global.asa中判斷的。

五，繼續發揮想象
想想，再想想。僅僅統計有多少人線上是不夠的，還要判斷使用者的線上狀態。
可以想象辦法基本，當使用者登入的時候，在login.asp裡將online設為1（如果有資料庫則上傳），但使用者離線時將online設為0，要完善它，就要修改一下Session_OnEnd事件，在該事件裡將online設為0（同樣將為0的值上傳）……

當然，Global.asa遠遠不止這些。不過我們現在先不著急全部掌握，當我們接觸到資料庫的時候再返回過來看，繼續研究該檔案，相信到那時一定又會感悟到很多。所以，還是先把上面的這些吃透吧：）

本文章原先以中文撰寫並發佈於 aliyun.com，亦設英文版本，僅作資訊用途。本網站不對文章的準確性，完整性或可靠性或其任何翻譯作出任何明示或暗示的陳述或保證。如對該文章有任何疑慮或投訴，請傳送電郵至 info-contact@alibabacloud.com 並提供相關疑慮或投訴的詳細說明。職員會於 5 個工作天內與您聯絡，一經驗證之後，即會刪除該侵權內容。

相關關鍵詞：
asp or asp net asp to asp net asp net and asp asp language asp tags newline asp substring asp
相關文章
ASP學習總結：錯誤碼
反爬蟲：利用ASP.NET MVC的Filter和緩衝（入坑出坑）
ASP.NET Core 2.0利用MassTransit整合RabbitMQ
實戰中的asp.net core結合Consul叢集&Docker實現服務治理
asp DateDiff實現文字在特定時間後消失
設定和讀取ASP.Net全域變數的方法

聯繫我們

該頁面正文內容均來源於網絡整理，並不代表阿里雲官方的觀點，該頁面所提到的產品和服務也與阿里云無關，如果該頁面內容對您造成了困擾，歡迎寫郵件給我們，收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容，歡迎發送郵件至： info-contact@alibabacloud.com 進行舉報並提供相關證據，工作人員會在 5 個工作天內聯絡您，一經查實，本站將立刻刪除涉嫌侵權內容。

熱門內容

A Free Trial That Lets You Build Big!

Start building with 50+ products and up to 12 months usage for Elastic Compute Service

Get Started for Free

  • Sales Support

    1 on 1 presale consultation

    Chat Contact Sales

  • After-Sales Support

    24/7 Technical Support 6 Free Tickets per Quarter Faster Response

    Open a Ticket

  • Alibaba Cloud offers highly flexible support services tailored to meet your exact needs.

    Learn More