asp+Access通用的自動替換資料庫中的字串_應用技巧

當初只是為了玩玩寫的，沒想到寫了之後不斷有人詢問，所以改寫了一下代碼，完善了一下，支援了正則替換，避開了會導致出錯的二進位（ole對象），並且做了一個EXE的程式。感謝虛擬幫忙。
附asp代碼：

複製代碼 代碼如下:

<%    
'####################################    
'批量替換資料庫內容2008-3-17     
'替換是無法復原的，所以操作前做好能備份    
'####################################    
Dim Db,conn,Rs1,Rs2,Str1,Str2,I,Re    
str1="admi[0-z]" '要替換的字串，支援正則    
str2="1234" '替換為的字串    
Db="db.mdb" '資料庫地址    
'以下無需改動    
'建立正則對象    
Set Re=new RegExp    
    Re.IgnoreCase =True   
    Re.Global=True   
Set Conn=Server.CreateObject("ADODB.Connection")    
    Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&server.mappath(Db)    
Set Rs1 = Conn.OpenSchema(20)    
    Do While Not Rs1.Eof    
        If UCase(Rs1("TABLE_TYPE"))="TABLE" Then '如果是使用者表,則進行操作    
          Set Rs2=Server.Createobject("adodb.recordset")    
              Rs2.Open "select * from ["&Rs1("TABLE_NAME")"]",conn,1,3    
              Do While Not Rs2.Eof    
                For I=0 to Rs2.fields.count-1 '遍曆所有欄位    
                    If Rs2(i).Properties("ISAUTOINCREMENT") = False And Rs2(i).Type<>128 And Rs2(i).Type<>204 And Rs2(i).Type<>205 Then '如果非自動編號並且非ole對象    
                        Rs2(Rs2(i).name)=Myreplace(Rs2(i).value&"")    
                    End If   
                Next   
             Rs2.Movenext    
             Loop   
        Rs2.Close    
        Set Rs2=nothing    
        End If   
    Rs1.MoveNext    
    Loop   
Rs1.Close    
Set Rs1=Nothing   
Conn.close    
Set Conn=Nothing   
Set Re=Nothing   
Response.Write "替換完成"   

'自訂的替換函數    
Function myreplace(byval Tstr)    
If Tstr="" Or isnull(Tstr) Then     
 Exit Function   
Else   
    Re.Pattern=Str1    
    myReplace =Re.Replace(Tstr,Str2)    
End If   
End Function   
%>