ASP開發中預存程序應用全接觸

預存程序

    ASP與預存程序(Stored Procedures)的文章不少，但是我懷疑作者們是否真正實踐過。我在初學時查閱過大量相關資料，發現其中提供的很多方法實際操作起來並不是那麼回事。對於簡單的應用，這些資料也許是有協助的，但僅限於此，因為它們根本就是千篇一律，互相抄襲，稍微複雜點的應用，就全都語焉不詳了。

　　現在，我基本上通過調用預存程序訪問SQL Server，以下的文字都是實踐的總結，希望對大家能有協助。

　　預存程序就是作為可執行對象存放在資料庫中的一個或多個SQL命令。

　　定義總是很抽象。預存程序其實就是能完成一定操作的一組SQL語句，只不過這組語句是放在資料庫中的(這裡我們只談SQL Server)。如果我們通過建立預存程序以及在ASP中調用預存程序，就可以避免將SQL語句同ASP代碼混雜在一起。這樣做的好處至少有三個：

　　第一、大大提高效率。預存程序本身的執行速度非常快，而且，調用預存程序可以大大減少同資料庫的互動次數。

　　第二、提高安全性。假如將SQL語句混合在ASP代碼中，一旦代碼失密，同時也就意味著庫結構失密。

　　第三、有利於SQL語句的重用。

　　在ASP中，一般通過command對象調用預存程序，根據不同情況，本文也介紹其它調用方法。為了方便說明，根據預存程序的輸入輸出，作以下簡單分類：

　　1. 只返回單一記錄集的預存程序

　　假設有以下預存程序(本文的目的不在於講述T-SQL文法，所以預存程序只給出代碼，不作說明)：

/*SP1*/
CREATE PROCEDURE dbo.getUserList
as
set nocount on
begin
select * from dbo.[userinfo]
end
go
　　以上預存程序取得userinfo表中的所有記錄，返回一個記錄集。通過command對象調用該預存程序的ASP代碼如下:

'**通過Command對象調用預存程序**
DIM MyComm,MyRst
Set MyComm = Server.CreateObject("ADODB.Command")
MyComm.ActiveConnection = MyConStr 'MyConStr是資料庫連接字串
MyComm.CommandText = "getUserList" '指定預存程序名
MyComm.CommandType = 4 '表明這是一個預存程序
MyComm.Prepared = true '要求將SQL命令先行編譯
Set MyRst = MyComm.Execute
Set MyComm = Nothing
　　預存程序取得的記錄集賦給MyRst，接下來，可以對MyRst進行操作。

　　在以上代碼中，CommandType屬性工作表明請求的類型，取值及說明如下：

　　-1 表明CommandText參數的類型無法確定
　　1 表明CommandText是一般的命令類型
　　2 表明CommandText參數是一個存在的表名稱
　　4 表明CommandText參數是一個預存程序的名稱

　　還可以通過Connection對象或Recordset對象調用預存程序，方法分別如下：

'**通過Connection對象調用預存程序**
DIM MyConn,MyRst
Set MyConn = Server.CreateObject("ADODB.Connection")
MyConn.open MyConStr 'MyConStr是資料庫連接字串
Set MyRst = MyConn.Execute("getUserList",0,4) '最後一個參斷含義同CommandType
Set MyConn = Nothing

'**通過Recordset對象調用預存程序**
DIM MyRst
Set MyRst = Server.CreateObject("ADODB.Recordset")
MyRst.open "getUserList",MyConStr,0,1,4
'MyConStr是資料庫連接字串,最後一個參斷含義與CommandType相同
　　2. 沒有輸入輸出的預存程序

　　請看以下預存程序：

/*SP2*/
CREATE PROCEDURE dbo.delUserAll
as
set nocount on
begin
delete from dbo.[userinfo]
end
go
　　該預存程序刪去userinfo表中的所有記錄，沒有任何輸入及輸出，調用方法與上面講過的基本相同，只是不用取得記錄集：

'**通過Command對象調用預存程序**
DIM MyComm
Set MyComm = Server.CreateObject("ADODB.Command")
MyComm.ActiveConnection = MyConStr 'MyConStr是資料庫連接字串
MyComm.CommandText = "delUserAll" '指定預存程序名
MyComm.CommandType = 4 '表明這是一個預存程序
MyComm.Prepared = true '要求將SQL命令先行編譯
MyComm.Execute '此處不必再取得記錄集
Set MyComm = Nothing
　　當然也可通過Connection對象或Recordset對象調用此類預存程序，不過建立Recordset對象是為了取得記錄集，在沒有返回記錄集的情況下，還是利用Command對象吧。

[1] [2] [3] 下一頁