Database Backup/恢複方案

來源:互聯網
上載者:User
備份|恢複|資料|資料庫
利用SQL語言,實現資料庫的備份/恢複的功能

體現了SQL Server中的四個知識點:

1.   擷取SQL Server伺服器上的預設目錄

2.   備份SQL語句的使用

3.   恢複SQL語句的使用,同時考慮了強制恢複時關閉其他使用者進程的處理

4.   作業建立SQL語句的使用

 

/*1.--得到資料庫的檔案目錄
 
 @dbname 指定要取得目錄的資料庫名
   如果指定的資料不存在,返回安裝SQL時設定的預設資料目錄
   如果指定NULL,則返回預設的SQL備份目錄名
----*/

/*--調用樣本
 select 資料庫檔案目錄=dbo.f_getdbpath('tempdb')
  ,[預設SQL SERVER資料目錄]=dbo.f_getdbpath('')
  ,[預設SQL SERVER備份目錄]=dbo.f_getdbpath(null)
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_getdbpath]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_getdbpath]
GO

create function f_getdbpath(@dbname sysname)
returns nvarchar(260)
as
begin
 declare @re nvarchar(260)
 if @dbname is null or db_id(@dbname) is null
  select @re=rtrim(reverse(filename)) from master..sysdatabases where name='master'
 else
  select @re=rtrim(reverse(filename)) from master..sysdatabases where name=@dbname

 if @dbname is null
  set @re=reverse(substring(@re,charindex('\',@re)+5,260))+'BACKUP'
 else
  set @re=reverse(substring(@re,charindex('\',@re),260))
 return(@re)
end
go



/*2.--備份資料庫--*/

/*--調用樣本

--備份當前資料庫
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_db.bak'

--差異備份當前資料庫
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_df.bak',@bktype='DF'

--備份當前資料庫日誌
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_log.bak',@bktype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_backupdb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_backupdb]
GO

create proc p_backupdb
@dbname sysname='',   --要備份的資料庫名稱,不指定則備份當前資料庫
@bkpath nvarchar(260)='', --備份檔案的存放目錄,不指定則使用SQL預設的備份目錄
@bkfname nvarchar(260)='', --備份檔案名,檔案名稱中可以用\DBNAME\代表資料庫名,\DATE\代表日期,\TIME\代表時間
@bktype nvarchar(10)='DB', --備份類型:'DB'備份資料庫,'DF' 差異備份,'LOG' 記錄備份
@appendfile bit=1   --追加/覆蓋備份檔案
as
 declare @sql varchar(8000)
 if isnull(@dbname,'')='' set @dbname=db_name()
 if isnull(@bkpath,'')='' set @bkpath=dbo.f_getdbpath(null)
 if isnull(@bkfname,'')='' set @bkfname='\DBNAME\_\DATE\_\TIME\.BAK'
 set @bkfname=replace(replace(replace(@bkfname,'\DBNAME\',@dbname)
  ,'\DATE\',convert(varchar,getdate(),112))
  ,'\TIME\',replace(convert(varchar,getdate(),108),':',''))
 set @sql='backup '+case @bktype when 'LOG' then 'log ' else 'database ' end +@dbname
  +' to disk='''+@bkpath+@bkfname
  +''' with '+case @bktype when 'DF' then 'DIFFERENTIAL,' else '' end
  +case @appendfile when 1 then 'NOINIT' else 'INIT' end
 print @sql
 exec(@sql)
go

 

/*3.--恢複資料庫--*/

