如何快速產生100萬不重複的8位編號

來源:互聯網
上載者:User

最近在論壇看到有人問,如何快速產生100萬不重複的8位編號,對於這個問題,有幾點是需要注意的:
1.    如何產生8位隨機數,產生的數越隨機,重複的可能性當然越小
2.    控制不重複
3.    考慮效能
針對這個問題,我寫了如下的樣本來解決,希望能為有這類需求的人提供指導
 
產生100萬條8位不重複資料的樣本
USE tempdb
GO
 
-- 建立測試表
CREATE TABLE tb(id char(8))
 
-- 建立用於自動過濾重複值的唯一索引
CREATE UNIQUE INDEX IX_tb ON tb(id)
WITH IGNORE_DUP_KEY
GO
 
-- 測試資料插入的處理時間, 記錄開始處理的時間點
DECLARE @dt datetime
SET @dt = GETDATE()
 
-- 插入隨機資料
SET NOCOUNT ON
DECLARE @row int
SET @row = 1000000 -- 設定總記錄數
WHILE @row >0
BEGIN
    -- 顯示提示資訊, 表示還需要插入多行資料
    RAISERROR('need %d rows', 10, 1, @row) WITH NOWAIT
 
    -- 插入隨機的位編碼資料
    SET ROWCOUNT @row
    INSERT tb SELECT
        id = RIGHT(100000000 + CONVERT(bigint, ABS(CHECKSUM(NEWID()))), 8)
    FROM syscolumns c1, syscolumns c2
    SET @row = @row - @@ROWCOUNT
END
 
-- 顯示插入資料使用的時間
SELECT BeginDate = @dt, EndDate = GETDATE(),
    Second = DATEDIFF(Second, @dt, GETDATE()),
GO
 
-- 顯示最終的結果記錄是否正確
SELECT COUNT(*) FROM tb
GO
 
-- 刪除測試
DROP TABLE tb
 
解決中用到的技巧:
1.    控制產生的資料不重複,直接使用唯一索引中的 IGNORE_DUP_KEY 選項,使插入資料中的重複值自動過濾,避免手工處理重複
2.    使用 CHECKSUM 配合 NEWID() 函數,使產生的資料盡量隨機,一般產生隨機數會考慮使用 RAND() 函數,但這個函數是產生偽隨機值,用下面的語句測試一下,會發現產生的資料全部是一樣的,這不適用於想批量產生多個隨機數,而NEWID() 函數產生的是GUID,基本上不會有重複的,再通過CHECKSUM將其轉化成數字,這樣產生重複的可能性會比較小
SELECT TOP 10
    RAND()
FROM sysobjects
3.    在效率控制,使用迴圈+批量產生的方式,而不是傳統的逐個產生。在SQL Server中,每個插入語句都會有一個內部的交易處理,如果逐條插入,則事務的開銷太大,效率勢必非常低;不考慮一次性產生100萬資料,一則因為產生的資料可能有重複的,去掉重複就沒有100萬了,二則一次性產生100萬資料,消耗的記憶體和CPU資源也很高,一般的電腦可能承受不住.



相關文章

Beyond APAC's No.1 Cloud

19.6% IaaS Market Share in Asia Pacific - Gartner IT Service report, 2018

Learn more >

Apsara Conference 2019

The Rise of Data Intelligence, September 25th - 27th, Hangzhou, China

Learn more >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。