iphon中C++和Objective-C混編

Using C++ With Objective-C
    蘋果的Objective-C編譯器允許使用者在同一個源檔案裡自由地混合使用C++和Objective-C，混編後的語言叫Objective-C++。有了它，你就可以在Objective-C應用程式中使用已有的C++類庫。
 
Objective-C和C++混編的要點
   在 Objective-C++中，可以用C++代碼調用方法也可以從Objective-C調用方法。在這兩種語言裡對象都是指標，可以在任何地方使用。例 如，C++類可以使用Objective-C對象的指標作為資料成員，Objective-C類也可以有C++對象指標做執行個體變數。下例說明了這一點。
    注意：Xcode需要源檔案以".mm"為副檔名，這樣才能啟動編譯器的Objective-C++擴充。
/* Hello.mm
   * Compile with: g++ -x objective-c++ -framework Foundation Hello.mm  -o hello
   */
 
  #import <Foundation/Foundation.h>
  class Hello {
  private:
      id greeting_text;  // holds an NSString
  public:
    Hello() {
        greeting_text = @"Hello, world!";
      }
    Hello(const char* initial_greeting_text) {
       greeting_text = [[NSString alloc] initWithUTF8String:initial_greeting_text];
    }
    void say_hello() {
      printf("%s/n", [greeting_text UTF8String]);
      }
  };
 
  @interface Greeting : NSObject {
  @private
    Hello *hello;
}
- (id)init;
- (void)dealloc;
  - (void)sayGreeting;
  - (void)sayGreeting:(Hello*)greeting;
@end
@implementation Greeting
- (id)init {
if (self = [super init]) {
   hello = new Hello();
}
return self;
}
- (void)dealloc {
  delete hello;
[super dealloc];
  }
- (void)sayGreeting {
  hello->say_hello();
  }
- (void)sayGreeting:(Hello*)greeting {
  greeting->say_hello();
}
@end
  int main() {
NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
 
    Greeting *greeting = [[Greeting alloc] init];
    [greeting sayGreeting];                         // > Hello,  world!
 
Hello *hello = new Hello("Bonjour, monde!");
  [greeting sayGreeting:hello];                   // > Bonjour,  monde!
 
delete hello;
[greeting release];
[pool release];
return 0;
}
 
    正如你可以在OC介面中聲明C結構一樣，你也可以在OC介面中聲明C++類。跟C結構一樣，OC介面中定義的C++類是全域範圍的，不是OC類的內嵌類（這與標準C（儘管不是C++）提升嵌套結構定義為檔案範圍是一致的）。
    為了允許你基於語言變種條件化地編寫代碼，OC++編譯器定義了__cplusplus和__OBJC__前置處理器常量，分別指定C++和OC。    如前所述，OC++不允許C++類繼承自OC對象，也不允許OC類繼承自C++對象。
 
class Base { /* ... */ };
@interface ObjCClass: Base ... @end // ERROR!
class Derived: public ObjCClass ... // ERROR!
 
   與 OC不同的是，C++對象是靜態類型的，有運行時多態是特殊情況。兩種語言的物件模型因此不能直接相容。更根本的，OC和C++對象在記憶體中的布局是互不 相容的，也就是說，一般不可能建立一個對象執行個體從兩種語言的角度來看都是有效。因此，兩種類型階層不能被混合。
    你可以在OC類內部聲明C++類，編譯器把這些類當作已聲明在全域名稱空間來對待。就像下面：
 
@interface Foo {
class Bar { ... } // OK
}
@end
Bar *barPtr; // OK
 
    OC允許C結構作為執行個體變數，不管它是否聲明在OC聲明內部。
 
@interface Foo {
struct CStruct { ... };
struct CStruct bigIvar; // OK
} ... @end
 
    Mac OS X 10.4以後，如果你設定fobjc- call-cxx-cdtors編譯器標誌，你就可以使用包含虛函數和有意義的使用者自訂零參數建構函式、解構函式的C++類執行個體來做為執行個體變數 （gcc-4.2預設設定編譯器標誌fobjc-call-cpp-cdtors）。OC成員變數alloc完以後，alloc函數會按聲明順序調用構造 器。構造器使用公用無參數恰當的建構函式。OC成員變數dealloc之前，dealloc方法按聲明順序反序調用調用解構函式。    OC沒有名稱空間得概念。不能在C++名稱空間內部聲明OC類，也不能在OC類裡聲明名稱空間。
    OC類，協議，分類不能聲明在C++ template裡，C++ template也不能聲明在OC介面，協議，分類的範圍內。
    但是，OC類可以做C++ template的參數，C++ template參數也可以做OC訊息運算式的接收者或參數（不能通過selector）。
 
C++詞彙歧義和衝突
    OC標頭檔中定義了一些標識符，所有的OC程式必須包含的，這些標識符識id，Class，SEL，IMP和BOOL。
    OC方法內，編譯器預聲明了標識符self和super，就想C++中的關鍵字this。跟C++的this不同的是，self和super是上下文相關的；OC方法外他們還可以用於普通標識符。
    協議內方法的參數列表，有5個上下文相關的關鍵字（oneway，in，out，inout，bycopy）。這些在其他內容中不是關鍵字。
   從 OC程式員的角度來看，C++增加了不少新的關鍵字。你仍然可以使用C++的關鍵字做OC selector的一部分，所以影響並不嚴重，但你不能使用他們命名OC類和執行個體變數。例如，儘管class是C++的關鍵字，但是你仍然能夠使用 NSObject的方法class：
 
 [foo class]; // OK
 
    然而，因為它是一個關鍵字，你不能用class做變數名稱：
 
NSObject *class; // Error
OC裡類名和分類名有單獨的命名空間。@interface foo和@interface(foo)能夠同時存在在一個原始碼中。OC++裡，你也能用C++中的類名或結構名來命名你的分類。
協議和template標識符使用文法相同但目的不同：
id<someProtocolName> foo;TemplateType<SomeTypeName> bar;
為了避免這種含糊之處，編譯器不允許把id做template名稱。    最後，C++有一個文法歧義，當一個label後面跟了一個運算式表示一個全域名稱時，就像下面：
label: ::global_name = 3;
第一個冒號後面需要空格。OC++有類似情況，也需要一個空格：
receiver selector: ::global_c++_name;
 
 
限制
   OC++ 沒有為OC類增加C++的功能，也沒有為C++類增加OC的功能。例如，你不能用OC文法調用C++對象，也不能為OC對象增加建構函式和解構函式，也不 能將this和self互相替換使用。類的體繫結構是獨立的。C++類不能繼承OC類，OC類也不能繼承C++類。另外，多語言異常處理是不支援的。也就 是說，一個OC拋出的異常不能被C++代碼捕獲，反過來C++代碼拋出的異常不能被OC代碼捕獲。

作者“wsqwsq000”