web|列印|列印報表|解決 <%@ LANGUAGE="VBSCRIPT" %>
<%
' = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
' 從ADO Recordset直接產生報表
' = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
'
' 概念:
'
' 這個應用被設計成示範怎樣從ADO Recordset產生報表。我們首先建立ADO Connection和
' Recordset對象，然後用SQL語句從資料庫中產生一個記錄集。然後我們建立一個Crystal
' Reports對象，並把這個這個對象指向ADO recordset。最後我們將Crystal Reports
' Smart Viewer送到用戶端顯示這個報表。
' 第一步：建立ADO Connection and Recordset
' 一個ADO的資料庫連接就是通過你已經存在的ODBC資料來源（DSN）從象ASP這樣的應用中來訪問
' 資料的串連。為了達到這個例子的目的，我們將使用到用一個叫做"Xtreme Sample Data"的
' 連到Access資料庫Xtreme.mdb系統DSN
' 建立ADO資料庫連接:
Set oConn = Server.CreateObject("ADODB.Connection")
'這裡建立叫做"oConn"的ADO connection，我們將用這個ADO connection對象串連到上述的DSN
'用 ADO connection 必須先要開啟它:
oConn.Open("Xtreme Sample Database")
'這裡開啟我們的ODBC的資料來源，這個資料來源指向Access資料庫Xtreme.mdb
'現在我們必須建立一個RecordSet對象：
set session("oRs") = Server.CreateObject("ADODB.Recordset")
'在上面我們建立了一個session("oRs"). 這個session中存放一個RecordSet對象
'將要包含用SQL語句返回的資料
'定義和產生 recordset:
session("oRs").ActiveConnection = oConn
'定義這個recordset將要使用的Connection 對象
session("oRs").Open "SELECT [Product ID], [Product Name] FROM Product"
'用SQL語句從Xtreme.mdb庫的"Product"表中取出兩個欄位
'===================================================================================
'建立Crystal Reports 對象
'===================================================================================
'你可能注意到，Crystal Reports對象被設為session，這是因為已經需求就會被一個叫做
'"rptserver.asp"的ASP處理，為了讓rptserver.asp能非常容易地訪問Crystal Report對象，
'我們把這些對象都設為session。這樣任何ASP頁都運行在這個session中，都能夠直接存取這些對象
reportname = "ADORecordset.rpt"
'這裡建立一個字串變數，指向Crystal Report檔案(.rpt file)，再用這段代碼的時候
'換成你的Crystal Report檔案名稱。
'建立APPLICATION 對象
If Not IsObject (session("oApp")) Then
Set session("oApp") = Server.CreateObject("CrystalRuntime.Application")
End If
'這個"if/end if" 結構用來每個session只建立一次 Crystal Reports Application對象o
'建立application對象 - session("oApp")，將Crystal Report Design Component
'automation server (craxdrt.dll)載入記憶體。
'
'我們建立session變數是為了再asp session過程中都使用它們.這樣可以減少將craxdrt.dll
'載入和卸載的系統開銷。在一個session中一旦建立了一個application對象我們就可以不必
'重建對象運行更多的報表 。
' 建立REPORT 對象
'
'這個REPORT 對象被Application的OpenReport方法建立
Path = Request.ServerVariables("PATH_TRANSLATED")
While (Right(Path, 1) <> "\" And Len(Path) <> 0)
iLen = Len(Path) - 1
Path = Left(Path, iLen)
Wend
response.Write path
'這個"While/Wend" 迴圈被用來將當前檔案從虛擬路徑(eg: http://Domain/Dir)轉換成Crystal
' Report file的實體路徑(eg: C:\)
'開啟REPORT (先清除以前的任何對象)
If IsObject(session("oRpt")) then
Set session("oRpt") = nothing
End if
On error resume next
Set session("oRpt") = session("oApp").OpenReport(path & reportname, 1)
'這裡用"PATH" 和 "reportname"變數計算出Crystal Report file的實體路徑, 並開啟它。
If Err.Number <> 0 Then
Response.Write "Error Occurred creating Report Object: " & Err.Description
Set Session("oRpt") = nothing
Set Session("oApp") = nothing
Session.Abandon
Response.End
End If
'這個 On erro resume next 塊檢查在建立report對象時出現的任何錯誤，我們正明確的捕獲任何
'錯誤如果視圖超過許可協議規定的最大並發使用者數。
'注意，我們並不只建立一次report對象。這是因為有了ASP session 你可以處理更多的超過一個報表
' rptserver.asp將僅僅處理一個叫session("oRpt")的report對象。因此，你如果希望處理多個報表
'的話，就要建立一個新的session("oRpt")對象。
session("oRpt").MorePrintEngineErrorMessages = False
session("oRpt").EnableParameterPrompting = False
'這裡不允許錯誤報表機制，包括Crystal Report Design Component automation server (craxdrt.dll)
'內建的錯誤報表，這是因為兩個原因：
'1. 列印引擎是在Web Server上執行的, 所以任何錯誤資訊都將被顯示在服務端，如果在服務端報告出錯了，
' 列印引擎將停止運作，你的應用將被“掛起”
'2. rptserver.asp 已經有一些錯誤處理邏輯在裡面了，可以捕獲任何非致命錯誤，並顯示在用戶端。
'
'**重要** 即使我們禁止了服務端引擎的錯誤處理，但是致命錯誤還是會在Web Server服務端被捕獲，並
'顯示出錯誤提示對話方塊。所以我們建議，你在"World Wide Web Publishing" service (IIS service)設定
'"Allow Service to Interact with Desktop"選項。這樣如果你的ASP應用死了，你將能看到錯誤提示。
'========================================================================
