SQL Server儲過程加密和解密原理深入分析

開始：
--------------------------------------------------------------------------------
在網路上，看到有SQL Server 2000和SQL Server 2005 的預存程序加密和解密的方法，後來分析了其中的代碼，發現它們的原理都是一樣的。後來自己根據實際的應用環境，編寫了兩個預存程序，一個加密預存程序（sp_EncryptObject），和一個解密預存程序（sp_EncryptObject），它們可以應用於SQL Server中的儲過程，函數，視圖，以及觸發器。
感覺這兩個預存程序蠻有意思的，拿來與大家分享；如果你看過類似的，就當作重溫一下也好。
用於加密的預存程序 （sp_EncryptObject） ：
--------------------------------------------------------------------------------
預存程序（sp_EncryptObject）加密的方法是在預存程序，函數，視圖的“As”位置前加上“with encryption”；如果是觸發器，就在“for”位置前加“with encryption”。
如果觸發器是{ AFTER | INSTEAD OF} 需要修改下面代碼"For"位置： 複製代碼 代碼如下:if objectproperty(object_id(@Object),'ExecIsAfterTrigger')=0 set @Replace='As' ; else set @Replace='For ';

預存程序完成代碼： 複製代碼 代碼如下:Use master
Go
if object_ID('[sp_EncryptObject]') is not null
Drop Procedure [sp_EncryptObject]
Go
create procedure sp_EncryptObject
(
@Object sysname='All'
)
as
/*
當@Object=All的時候，對所有的函數，預存程序，視圖和觸發器進行加密
調用方法：
. Execute sp_EncryptObject 'All'
. Execute sp_EncryptObject 'ObjectName'
*/
begin
set nocount on
if @Object <>'All'
begin
if not exists(select 1 from sys.objects a where a.object_id=object_id(@Object) And a.type in('P','V','TR','FN','IF','TF'))
begin
--SQL Server 2008
raiserror 50001 N'無效的加密對象！加密對象必須是函數，預存程序，視圖或觸發器。'
--SQL Server 2012
--throw 50001, N'無效的加密對象！加密對象必須是函數，預存程序，視圖或觸發器。',1
return
end
if exists(select 1 from sys.sql_modules a where a.object_id=object_id(@Object) and a.definition is null)
begin
--SQL Server 2008
raiserror 50001 N'對象已經加密！'
--SQL Server 2012
--throw 50001, N'對象已經加密！',1
return
end
end
declare @sql nvarchar(max),@C1 nchar(1),@C2 nchar(1),@type nvarchar(50),@Replace nvarchar(50)
set @C1=nchar(13)
set @C2=nchar(10)
declare cur_Object
cursor for
select object_name(a.object_id) As ObjectName,a.definition
from sys.sql_modules a
inner join sys.objects b on b.object_id=a.object_id
and b.is_ms_shipped=0
and not exists(select 1
from sys.extended_properties x
where x.major_id=b.object_id
and x.minor_id=0
and x.class=1
and x.name='microsoft_database_tools_support'
)
where b.type in('P','V','TR','FN','IF','TF')
and (b.name=@Object or @Object='All')
and b.name <>'sp_EncryptObject'
and a.definition is not null
order by Case
when b.type ='V' then 1
when b.type ='TR' then 2
when b.type in('FN','IF','TF') then 3
else 4 end,b.create_date,b.object_id
open cur_Object
fetch next from cur_Object into @Object,@sql
while @@fetch_status=0
begin
Begin Try
if objectproperty(object_id(@Object),'ExecIsAfterTrigger')=0 set @Replace='As' ; else set @Replace='For ';
if (patindex('%'+@C1+@C2+@Replace+@C1+@C2+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C1+@C2+@Replace+@C1+@C2,@C1+@C2+'With Encryption'+@C1+@C2+@Replace+@C1+@C2)
end
else if(patindex('%'+@C1+@Replace+@C1+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C1+@Replace+@C1,@C1+'With Encryption'+@C1+@Replace+@C1)
end
else if(patindex('%'+@C2+@Replace+@C2+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C2+@Replace+@C2,@C2+'With Encryption'+@C2+@Replace+@C2)
end
else if(patindex('%'+@C2+@Replace+@C1+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C2+@Replace+@C1,@C1+'With Encryption'+@C2+@Replace+@C1)
end
else if(patindex('%'+@C1+@C2+@Replace+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C1+@C2+@Replace,@C1+@C2+'With Encryption'+@C1+@C2+@Replace)
end
else if(patindex('%'+@C1+@Replace+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C1+@Replace,@C1+'With Encryption'+@C1+@Replace)
end
else if(patindex('%'+@C2+@Replace+'%',@sql)>0)
begin
set @sql=Replace(@sql,@C2+@Replace,@C2+'With Encryption'+@C2+@Replace)
end
set @type =
case
when object_id(@Object,'P')>0 then 'Proc'
when object_id(@Object,'V')>0 then 'View'
when object_id(@Object,'TR')>0 then 'Trigger'
when object_id(@Object,'FN')>0 or object_id(@Object,'IF')>0 or object_id(@Object,'TF')>0 then 'Function'
end
set @sql=Replace(@sql,'Create '+@type,'Alter '+@type)
Begin Transaction
exec(@sql)
print N'已完成加密對象('+@type+')：'+@Object
Commit Transaction
End Try
Begin Catch
Declare @Error nvarchar(2047)
Set @Error='Object: '+@Object+@C1+@C2+'Error: '+Error_message()
Rollback Transaction
print @Error
print @sql
End Catch
fetch next from cur_Object into @Object,@sql
end
close cur_Object
deallocate cur_Object
end
Go
exec sp_ms_marksystemobject 'sp_EncryptObject' --標識為系統對象
go

如果SQL Server 2012，請修改下面兩個位置的代碼。在SQL Server 2012，建議在使用throw來代替raiserror。

解密方法：
解密過程，最重要採用異或方法：
[字元1]經過函數 fn_x（x）加密變成[加密後字元1]，如果我們已知[加密後字元1]，反過來查[字元1],可以這樣：
[字元1] = [字元2] ^ fn_x([字元2]) ^ [加密後字元1]
這裡我列舉一個簡單的例子： 複製代碼 代碼如下:--建立加密函數（fn_x）
if object_id('fn_x') is not null drop function fn_x
go
create function fn_x
(
@x nchar(1)
)returns nchar(1)
as
begin
return(nchar((65535-unicode(@x))))
end
go
declare @nchar_1_encrypt nchar(1),@nchar_2 nchar(1)
--對字元'A'進行加密，存入變數@nchar_1_encrypt
set @nchar_1_encrypt=dbo.fn_x(N'A')
--參考的字元@nchar_2
set @nchar_2='x'
--算出@nchar_1_encrypt 加密前的字元
select nchar(unicode(@nchar_2)^unicode(dbo.fn_x(@nchar_2))^unicode(@nchar_1_encrypt)) as [@nchar_1]
/*
@nchar_1
--------------------
A
*/

[注]： 從SQL Server 2000至 SQL Server 2012 採用異或方法都可以解密
用於解密的預存程序（sp_DecryptObject）： 複製代碼 代碼如下:Use master
Go
if object_ID('[sp_DecryptObject]') is not null
Drop Procedure [sp_DecryptObject]
Go
create procedure sp_DecryptObject
(
@Object sysname, --要解密的對象名：函數，預存程序，視圖或觸發器
@MaxLength int=4000 --評估內容的長度
)
as
set nocount on
/* 1. 解密 */
if not exists(select 1 from sys.objects a where a.object_id=object_id(@Object) And a.type in('P','V','TR','FN','IF','TF'))
begin
--SQL Server 2008
raiserror 50001 N'無效的對象！要解密的對象必須是函數，預存程序，視圖或觸發器。'
--SQL Server 2012
--throw 50001, N'無效的對象！要解密的對象必須是函數，預存程序，視圖或觸發器。',1
return
end
if exists(select 1 from sys.sql_modules a where a.object_id=object_id(@Object) and a.definition is not null)
begin
--SQL Server 2008
raiserror 50001 N'對象沒有加密！'
--SQL Server 2012
--throw 50001, N'無效的對象！要解密的對象必須是函數，預存程序，視圖或觸發器。',1
return
end
declare @sql nvarchar(max) --解密出來的SQL語句
,@imageval nvarchar(max) --加密字串
,@tmpStr nvarchar(max) --臨時SQL語句
,@tmpStr_imageval nvarchar(max) --臨時SQL語句(加密後)
,@type char(2) --物件類型('P','V','TR','FN','IF','TF')
,@objectID int --對象ID
,@i int --While迴圈使用
,@Oject1 nvarchar(1000)
set @objectID=object_id(@Object)
set @type=(select a.type from sys.objects a where a.object_id=@objectID)
declare @Space4000 nchar(4000)
set @Space4000=replicate('-',4000)
/*
@tmpStr 會構造下面的SQL語句
-------------------------------------------------------------------------------
alter trigger Tr_Name on Table_Name with encryption for update as return /**/
alter proc Proc_Name with encryption as select 1 as col /**/
alter view View_Name with encryption as select 1 as col /**/
alter function Fn_Name() returns int with encryption as begin return(0) end/**/
*/
set @Oject1=quotename(object_schema_name(@objectID))+'.'+quotename(@Object)
set @tmpStr=
case
when @type ='P ' then N'Alter Procedure '+@Oject1+' with encryption as select 1 as column1 '
when @type ='V ' then N'Alter View '+@Oject1+' with encryption as select 1 as column1 '
when @type ='FN' then N'Alter Function '+@Oject1+'() returns int with encryption as begin return(0) end '
when @type ='IF' then N'Alter Function '+@Oject1+'() returns table with encryption as return(Select a.name from sys.types a) '
when @type ='TF' then N'Alter Function '+@Oject1+'() returns @t table(name nvarchar(50)) with encryption as begin return end '
else 'Alter Trigger '+@Oject1+'on '+quotename(object_schema_name(@objectID))+'.'+(select Top(1) quotename(object_name(parent_id)) from sys.triggers a where a.object_id=@objectID)+' with encryption for update as return '
end
set @tmpStr=@tmpStr+'/*'+@Space4000
set @i=0
while @i < (ceiling(@MaxLength*1.0/4000)-1)
begin
set @tmpStr=@tmpStr+ @Space4000
Set @i=@i+1
end
set @tmpStr=@tmpStr+'*/'
------------
set @imageval =(select top(1) a.imageval from sys.sysobjvalues a where a.objid=@objectID and a.valclass=1)
begin tran
exec(@tmpStr)
set @tmpStr_imageval =(select top(1) a.imageval from sys.sysobjvalues a where a.objid=@objectID and a.valclass=1)
rollback tran
-------------
set @tmpStr=stuff(@tmpStr,1,5,'create')
set @sql=''
set @i=1
while @i<= (datalength(@imageval)/2)
begin
set @sql=@sql+isnull(nchar(unicode(substring(@tmpStr,@i,1)) ^ unicode(substring(@tmpStr_imageval,@i,1))^unicode(substring(@imageval,@i,1)) ),'')
Set @i+=1
end
/* 2. 列印 */
declare @patindex int
while @sql>''
begin
set @patindex=patindex('%'+char(13)+char(10)+'%',@sql)
if @patindex >0
begin
print substring(@sql,1,@patindex-1)
set @sql=stuff(@sql,1,@patindex+1,'')
end
else
begin
set @patindex=patindex('%'+char(13)+'%',@sql)
if @patindex >0
begin
print substring(@sql,1,@patindex-1)
set @sql=stuff(@sql,1,@patindex,'')
end
else
begin
set @patindex=patindex('%'+char(10)+'%',@sql)
if @patindex >0
begin
print substring(@sql,1,@patindex-1)
set @sql=stuff(@sql,1,@patindex,'')
end
else
begin
print @sql
set @sql=''
end
end
end
end
Go
exec sp_ms_marksystemobject 'sp_DecryptObject' --標識為系統對象
go

如果SQL Server 2012，請修改下面兩個位置的代碼。方法類似於前面的加密過程：

搭建測試環境：
--------------------------------------------------------------------------------
在一個測試環境中（DB: Test），先執行上面的加密預存程序（sp_EncryptObject）和解密預存程序（sp_EncryptObject）;再建立兩個表：TableA & TableB 複製代碼 代碼如下:use test
go
--建立表: TableA & TableB
if object_id('myTableA') is not null drop table myTableA
if object_id('myTableB') is not null drop table myTableB
go
create table myTableA (ID int identity,data nvarchar(50),constraint PK_myTableA primary key(ID))
create table myTableB (ID int ,data nvarchar(50),constraint PK_myTableB primary key(ID))
go

接下來，我們要建立6個未加密的對象（物件類型包含 'P','V','TR','FN','IF','TF'）：
1.視圖（myView）： 複製代碼 代碼如下:if object_id('myView') is not null drop view myView
go
create view myView
As
select * from TableA;
go

2.觸發器（MyTrigger）： 複製代碼 代碼如下:if object_id('MyTrigger') is not null drop Trigger MyTrigger
go
create trigger MyTrigger
on TableA
for update
As
insert into TableB(ID,data) select a.ID,a.Data From Inserted a
go

3.預存程序（MyProc）： 複製代碼 代碼如下:if object_id('MyProc') is not null drop proc MyProc
go
create proc MyProc
(
@data nvarchar(50)
)
As
insert into TableA(data) values(@data)
go

4.使用者定義資料表值函式(TF)（MyFunction_TF）： 複製代碼 代碼如下:if object_id('MyFunction_TF') is not null drop function MyFunction_TF
go
create function MyFunction_TF
(
)
returns @t table
(
id int,
data nvarchar(50)
)
As
begin
insert @t(id,data) select id,data from TableA
return
end
go

5.內聯資料表值函式(IF) （MyFunction_IF）： 複製代碼 代碼如下:if object_id('MyFunction_IF') is not null drop function MyFunction_IF
go
create function MyFunction_IF
(
)
returns table
As
return(select top(3) id, data from TableA order by id desc)
go

6.純量涵式(FN)（MyFunction_FN）： 複製代碼 代碼如下:if object_id('MyFunction_FN') is not null drop function MyFunction_FN
go
create function MyFunction_FN
(
)
returns nvarchar(50)
As
begin
return(select top(1) data from TableA order by id desc)
end
go

當執行完了上面的1-6步驟的指令碼，我們通過查詢系統檢視表sys.sql_modules，可以看到未加密前的定義資訊： 複製代碼 代碼如下:select b.name as object,b.type,a.definition
from sys.sql_modules a
inner join sys.objects b on b.object_id=a.object_id
where b.create_date>=convert(date,getdate())
order by b.object_id

加密測試：
--------------------------------------------------------------------------------
下面我就通過調用加密預存程序（sp_EncryptObject），一次性對它們進行加密： 複製代碼 代碼如下:use test
go
exec sp_EncryptObject 'all'
go

當我們再查回系統檢視表sys.sql_modules，會發現definition列返回的是null值，說明定義內容已經給加密：

解密測試：
--------------------------------------------------------------------------------
解密過程，必須在DAC串連SQL Server，我們這裡例子是從 SSMS(SQL Server Management Studio) 查詢編輯器啟動 DAC，

解密預存程序（sp_DecryptObject），只能一次對一個預存程序、函數、視圖或觸發器，進行解密： 複製代碼 代碼如下:use test
go
exec sp_DecryptObject MyTrigger
go

當定義內容長度超過4000，我們可以指定@MaxLength的值，如： 複製代碼 代碼如下:exec sp_DecryptObject fn_My,20000
go

這裡（fn_My）是一個函數，定義內容超過了8000：

... ...

小結：
--------------------------------------------------------------------------------
雖然，上面的指令碼，我已經在SQL Server 2008 R2 和SQL Server 2012測試過，但無法避免一些未知錯誤 。如果你自己在測試上面的指令碼，請不要在生產環境上。如果你在應用過程，碰到有什麼問題或有什麼意見和建議可以發email聯絡我或跟帖，在此非常感謝！