ASP實現緩衝類無錯版

<%
'**********************************************
'vbs Cache類
' 屬性valid，是否可用，取值前判斷
' 屬性name，cache名，建立對象後賦值
' 方法add(值,到期時間)，設定cache內容
' 屬性value，返回cache內容
' 屬性blempty，是否未設定值
' 方法makeEmpty，釋放記憶體，測試用
' 方法equal(變數1)，判斷cache值是否和變數1相同
' 方法expires(time)，修改到期時間為time
' 木鳥寫的緩衝類
'**********************************************

class Cache
private obj 'cache內容
private expireTime '到期時間
private expireTimeName '到期時間application名
private cacheName 'cache內容application名
private path 'uri

private sub class_initialize()
path=request.servervariables("url")
path=left(path,instrRev(path,"/"))
end sub

private sub class_terminate()
end sub

public property get blEmpty
'是否為空白
if isempty(obj) then
blEmpty=true
else
blEmpty=false
end if
end property

public property get valid
'是否可用(到期)
if isempty(obj) or not isDate(expireTime) then
valid=false
elseif CDate(expireTime)<now then
valid=false
else
valid=true
end if
end property

public property let name(str)
'設定cache名
cacheName=str & path
obj=application(cacheName)
expireTimeName=str & "expires" & path
expireTime=application(expireTimeName)
end property

public property let expires(tm)
'重設定到期時間
expireTime=tm
application.lock
application(expireTimeName)=expireTime
application.unlock
end property

public sub add(var,expire)
'賦值
if isempty(var) or not isDate(expire) then
exit sub
end if
obj=var
expireTime=expire
application.lock
application(cacheName)=obj
application(expireTimeName)=expireTime
application.unlock
end sub

public property get value
'取值
if isempty(obj) or not isDate(expireTime) then
value=null
elseif CDate(expireTime)<now then
value=null
else
value=obj
end if
end property

public sub makeEmpty()
'釋放application
application.lock
application(cacheName)=empty
application(expireTimeName)=empty
application.unlock
obj=empty
expireTime=empty
end sub

public function equal(var2)
'比較
if typename(obj)<>typename(var2) then
equal=false
elseif typename(obj)="Object" then
if obj is var2 then
equal=true
else
equal=false
end if
elseif typename(obj)="Variant()" then
if join(obj,"^")=join(var2,"^") then
equal=true
else
equal=false
end if
else
if obj=var2 then
equal=true
else
equal=false
end if
end if
end function

end class

dim content,myCache
Set myCache = new Cache
myCache.name="sofoisndoffo" '定義緩衝名稱
if myCache.valid then '如果緩衝有效
content=myCache.value '讀取緩衝內容
else
content="sosuo8.com測試" '大量內容，可以是非常耗時大量資料庫查詢記錄集
myCache.add content,dateadd("n",1000,now) '將內容賦值給緩衝，並設定緩衝有效期間是目前時間＋1000分鐘
end if
Response.Write(content)
'myCache.makeEmpty()
set clsCache=nothing '釋放對象
%>