在Asp中如何快速最佳化分頁的技巧

 近日一直在研究如何才能寫出高小的分頁演算法，大概整理了一下，思路如下：
 
    首先資料庫裡需要有一個自動編號欄位（ID）。然後第一次訪問的時候，取出所有記錄，定製好每頁的記錄數PageSize，計算出頁數，然後根據頁數建立一個一維數組PageId(PageCount)，PageId(0)儲存記錄初試條件，然後對應每個元素儲存每頁對應的ID邊界碼
（
  1，ID邊界碼：如果資料庫記錄ID記錄序列如下  1，2，3，4，5，6，7，8，9，10，11，12，13，14，15，16
  假設需要按照ID 順序排序的話 ，PageSize = 5, Pagecount = 4 ，PageId(4)
   數組PageId的值分別為PageId(0) = 1, PageId(1) = 5 ,PageId(2) = 10,PageId(3) = 15 ,PageId(4) = 16
   當訪問第 i 頁的時候就直接找 [PageId(i-1) , PageId(i) ) 之間的記錄，這樣可以保證每次取的記錄都只是PageSize 條記錄。
  假設需要按照ID倒序排列的話,
   數組PageId的值分別為PageId(0) = 16 , PageId(1) = 12 , PageId(2) = 7 ,PageId(3) = 2, PageId(4) = 1, 當訪問第 i 頁的時候就直接尋找ID屬於[ PageId(i-1) , PageId(i) ) 

）
 將數組PageId()儲存在Application()中，以便訪問，這樣，只是第一次訪問分頁程式的時候便初始化Application()。代碼部分如下:（下面稱為新程式）

<%
 Time1 = Timer()
 Dim Conn
 Set Conn = Server.CreateObject("Adodb.Connection")
 Conn.open "Driver={MicroSoft Access Driver (*.mdb)};Dbq="&Server.MapPath("db.mdb")
 'www.knowsky.com
 Dim Page,PageCounts,PageId,PageList
 Dim Rs,Sql
 Dim IsInit,i
 
 IsInit   = False                                         '標誌為，用來判斷Application("PageId")是否初始化
 PageList = 20                                            '設定每頁顯示20條資料
 Set Rs    = Server.CreateObject("Adodb.Recordset")
 Page     = Request.QueryString("Page")                         '注意頁碼需要檢查類型
 
 If IsEmpty(Application("PageId")) Then               '如果Application("PageId")還未初始化,則先進行初始化
  Response.Write("Init app!<br>")
  Sql      = "Select * From test Order By Id Desc"  '假定這裡是按照ID倒序排列
  Rs.open Sql,Conn,1,1  '得到記錄集對象
 
  If Not (Rs.Eof  or Rs.Bof) Then
   Rs.PageSize = PageList                        '設定每頁記錄數
   PageCounts  = Rs.PageCount
   ReDim PageId(PageCounts)                      '重新定義數組PageId
   For i = 0 To PageCounts                       '開始給數組 PageId() 賦值   
    If Rs.eof Then Exit For
    PageId(i) = Rs("ID")
    Rs.Move (PageList)
   Next
   Rs.MoveLast
   PageId(PageCounts) = Rs("ID")
   Application.Lock()
   Application("PageId") = PageId
   Application.UnLock() 
  End If
  Rs.Close
 End If
 IdStart = Clng(Application("PageId")(Page-1))
 IdEnd   = Clng(Application("PageId")(Page))
 Sql = "Select * from test where id<="&IdStart&" and id>"&IdEnd&" "
 Rs.open Sql,Conn,1,1
 While Not Rs.eof
  Response.Write(rs(0)&"--"&rs(1))
  Rs.MoveNext
 Wend
 Rs.Close 
 Set Rs = Nothing
 Conn.Close
 Set Conn = Nothing
 
 
 For i = 1 To Ubound(Application("PageId"))
  Response.Write("<a href=http://www.dvbbs.net/tech/asp/'Test1.asp?Page="&i&"'>"&i&"</a>　")
 Next
 Time2 = Timer()
 
 Response.Write("<br>"&(Time2-Time1)*1000)
 'Application.Contents.Remove("PageId")
