oracle下加密預存程序的方法

方法1： X:\oracle\ora81\bin\wrap iname=XXX oname=XXX

方法2：9i在win2000下使用wrap加密預存程序,10g可以用加密包dbms_ddl.wrap或dbms_ddl.create_wrapped。

11.5.1 在win2000下使用wrap加密預存程序
wrap.bat
rem 使用方法：wrap 待加密的檔案名稱
set NLS_LANG=AMERICAN_AMERICA.USACII7
wrap.exe iname=%1
pause
11.5.2 WRAP 程式包(10.2版本)
PL/SQL 程式單元經常包含關於公司流程和商業秘密的非常敏感和機密的資訊，這使得它們與表相類似，成為受保護的實體組。為防止未經授權而查看原始碼的情況，我們要經常使用 wrap 命令列公用程式，這將使程式變得很混亂。
只有在建立 PL/SQL 指令碼後才能調用 wrap；該公用程式將輸入的明文打包為一個檔案。但是，在某些情況下，您可能希望在 PL/SQL 代碼中動態產生封裝。在這種情況下，因為還不存在源檔案，不能調用 wrap 公用程式。
由於 Oracle 資料庫 10g 第 2 版提供了一個供應程式包，您可以使用它建立代碼，並進行打包。該程式包補充（而不是替代）了 wrap 公用程式。而後者仍然適合於希望使用命令列來快速打包大量源檔案的情況。
例如，假設您希望以打包形式建立簡單的過程 p1。
create or replace procedure p1 as
begin
null;
end;
在 PL/SQL 單元中，您可以使用以下命令以打包方式動態地建立這一過程：
begin
dbms_ddl.create_wrapped
('create or replace procedure p1 as begin null; end;')
end;
/
現在您希望確認打包過程。您可以從字典中選擇源文本。
SQL> select text from user_source where name = 'P1';

Text
-----------------------------------------------------------------
procedure p1 wrapped
a000000
369
abcd
abcd
……等等……
第一行 procedure p1 wrapped 是確認以打包方式建立過程。如果您利用 DBMS_METADATA.GET_DDL() 函數來擷取該過程的 DDL，則仍然會看到原始碼已被打包。
有時您可能會有略微不同的需求；例如，您可能要產生 PL/SQL 代碼，但不想建立過程。在這種情況下，您可以將其儲存在一個檔案或表中，以便以後執行。但是因為以上方法建立了過程，所以該方法在這裡行不通。所以您需要在程式包中調用另一個函數：
SQL> select dbms_ddl.wrap
2 ('create or replace procedure p1 as begin null; end;')
3 from dual
4 /

DBMS_DDL.WRAP('CREATEORREPLACEPROCEDUREP1ASBEGINNULL;END;')
----------------------------------------------------------------------
create or replace procedure p1 wrapped
a000000
369
abcd
abcd
... and so on ...
WRAP 函數的輸出是一個可傳遞的參數，它代表著 PL/SQL 代碼的打包輸出結果。該參數可以儲存在純檔案檔案或表中，可以在以後執行。如果您產生的程式碼要在其他地方部署，並且必須要保證代碼的安全性，則這種方法很有用。
如果您可以將所儲存代碼的全部文本作為一個 varchar2 資料類型（大小限制為 32K）來傳遞，則這一方法可以正常工作。如果 PL/SQL 代碼超過 32K，則您必須使用一種略微不同的方法：接受一個集合變數作為輸入。
在這裡您可以使用一個供應的資料類型：程式包 DBMS_SQL 中的 varchar2。這是一個集合資料類型 (TABLE OF VARCHAR2)，表的每個單元都接收多達 32K 的文本；可隨意增加該表所含的單元數，以滿足您的需要。例如，假設您必須封裝一個名為 myproc 的非常長的過程，其定義如下：
create or replace procedure myproc as
l_key VARCHAR2(200);
begin
l_key := 'ARUPNANDA';
end;
當然，這根本不是一個非常長的過程；但是為了示範起見，假設它很長。為了將其建立為打包形式，您要執行以下的 PL/SQL 塊：
1 declare
2 l_input_code dbms_sql.varchar2s;
3 begin
4 l_input_code (1) := 'Array to hold the MYPROC';
5 l_input_code (2) := 'create or replace procedure myproc as ';
6 l_input_code (3) := ' l_key VARCHAR2(200);';
7 l_input_code (4) := 'begin ';
8 l_input_code (5) := ' l_key := ''ARUPNANDA'';';
9 l_input_code (6) := 'end;';
10 l_input_code (7) := 'the end';
11 sys.dbms_ddl.create_wrapped (
12 ddl => l_input_code,
13 lb => 2,
14 ub => 6
15 );
16* end;
在這裡我們定義了一個變數 l_input_code 來儲存輸入的明文代碼。在第 4 行到第 10 行中，我們用要打包的代碼來填充這些行。在本樣本中，同樣為了簡單起見，我使用了非常短的行。實際上，您可能要使用非常長的行，其大小多達 32KB。同樣，我在數組中只使用了 7 個單元；實際上您可能要使用若干單元來填充全部代碼。
第 11 到第 15 行表明我如何調用該過程，以便將該過程建立為打包形式。在第 12 行中，我將集合作為一個參數 DDL 來傳遞。但是，在這裡暫停一下 — 我已經分配了一個注釋作為數組的第一個單元，可能用於文檔。但它不是有效文法。同樣，我將另一個注釋分配給數組的最後一個單元 (7)，它也不是用於建立過程的有效文法。為了使封裝操作僅僅處理有效行，我在第 13 和第 14 行中指定了儲存我們代碼的集合的最低 (2) 和最高 (6) 的單元。參數 LB 表示數組的下界，在本樣本中是 2，而 HB 是上界 (6)。
使用這種方法，現在可以從您的 PL/SQL 代碼中以打包方式建立任意大小的過程。
============================================================

CREATE OR REPLACE PROCEDURE p_wraped_user AUTHID CURRENT_USER AS
--Created by xsb on 2006-11-10
--For:大量加密本使用者下的所有代碼，包括預存程序、函數、包。
v_procs dbms_sql.varchar2a;

BEGIN
FOR n IN (SELECT DISTINCT NAME, TYPE
FROM user_source
WHERE NAME <> 'P_WRAPED_USER' AND
TYPE <> 'TYPE'
MINUS
SELECT DISTINCT NAME, TYPE
FROM user_source
WHERE line = 1 AND
instr(text, 'wrapped') > 0
--WHERE NAME = 'GET_CLERK' --AND
-- TYPE = 'PACKAGE BODY'
ORDER BY TYPE) LOOP
FOR i IN (SELECT rownum rn, text
FROM (SELECT decode(line, 1, 'create or replace ') || text text
FROM user_source
WHERE NAME = n.NAME AND
TYPE = n.TYPE
ORDER BY line)) LOOP
v_procs(i.rn) := i.text;
END LOOP;
dbms_ddl.create_wrapped(v_procs, 1, v_procs.COUNT);
v_procs.DELETE;
END LOOP;

END;