讀一讀Scktsrvr.exe的來源程式

使用DELPHI做多層開發的朋友們都應該對Scktsrvr.exe這個程式不陌生的，
Borland公司在DELPHI中給出了它的原始碼。
這是一個900來行的程式，程式不算長，
現在我只選其中部分仔細讀一讀。
走的線路大致是，從伺服器接到用戶端串連，處理用戶端的一個請求（這兒
選了用戶端向伺服器發出的'取應用伺服器列表'請求)

伺服器接受了用戶端串連後,
因為ServerSocket採用的是阻塞模式,伺服器執行了下面這個線程來
服務用戶端：

//SCKTMAIN.PAS

procedure TSocketDispatcherThread.ClientExecute;
var
  Data: IDataBlock;
  msg: TMsg;
  Obj: ISendDataBlock;
  Event: THandle;
  WaitTime: DWord;
begin
  CoInitialize(nil);                 //初始化COM
  try
    Synchronize(AddClient);             //在程式介面上顯示客戶資訊,
        //用同步保證AddClient執行緒安全性
    FTransport := CreateServerTransport;
    try
      Event := FTransport.GetWaitEvent;
      PeekMessage(msg, 0, WM_USER, WM_USER, PM_NOREMOVE);
      GetInterface(ISendDataBlock, Obj);
      if FRegisteredOnly then
        FInterpreter := TDataBlockInterpreter.Create(Obj, SSockets) else
        FInterpreter := TDataBlockInterpreter.Create(Obj, '');
      try
        Obj := nil;
        if FTimeout = 0 then
          WaitTime := INFINITE else
          WaitTime := 60000;
        while not Terminated and FTransport.Connected do
        try
          case MsgWaitForMultipleObjects(1, Event, False, WaitTime, QS_ALLEVENTS) of
              //MsgWaitForMultipleObjects保持線程同步之用,
              //本文暫不細說它.
            WAIT_OBJECT_0:  //有資料來了
            begin
              WSAResetEvent(Event);
              Data := FTransport.Receive(False, 0);  //從用戶端接收資料區塊
              if Assigned(Data) then
              begin
                FLastActivity := Now;
                FInterpreter.InterpretData(Data);//下面接著分析這兒
                Data := nil;
                FLastActivity := Now;
              end;
            end;
            WAIT_OBJECT_0 + 1:
              while PeekMessage(msg, 0, 0, 0, PM_REMOVE) do
                DispatchMessage(msg);
            WAIT_TIMEOUT:
              if (FTimeout > 0) and ((Now - FLastActivity) > FTimeout) then
                FTransport.Connected := False;
          end;
        except
          FTransport.Connected := False;
        end;
      finally
        FInterpreter.Free;
        FInterpreter := nil;
      end;
    finally
      FTransport := nil;
    end;
  finally
    CoUninitialize;
    Synchronize(RemoveClient);
  end;
end;
就這麼舒舒服服的六十來行。
除開那些流程式控制制的語句，我們主要看到兩個東西:
資料轉送(FTransport) 和  資料解析(FInterpreter)。

在本文中,我更感興趣的是它的應用協議的實現,
資料轉送(FTransport)就先扔在一邊,以後再看了.

現在我們就來看看它的資料解析部分。
。。。
FInterpreter := TDataBlockInterpreter.Create(Obj, SSockets) else
FInterpreter := TDataBlockInterpreter.Create(Obj, '');
//這兩種建立TDataBlockInterpreter類執行個體的方法的區別也不去管它.
。。。
 FInterpreter.InterpretData(Data);
。。。
就是這兒，就是這麼一句。
它具體到底幹了些什麼呢？？
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
。。。
 type
  TSocketDispatcherThread = class(TServerClientThread, ISendDataBlock)
  private
。。。
    FInterpreter: TDataBlockInterpreter;
    FTransport: ITransport;
。。。
 
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
FInterpreter這個對象引用就是這兒定義的。

procedure TDataBlockInterpreter.InterpretData(const Data: IDataBlock);
var
  Action: Integer;