%>

傳統分頁代碼如下:（下面稱為舊程式）
<%
 Time1 = Timer()
 Dim Conn
 Set Conn = Server.CreateObject("Adodb.Connection")
 Conn.open "Driver={MicroSoft Access Driver (*.mdb)};Dbq="&Server.MapPath("db.mdb")
 
 Dim Page,PageCounts,PageList
 Dim Rs,Sql
 
 PageList = 20
 Page     = Request.QueryString( "Page" )
 Set Rs   = Server.CreateObject("Adodb.Recordset")
 Sql      = "Select * from test order by id desc"
 Rs.Open Sql,Conn,1,1
 
 If Page = "" Then Page = 1
 If Not( Rs.eof Or Rs.Bof ) Then
  Rs.PageSize     = PageList
  PageCounts      = Rs.PageCount
  Rs.AbsolutePage = Page 
 End If
 
 For i = 1 to PageList
  If Rs.eof Then Exit For
  Response.Write(Rs(0)&"-----"&Rs(1)&"<br>")
  Rs.MoveNext
 next
 
 For i = 1 To PageCounts
  Response.Write("<a href=http://www.dvbbs.net/tech/asp/'Test.asp?Page="&i&"'>"&i&"</a>　")
 Next
 Time2 = Timer()
 
 Response.Write("<br>"&(Time2-Time1)*1000)
%>
 
    其實，總體的思想就是，建立一個Application("PageId")全域數組,每個元素都儲存頁面所區記錄的ID區間，比如，Application("PageId")(0) 儲存第一個元素的ID，然後Application("PageId")(1)儲存下一頁的第一個ID…………依次類推，當需要訪問第 i 頁的時候，就直接尋找ID在 [ Application("PageId")(i-1)  , Application("i") ) 裡面的記錄集，這樣，每次只用尋找需要的記錄數，而不需要每次都把所有記錄都尋找一遍，但是，這個方法是在第一次訪問的時候，即需要建立數組Application("PageId")的時候比較慢一點，當第N次訪問的時候 （N>1）速度就快將近10倍，我採用上面2個程式測試：
  1，資料庫記錄有32000條記錄，舊程式訪問一頁需要500毫秒左右，新程式只是第一次訪問的時候達到這個時間，然後每次都只需要55毫秒左右。
  2，將資料增加到64000條記錄，舊程式訪問一頁需要1000毫秒左右，新程式也是第一次訪問的時候達到這個似乎件， 後面每次仍然還是保持在55毫秒左右。
  3，將資料增加到128000條記錄，舊程式訪問一頁需要1900毫秒左右，新程式第一次訪問需要2300毫秒左右，然後每次訪問只需要70毫秒左右。
  這裡需要注意的是資料庫每改動一次，Application("PageId") 就需要重新賦值!

    研究心得：（首先謝謝葉子(DVBBS)的心得）盡量不要用內建的分頁程式，Rs.RecordCount 很耗資源。依次，估計Rs.PageCount ……也耗資源，而且用Rs.GetRows()效果也很明顯提高。
 
    經過比較，葉子的演算法在記錄比較靠前的時候速度以及效率是比較高的。但是不太穩定，有時（很少）會從30毫秒左右跳到1-200毫秒。到了後面效率就明顯下降到50-80毫秒，越後效率越低。新演算法第一次效率比較低下，大約在500毫秒左右，但是比較穩定，後面一般哦度是50毫秒左右，而且隨著庫的記錄數變化，這個速度依然如此。不會有什麼變化。下次就把葉子和我的演算法結合起來試試，不過葉子的演算法確實是很不錯D，具備通用性。我這個只能拿來聊聊了。