這裡所說的“小偷”指的是在ASP中運用XML中的XMLHTTP組件提供的強大功能，把遠程網站上的資料（圖片，網頁及其他檔案）抓取到本地，經過各種處理後顯示到頁面上或者儲存進資料庫的一類程式。你可以通過這種小偷程式，完成過去一些似乎完全不可能實現的任務，比如說把某個站的頁面偷梁換柱後變成自己的頁面，或者把某個站的一些資料（文章，圖片）儲存到本機資料庫中加以利用。“小偷”的優點有：無須維護網站，因為小偷程式中的資料來自其他網站，它將隨著該網站的更新而更新；可以節省大量的伺服器資源，一般小偷程式就幾個檔案，所有網頁內容都是來自其他網站。缺點在於：不穩定，如果目標網站出錯，程式也會出錯，而且，如果目標網站進行升級維護，那麼小偷程式也要進行相應修改；速度，因為是遠程調用，速度和在本機伺服器上讀取資料比起來，肯定要慢一些。怎麼樣，聽起來很神奇吧？我們現在就開始來學習一些“小偷”程式的入門知識吧！
我們拿個簡單點的東西來研究一下吧，QQ網站上的天氣預報程式
代碼如下：
<%
On Error Resume Next
Server.ScriptTimeOut=9999999
Function getHTTPPage(Path)
t = GetBody(Path)
getHTTPPage=BytesToBstr(t,"GB2312")
End function
' 首先，進行小偷程式的一些初始化設定，以上代碼的作用分別是忽略掉所有非致命性錯誤，把小偷程式的運行逾時時間設定得很長（這樣不會出現運行逾時的錯誤），轉換原來預設的UTF-8編碼轉換成GB2312編碼，否則直接用XMLHTTP組件調用有中文字元的網頁得到的將是亂碼。
Function GetBody(url)
on error resume next
Set Retrieval = CreateObject("Microsoft.XMLHTTP")
With Retrieval
.Open "Get", url, False, "", ""
.Send
GetBody = .ResponseBody
End With
Set Retrieval = Nothing
End Function
'然後調用XMLHTTP組件建立一個對象並進行初始化設定。
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function
Function Newstring(wstr,strng)
Newstring=Instr(lcase(wstr),lcase(strng))
if Newstring<=0 then Newstring=Len(wstr)
End Function
'處理抓取回來的資料需要調用adodb.stream組件並進行初始化設定。%>
'以下即為頁面顯示部分
<%
Dim wstr,str,url,start,over,city
'定義一些需要使用到的變數
city = Request.QueryString("id")
'程式傳回的ID變數（即使用者選擇的城市）賦給id
url="http://appnews.qq.com/cgi-bin/news_qq_search?city="&city&""
'這裡設定需要抓取的頁面地址，當然你也可以直接指定某個地址而不使用變數
wstr=getHTTPPage(url)
'擷取指定頁面的全部資料
start=Newstring(wstr," <html>")
'這裡設定需要處理的資料的頭部，這個變數應視不同情況而設定，具體內容可以通過查看需要抓取的頁面的原始碼來確定。因為在這個程式裡我們需要抓取整個頁面,所以設定為頁面全部抓取。注意，設定的內容必須是頁面內容唯一的，不可以重複。
over=Newstring(wstr," </HTML>")
'和start相對應的就是需要處理的資料的尾部，同樣的，設定的內容必須是頁面中唯一的。
body=mid(wstr,start,over-start)
'設定顯示頁面的範圍
'下面就是動用乾坤挪移+++的時候了，通過replace可以用一些字元替換掉資料中指定的字元。
body = replace(body,"skin1","天氣預報 - 斯克網路")
body = replace(body,"http://appnews.qq.com/cgi-bin/news_qq_search?city","tianqi.asp?id")
'本程式中已經完成了替換的工作，如果有其他需要的話可以繼續進行類似的替換操作。
response.write body
%>
替換完需要修改的內容後，就可以把修改的內容顯示在頁面上了。至此程式結束
程式使用方法及結果：把上述代碼去掉說明部分後儲存為tianqi.asp，上傳到支援ASP和XML的空間下，在瀏覽器中運行即可。你可以在在這個程式的基礎上進行進一步的介面美化或者程式最佳化。
以上只是一些關於XMLHTTP組件的初級應用，實際上它還能實現的功能還有很多，比如說儲存遠程圖片到本機伺服器上，配合adodb.stream組件可以把擷取來的資料儲存進資料庫。小偷的作用和使用範圍都很廣。但是不可以拿來做違法的事哦！
也許還有人要問了，這種“小偷”程式難道只是ASP的專利嗎？非也，PHP通過fopen函數一樣可以實現同樣的效果，由於PHP本身的各種特點，寫出來的小偷程式和ASP相比，在體積和執行效率上都有者明顯的優勢，但限於篇幅，這裡就不一一說明了。
Start building with 50+ products and up to 12 months usage for Elastic Compute Service
1 on 1 presale consultation
24/7 Technical Support 6 Free Tickets per Quarter Faster Response
Alibaba Cloud offers highly flexible support services tailored to meet your exact needs.
A comprehensive suite of global cloud computing services to power your business
Payment Methods We Support