/*--調用樣本
--完整恢複資料庫
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db'

--差異備份恢複
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_df.bak',@dbname='db',@retype='DF'

--記錄備份恢複
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

create proc p_RestoreDb
@bkfile nvarchar(1000),  --定義要恢複的備份檔案名
@dbname sysname='',      --定義恢複後的資料庫名,預設為備份的檔案名稱
@dbpath nvarchar(260)='', --恢複後的資料庫存放目錄,不指定則為SQL的預設資料目錄
@retype nvarchar(10)='DB', --恢複類型:'DB'完事恢複資料庫,'DBNOR' 為差異恢複,日誌恢複進行完整恢複,'DF' 差異備份的恢複,'LOG' 日誌恢複
@filenumber int=1,   --恢複的檔案號
@overexist bit=1,        --是否覆蓋已經存在的資料庫,僅@retype為
@killuser bit=1       --是否關閉使用者使用進程,僅@overexist=1時有效
as
declare @sql varchar(8000)

--得到恢複後的資料庫名
if isnull(@dbname,'')=''
 select @sql=reverse(@bkfile)
  ,@sql=case when charindex('.',@sql)=0 then @sql
   else substring(@sql,charindex('.',@sql)+1,1000) end
  ,@sql=case when charindex('\',@sql)=0 then @sql
   else left(@sql,charindex('\',@sql)-1) end
  ,@dbname=reverse(@sql)

--得到恢複後的資料庫存放目錄
if isnull(@dbpath,'')='' set @dbpath=dbo.f_getdbpath('')

--產生資料庫恢複語句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
 +' from disk='''+@bkfile+''''
 +' with file='+cast(@filenumber as varchar)
 +case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
 +case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end
print @sql
--添加移動邏輯檔案的處理
if @retype='DB' or @retype='DBNOR'
begin
 --從備份檔案中擷取邏輯檔案名稱
 declare @lfn nvarchar(128),@tp char(1),@i int

 --建立暫存資料表,儲存擷取的資訊
 create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
 --從備份檔案中擷取資訊
 insert into #tb exec('restore filelistonly from disk='''+@bkfile+'''')
 declare #f cursor for select ln,tp from #tb
 open #f
 fetch next from #f into @lfn,@tp
 set @i=0
 while @@fetch_status=0
 begin
  select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
   +case @tp when 'D' then '.mdf''' else '.ldf''' end
   ,@i=@i+1
  fetch next from #f into @lfn,@tp
 end
 close #f
 deallocate #f
end

--關閉使用者進程處理
if @overexist=1 and @killuser=1
begin
 declare @spid varchar(20)
 declare #spid cursor for
  select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
 open #spid
 fetch next from #spid into @spid
 while @@fetch_status=0
 begin 
  exec('kill '+@spid)
  fetch next from #spid into @spid
 end 
 close #spid
 deallocate #spid
end

--恢複資料庫
exec(@sql)

go

/*4.--建立作業--*/

/*--調用樣本

--每月執行的作業
exec p_createjob @jobname='mm',@sql='select * from syscolumns',@freqtype='month'

--每周執行的作業
exec p_createjob @jobname='ww',@sql='select * from syscolumns',@freqtype='week'

--每日執行的作業
exec p_createjob @jobname='a',@sql='select * from syscolumns'

--每日執行的作業,每天隔4小時重複的作業
exec p_createjob @jobname='b',@sql='select * from syscolumns',@fsinterval=4

--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_createjob]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_createjob]
GO

create proc p_createjob
@jobname varchar(100),  --作業名稱
@sql varchar(8000),   --要執行的命令
@dbname sysname='',   --預設為當前的資料庫名
@freqtype varchar(6)='day', --時間周期,month 月,week 周,day 日
@fsinterval int=1,   --相對於每日的重複次數
@time int=170000   --開始執行時間,對於重複執行的作業,將從0點到23:59分
as
if isnull(@dbname,'')='' set @dbname=db_name()

--建立作業
exec msdb..sp_add_job @job_name=@jobname

--建立作業步驟
exec msdb..sp_add_jobstep @job_name=@jobname,
 @step_name = '資料處理',
 @subsystem = 'TSQL',
 @database_name=@dbname,
 @command = @sql,
 @retry_attempts = 5, --重試次數
 @retry_interval = 5  --稍候再試

--建立調度
declare @ftype int,@fstype int,@ffactor int
select @ftype=case @freqtype when 'day' then 4
     when 'week' then 8
     when 'month' then 16 end
 ,@fstype=case @fsinterval when 1 then 0 else 8 end
if @fsinterval<>1 set @time=0
set @ffactor=case @freqtype when 'day' then 0 else 1 end

EXEC msdb..sp_add_jobschedule @job_name=@jobname,
 @name = '時間安排',
 @freq_type=@ftype ,      --每天,8 每周,16 每月
 @freq_interval=1,     --重複執行次數
 @freq_subday_type=@fstype,   --是否重複執行
 @freq_subday_interval=@fsinterval,  --週期
 @freq_recurrence_factor=@ffactor,
 @active_start_time=@time     --下午17:00:00分執行

go


/*--應用案例--備份方案:
完整備份(每個星期天一次)+差異備份(每天備份一次)+記錄備份(每2小時備份一次)

調用上面的預存程序來實現
--*/

