VBS 修改遠端桌面連接埠號碼的代碼

複製代碼 代碼如下:'===========================================================================================
CheckOS ' 檢查作業系統版本
CheckMeState ' 檢查程式運行狀態
main ' 執行主程式

Sub main()
Dim PortNumberOld, PortNumberNew
Set wso = CreateObject("WScript.Shell")

PortNumberOld = regKeyRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp\PortNumber")
PortNumberNew = Trim( Inputbox( "請輸入一個連接埠號碼：", "修改遠端桌面連接埠", PortNumberOld ) )

If PortNumberNew = "" Then Exit Sub
If Not ( ( IsNumeric( PortNumberNew ) = True ) And ( PortNumberOld <> PortNumberNew ) And _
( PortNumberNew > 0 ) And ( PortNumberNew < 65535 ) ) Then
wso.popup "輸入錯誤，請重試！", 5 , "錯誤：修改失敗", 16+4096 ' 提示資訊
Exit Sub
End If

wso.RegWrite "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp\PortNumber", PortNumberNew, "REG_DWORD"
wso.RegWrite "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp\PortNumber", PortNumberNew, "REG_DWORD"

PortNumberOld = regKeyRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp\PortNumber")
If CLng( PortNumberOld ) = CLng( PortNumberNew ) Then
wso.popup "修改成功，請重啟電腦！", 5 , "提示：修改成功", 64+4096
Else
wso.popup "修改失敗，你可能沒有許可權！", 5 , "警告：修改失敗", 48+4096
End If
Set wso = Nothing
End Sub

'===========================================================================================
'小函數
Function Exist( strPath )
'On Error Resume Next
Set fso = CreateObject("Scripting.FileSystemObject")
If ((fso.FolderExists( strPath )) Or (fso.FileExists( strPath ))) then
Exist = True
Else
Exist = False
End if
Set fso = Nothing
End Function
Sub Move( strSource, strDestination )
On Error Resume Next
If Exist( strSource ) Then
Set fso = CreateObject("Scripting.FileSystemObject")
If (fso.FileExists(strSource)) Then fso.MoveFile strSource, strDestination
If (fso.FolderExists(strSource)) Then fso.MoveFolder strSource, strDestination
Set fso = Nothing
Else
WarningInfo "警告", "找不到 " & strSource & " 檔案！", 2
End If
If Not Exist( strDestination ) Then WarningInfo "警告", "移動失敗，無法移動 " & VbCrLf & strSource & " 至" & VbCrLf & strDestination, 2
End Sub
Sub RunHideNotWait( strCmd )
'On Error Resume Next
Set wso = CreateObject("WScript.Shell")
wso.Run strCmd, 0, False
Set wso = Nothing
End Sub
Function regKeyRead( strKey )
On Error Resume Next
Set wso = CreateObject("WScript.Shell")
regKeyRead = wso.RegRead( strKey ) 'strKey = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\DocTip"
Set wso = Nothing
End Function

'===========================================================================================
'是否重複運行
Sub CheckMeState()
If IsRun( WScript.ScriptFullName ) Then
Set wso = CreateObject("WScript.Shell")
If wso.Popup("程式已運行，請不要重複運行本程式！" & VbCrLf & VbCrLf & _
"退出已運行程式，請按“確定”，否則請按“取消”。(3秒後自動取消)" _
, 3, "警告", 1) = 1 Then
KillMeAllRun
End If
Set wso = Nothing
'WarningInfo "警告：", "程式已運行，請不要重複運行本程式！！", 1
WScript.Quit
End If
End Sub
' 檢測是否重複運行
Function IsRun(appPath)
IsRun=False
For Each ps in GetObject("winmgmts:\\.\root\cimv2:win32_process").instances_
'IF Lcase(ps.name)="mshta.exe" Then
IF Lcase(ps.name)="wscript.exe" Then
IF instr(Lcase(ps.CommandLine),Lcase(appPath)) Then i=i+1
End IF
next
if i>1 then
IsRun=True
end if
End Function
'終止自身
Function KillMeAllRun()
Dim MeAllPid
Set pid = Getobject("winmgmts:\\.").InstancesOf("Win32_Process")
For Each ps In pid
'if LCase(ps.name) = LCase("mshta.exe") then
IF Lcase(ps.name)="wscript.exe" Or Lcase(ps.name)="cscript.exe"Then
IF instr(Lcase(ps.CommandLine),Lcase(WScript.ScriptFullName)) Then MeAllPid = MeAllPid & "/PID " & ps.ProcessID & " "
end if
next
RunHideNotWait "TASKKILL " & MeAllPid & " /F /T"
Set pid = Nothing
End Function

'===========================================================================================
'檢查作業系統版本
Sub CheckOS()
Dim os_ver
os_ver = GetSystemVersion
If os_ver >= 60 Or os_ver <= 50 Then
Msgbox "不支援該作業系統！　　　　", 48+4096, "警告"
WScript.Quit ' 退出程式
End If
End Sub
'取得作業系統版本
Function GetSystemVersion()
Dim os_obj, os_version, os_version_arr
Set os_obj = GetObject("winmgmts:").InstancesOf("Win32_OperatingSystem")
For Each os_info In os_obj
os_version = os_info.Version
If os_version <> "" Then Exit For
Next
Set os_obj = Nothing
os_version_arr = Split( os_info.Version, ".")
GetSystemVersion = Cint( os_version_arr( 0 ) & os_version_arr( 1 ) )
End Function