ORACLE相關文法——子程式和程式包(package,function,procedure)

子程式是命名的PL/SQL塊，可帶參數並可在需要時隨時調用。
PL/SQL有兩種類型的子程式，即過程和函數。
過程用於執行特定的任務，函數用於執行任務並傳回值。
程式包是對相互關聯類型、變數、常量、遊標、異常、過程和函數的封裝。
程式包由包規範和包主體兩部分組成。
包規範是包的介面，包含公用對象及其類型。
包主體實現包規範中的遊標和子程式，包主體中的聲明僅限於在包內使用。
程式包中遊標的定義分為遊標規範和遊標主體兩部分。

文法及樣本：
1、預存程序
建立預存程序的文法：
CREATE [OR REPLACE] PROCEDURE procedure_name
[(parameter_list)]
{IS|AS}
[local_declarations]
BEGIN
executable_statements
[EXCEPTION
exception_handlers]
END [procedure_name];
其中：procedure_name是過程的名稱。
parameter_list是參數列表。
local_declarations是局部聲明。
executable_statements是可執行語句。
exception_handlers是例外處理常式。
樣本1：示範建立過程(參數列表中為IN參數賦予一個預設值，不能為OUT、IN OUT參數賦予預設值)
create or replace procedure find_emp(emp_no in number:=7900)
as
empname varchar2(20);
begin
select ename into empname from emp where empno=emp_no;
dbms_output.put_line('僱員姓名是 '||empname);
exception
when no_data_found then
dbms_output.put_line('僱員編號未找到');
end find_emp;

調用過程：EXECUTE procudure_name(parameters_list);
也可以在過程裡面調用，直接寫上procudure_name而不必寫EXECUTE。

樣本2：示範建立帶OUT參數的過程
create or replace procedure test(value1 varchar2,value2 out number)
is
identity number;
begin
select sal into identity from emp where empno=value1;
if identity<2000 then
value2:=1000;
else
value2:=500;
end if;
end;

調用帶OUT參數的過程：
declare
value2 number;
begin
test('7900',value2);
dbms_output.put_line(value2);
end;

樣本3：示範建立帶IN OUT參數的過程
create or replace procedure swap(p1 in out number,p2 in out number)
is
v_temp number;
begin
v_temp:=p1;
p1:=p2;
p2:=v_temp;
end;

調用帶IN OUT參數的過程：
declare
num1 number:=100;
num2 number:=200;
begin
swap(num1,num2);
dbms_output.put_line('num1= '||num1);
dbms_output.put_line('num2= '||num2);
end;

樣本4：將過程的執行許可權授予其他使用者
GRANT EXECUTE ON find_emp TO scott;
GRANT EXECUTE ON swap TO PUBLIC;
將find_emp過程的執行許可權授予給使用者scott，將執行swap過程的許可權授予所有資料庫使用者。

刪除過程文法：DROP PROCEDURE procudure_name;

2、函數
定義函數的文法如下：
CREATE [OR REPLACE] FUNCTION function_name
[(parameter_list)]
RETURN datatype
{IS|AS}
[local_declarations]
BEGIN
executable_statements
[EXCEPTION
exception_handlers]
END [function_name];
其中：function_name是函數的名稱。
parameter_list是參數列表。
local_declarations是局部聲明。
executable_statements是可執行語句。
exception_handlers是例外處理常式。
使用函數時注意：形式參數必須只使用資料庫類型，不得使用PL/SQL類型。函數的傳回型別也必須是資料庫類型。
函數不能單獨執行，只能通過SQL語句或PL/SQL程式塊來調用。
樣本5：示範如何建立函數
create or replace function fun_hello
return varchar2 is
begin
return '朋友，您好';
end;
調用函數：select fun_hello from dual;

函數的授權：同過和的授權一樣具體請看樣本4。
刪除函數：DROP FUNCTION function_name