declare @sql varchar(8000)
--完整備份(每個星期天一次)
set @sql='exec p_backupdb @dbname=''要備份的資料庫名'''
exec p_createjob @jobname='每周備份',@sql,@freqtype='week'

--差異備份(每天備份一次)
set @sql='exec p_backupdb @dbname=''要備份的資料庫名'',@bktype='DF''
exec p_createjob @jobname='每天差異備份',@sql,@freqtype='day'

--記錄備份(每2小時備份一次)
set @sql='exec p_backupdb @dbname=''要備份的資料庫名'',@bktype='LOG''
exec p_createjob @jobname='每2小時記錄備份',@sql,@freqtype='day',@fsinterval=2

*--應用案例2

生產資料核心庫:PRODUCE

備份方案如下:
 1.設定三個作業,分別對PRODUCE庫進行每日備份,每周備份,每月備份
 2.建立三個新庫,分別命名為:每日備份,每周備份,每月備份
 3.建立三個作業,分別把三個備份庫還原到以上的三個新庫。

目的:當使用者在produce庫中有任何的資料丟失時,均可以從上面的三個備份庫中匯入相應的TABLE資料。
--*/

declare @sql varchar(8000)

--1.建立每月備份和產生月備份資料庫的作業,每月每1天下午16:40分進行:
set @sql='
declare @path nvarchar(260),@fname nvarchar(100)
set @fname=''PRODUCE_''+convert(varchar(10),getdate(),112)+''_m.bak''
set @path=dbo.f_getdbpath(null)+@fname

--備份
exec p_backupdb @dbname=''PRODUCE'',@bkfname=@fname

--根據備份產生每月新庫
exec p_RestoreDb @bkfile=@path,@dbname=''PRODUCE_月''

--為周資料庫恢複準備基礎資料庫
exec p_RestoreDb @bkfile=@path,@dbname=''PRODUCE_周'',@retype=''DBNOR''

--為日資料庫恢複準備基礎資料庫
exec p_RestoreDb @bkfile=@path,@dbname=''PRODUCE_日'',@retype=''DBNOR''
'
exec p_createjob @jobname='每月備份',@sql,@freqtype='month',@time=164000

--2.建立每周差異備份和產生周備份資料庫的作業,每周日下午17:00分進行:
set @sql='
declare @path nvarchar(260),@fname nvarchar(100)
set @fname=''PRODUCE_''+convert(varchar(10),getdate(),112)+''_w.bak''
set @path=dbo.f_getdbpath(null)+@fname

--差異備份
exec p_backupdb @dbname=''PRODUCE'',@bkfname=@fname,@bktype=''DF''

--差異恢複周資料庫
exec p_backupdb @bkfile=@path,@dbname=''PRODUCE_周'',@retype=''DF''
'
exec p_createjob @jobname='每周差異備份',@sql,@freqtype='week',@time=170000

--3.建立每日記錄備份和產生日備份資料庫的作業,每周日下午17:15分進行:
set @sql='
declare @path nvarchar(260),@fname nvarchar(100)
set @fname=''PRODUCE_''+convert(varchar(10),getdate(),112)+''_l.bak''
set @path=dbo.f_getdbpath(null)+@fname

--記錄備份
exec p_backupdb @dbname=''PRODUCE'',@bkfname=@fname,@bktype=''LOG''

--日誌恢複日資料庫
exec p_backupdb @bkfile=@path,@dbname=''PRODUCE_日'',@retype=''LOG''
'
exec p_createjob @jobname='每周差異備份',@sql,@freqtype='day',@time=171500


 

更多的資訊參考我在CSDN上發表的貼子:

http://expert.csdn.net/Expert/topic/2359/2359124.xml?temp=.7861292


相關文章

Beyond APAC's No.1 Cloud

19.6% IaaS Market Share in Asia Pacific - Gartner IT Service report, 2018

Learn more >

Apsara Conference 2019

The Rise of Data Intelligence, September 25th - 27th, Hangzhou, China

Learn more >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。