begin
  Action := Data.Signature;//取出由用戶端傳來的資料區塊中請求標誌值
        //用戶端資料區塊的具體資料格式等會兒說.
  if (Action and asMask) = asError then DoException(Data);
  try
    case (Action and asMask) of     //根據用戶端的請求標誌值作相應的處理.
            //呵,就只有這麼幾個。一個大型的MIDAS系統
           //就全站在它們肩上.
      asInvoke: DoInvoke(Data);
      asGetID: DoGetIDsOfNames(Data);
      asCreateObject: DoCreateObject(Data);
      asFreeObject: DoFreeObject(Data);
      asGetServers: DoGetServerList(Data);
      asGetAppServers: DoGetAppServerList(Data);//取這個再進一步讀一讀.
    else
      if not DoCustomAction(Action and asMask, Data) then
        raise EInterpreterError.CreateResFmt(@SInvalidAction, [Action and asMask]);
    end;
  except
    on E: Exception do
    begin
      Data.Clear;
      WriteVariant(E.Message, Data);
      Data.Signature := ResultSig or asError;
      FSendDataBlock.Send(Data, False);
    end;
  end;
end;
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
順著線一步步摸下去，
看它是怎麼取APPSERVER列表返回用戶端的。

很簡單，就是通過GetMIDASAppServerList取本地的MIDAS應用服務
器列表，然後將其寫在Data中，傳回用戶端就了事。
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
procedure TDataBlockInterpreter.DoGetAppServerList(const Data: IDataBlock);
var
  VList: OleVariant;
  List: TStringList;
  i: Integer;
begin
  Data.Clear;
  List := TStringList.Create;
  try
    GetMIDASAppServerList(List, FCheckRegValue);//取原生應用伺服器列表
          //想知道它是怎麼做的嗎?
          //源碼上都有,自己看.
    if List.Count > 0 then
    begin
      VList := VarArrayCreate([0, List.Count - 1], varOleStr);
      for i := 0 to List.Count - 1 do
        VList[i] := List[i];
    end else
      VList := NULL;
  finally
    List.Free;
  end;
  WriteVariant(VList, Data);
  Data.Signature := ResultSig or asGetAppServers;
  FSendDataBlock.Send(Data, False);//將應用伺服器列表傳回用戶端
end;

========================================================
哦..前面還有一個地方沒有說,就是這個神秘的Data的資料格式,它是以介面
形式提供的,
這個程式中用的是TDataBlock中實現的這個介面.
源碼中可以看出,TDataBlock中包含了一個Stream,
function TDataBlock.GetSize: Integer;
begin
  Result := FStream.Size - BytesReserved;//BytesReserved的值這兒是8
end;
從這兒可以看出.資料區塊是從Stream的第8個位元組算起,前面就是兩個int型數的位置了.
function TDataBlock.GetSignature: Integer;
begin
  FStream.Position := 0;
  FStream.Read(Result, SizeOf(Result));
end;
呵, 沒錯, Stream的頭四位元組就是它的Signature.用戶端的請求標誌就是放在這兒.

function TDataBlock.GetStream: TStream;
var
  DataSize: Integer;
begin
  FStream.Position := 4;
  DataSize := FStream.Size - BytesReserved;
  FStream.Write(DataSize, SizeOf(DataSize));
  FStream.Position := 0;
  Result := FStream;
end;
這兒很明顯,就是Data中包含資料的長度值.

需要提一下的是,如果你想改變一下傳輸資料區塊的格式,比如給它加密加壓什麼的,
中需要自己來實現IDataBlock介面,替掉TDataBlock就是了.

從這些源碼中可以得到很多東西,無論是從優美的風格上,
無論是通訊程式開發還是MIDAS資料庫以及DCOM學習或應用者,
它都是值得一讀的來源程式.
我覺得,更重要的是,它提供了一個嚴謹優美和實際的範例,更給出了
一個靈活實用的架構體系。

 

                                             halfdream(哈欠) 於2001-10-14晚