過程和函數的差異
過程 函數
作為PL/SQL語句執行 作為運算式的一部分調用
在規範中不包含RETURN子句 必須在規範中包含RETURN子句
不返回任何值 必須返回單個值
可以包含RETURN語句，但是與函數不同，它不能用於傳回值 必須包含至少一條RETURN語句

3、程式包
建立包規範的文法：
CREATE [OR REPLACE] PACKAGE package_name
IS|AS
[Public type and item declarations]
[Subprogram specifications]
END [package_name];
其中：package_name是包的名稱。
Public type and item declarations是宣告類型、常量、變數、異常和遊標等。
Subprogram specifications聲明PL/SQL子程式。

樣本6：示範建立程式包規範
create or replace package pack_op is
procedure pro_print_ename(id number);
procedure pro_print_sal(id number);
function fun_re_date(id number) return date;
end;

建立包主體的文法：
CREATE [OR REPLACE] PACKAGE BODY package_name
IS|AS
[Public type and item declarations]
[Subprogram bodies]
[BEGIN
Initialization_statements]
END [package_name];
其中：package_name是包的名稱。
Public type and item declarations是宣告類型、常量、變數、異常和遊標等。
Subprogram bodies是定義公用和私人PL/SQL子程式。

樣本7：示範建立程式包主體
create or replace package body pack_op is
procedure pro_print_ename(id number) is
name emp.ename%type;
begin
select ename into name from emp where empno=id;
dbms_output.put_line('職員姓名：'||name);
end pro_print_ename;
procedure pro_print_sal(id number) is
salary emp.sal%type;
begin
select sal into salary from emp where empno=id;
dbms_output.put_line('職員工資：'||salary);
end pro_print_sal;
function fun_re_date(id number) return date is
bedate emp.hiredate%type;
begin
select hiredate into bedate from emp where empno=id;
return bedate;
end fun_re_date;
end pack_op;

樣本8：調用程式包中建立的過程和函數
exec pack_op.pro_print_ename(7900);
exec pack_op.pro_print_sal(7900);
select pack_op.fun_re_date(7900) from dual;

樣本9：示範程式包中的遊標
建立包規範
create or replace package pack_emp is
cursor cur_emp return emp%rowtype;
procedure pro_cur;
end pack_emp;

建立包主體
create or replace package body pack_emp is
cursor cur_emp return emp%rowtype is
select * from emp;
procedure pro_cur is
rec_emp emp%rowtype;
begin
open cur_emp;
loop
fetch cur_emp into rec_emp;
exit when cur_emp%notfound;
if rec_emp.sal<1000 then
dbms_output.put_line('員工工資：'||rec_emp.sal||'，需加倍努力爭取提高工資');
elsif rec_emp.sal>=1000 and rec_emp.sal<2000 then
dbms_output.put_line('員工工資：'||rec_emp.sal||'，工資一般，爭取搞個部門經理做做');
else
dbms_output.put_line('員工工資：'||rec_emp.sal||'，工資不錯，爭取搞個總經理做做');
end if;
end loop;
end pro_cur;
end pack_emp;

調用程式包中的過程以調用程式包中的遊標
exec pack_emp.pro_cur;

樣本10：預存程序返回遊標的子程式包(此程式包返回r_cur遊標)
CREATE OR REPLACE package SCOTT.pk_wt
is
type mytype is ref cursor;
procedure p_wt(mycs out mytype);
end;

CREATE OR REPLACE package BODY SCOTT.pk_wt
is
procedure p_wt(mycs out mytype)
is
r_cur mytype;
begin
open r_cur for select * from emp;
mycs:=r_cur;
end p_wt;
end pk_wt;

查詢有關過程、函數和程式包的資訊：USER_OBJECTS資料字典視圖
column object_name format a18
select object_name,object_type from user_objects where object_type in ('PROCEDURE','FUNCTION','PACKAGE','PACKAGE BODY');