ASP編程入門進階（十六）：FSO組件之磁碟機操作

fso|編程|磁碟機|fso|磁碟機 FSO，正如UFO般令人激動、令人神往，當然更多的亦是讓人歡喜讓人憂。君不見某空間服務商廣告：100MB空間只要60RMB/年，支援資料庫，支援什麼什麼……一問不支援FSO，立馬泄氣。那FSO究竟是什麼東西，它的力量又是如何巨大，其操作的原理又是怎的怎的呢？這次來個徹底的理解。

首先，FSO是FileSystemObject的簡稱。當然也就是我們的俗稱FSO組件了，該組件可以用來處理磁碟機、檔案夾以及檔案。

它可以檢測並顯示出系統磁碟機的資訊分配情況；還能夠建立、改變、移動和刪除檔案夾，並能探測一些給定的檔案夾是否存在，若存在，還能提取出該檔案夾的資訊，如名稱、被建立或最後一次修改的日期，等等。FSO還使得對檔案的處理變得很容易。

一、fso.GetDrive

正如其它組件的建立一樣，FSO的引用也必須建立串連。


Set fso=Server.CreateObject("Scripting.FileSystemObject")



注意CreateObject的內部再也不是MSWC了，而是Scripting。
那下面就可以通過fso來處理磁碟機了。比如fso.GetDriveName提取磁碟機名，fso.GetDrive同樣提取標準磁碟機名。比如：

1，fso.asp


<%Set fso=Server.CreateObject("Scripting.FileSystemObject")%>
<%=fso.GetDriveName("d:")%><br>
<%=fso.GetDrive("d:")%>



你會發現GetDriveName("d:")就是“d:”，而GetDrive("d:")則為標準的“D:”，所以我們一般這樣寫fso.GetDrive(fso.GetDriveName(drvPath))來提取某個具體的驅動盤。

二、drv.GetInfo
上面已經把某個特定的磁碟機提取了，那接著是不是提取該驅動盤的具體資訊。

2，drv.asp


<%
Set fso=Server.CreateObject("Scripting.FileSystemObject")
Set drv=fso.GetDrive(fso.GetDriveName("d:"))
%>
該盤的空間大小：<%=drv.TotalSize%><br>
該盤的剩餘空間大小：<%=drv.FreeSpace%>



以上只是提取的D盤磁碟機的資訊，來個通用的函數，繼續分別測試自己的驅動吧。

3，drvinfo.asp


<%
Function ShowDriveInfo(drvPath)
Dim fso, drv, s
Set fso = CreateObject("Scripting.FileSystemObject")
Set drv = fso.GetDrive(fso.GetDriveName(drvPath))
s = "驅動盤" & drv & "的卷標是："
s = s & drv.VolumeName & "<br>"
s = s & "總計空間：" & drv.TotalSize & "<br>"
s = s & "剩餘空間：" & drv.FreeSpace & "<br>"
s = s & "檔案類型：" & drv.DriveType & "<br>"
s = s & "檔案系統：" & drv.FileSystem
Response.Write s
End Function
%>
<%
on error resume next
whatpath=request.form("path")
if whatpath<>"" then
ShowDriveInfo(whatpath)
end if%>
<form action="drvinfo.asp" method="post">
<input name="path">
<input type="submit">
</form>




其中的drv.TotalSize和drv.FreeSpace返回的是位元組數，我們可以用FormatNumber()函數處理下。比如FormatNumber(Drive.TotalSize/1024,0)得到一眼就知磁碟多少G的值。

還有一個檔案類型：drv.DriveType最多的時候是顯示數值“2”，其實“2”就表示的“硬碟”，“1”表示“軟碟機”，“4”表示“光碟片磁碟機”……

下面就用一個程式遍曆顯示自己機器上所有磁碟機的資訊

4，showall.asp


<%
Function tran(Driver)
Select Case Driver
Case 0: tran="裝置無法識別"
Case 1: tran="軟碟機"
Case 2: tran="硬碟"
Case 3: tran="網路硬碟"
Case 4: tran="光碟片磁碟機"
Case 5: tran="RAM虛擬磁碟"
End Select
End Function
set fso=Server.CreateObject("Scripting.FileSystemObject")
%>

<table border=1 width="100%">
<tr>
<td>盤符</td>
<td>類型</td>
<td>卷標</td>
<td>總計大小</td>
<td>可用空間</td>
<td>檔案系統</td>
<td>序號</td>
<td>是否可用</td>
<td>路徑</td>
</tr>
<%
on error resume next
For each drv in fso.Drives
Response.Write "<tr>"
Response.Write "<td>" & drv.DriveLetter & "</td>"
Response.write "<td>" & tran(drv.DriveType) & "</td>"
Response.write "<td>" & drv.VolumeName & "</td>"
Response.write "<td>" & FormatNumber(drv.TotalSize / 1024, 0)& "</td>"
Response.write "<td>" & FormatNumber(drv.Availablespace / 1024, 0) & "</td>"
Response.write "<td>" & drv.FileSystem & "</td>"
Response.write "<td>" & drv.SerialNumber & "</td>"
Response.write "<td>" & drv.IsReady & "</td>"
Response.write "<td>" & drv.Path & "</td>"
Response.Write "</tr>"
Next
set fs=nothing
%>
</tabl