asp常用的幾種郵件發送組件程式

asp常用的幾種郵件發送組件程式

<%
Dim SendMail,cdoConfig

Sub Jmail(email,topic,mailbody)
 On Error Resume Next
 Dim JMail
 Set JMail=Server.CreateObject("JMail.Message")
 JMail.silent=True
 JMail.Logging=True
 JMail.Charset="gb2312"
 If Not(Newasp.MailUserName = "" Or Newasp.MailPassword = "") Then
  JMail.MailServerUserName = Newasp.MailUserName '您的郵件伺服器登入名稱
  JMail.MailServerPassword = Newasp.MailPassword '登入密碼
 End If
 JMail.ContentType = "text/html"
 JMail.Priority = 1
 JMail.MailDomain = "govery.cn"
 JMail.From = Newasp.MailFrom  '郵件地址
 JMail.FromName = Newasp.SiteName  '網站名稱
 JMail.AddRecipient email
 JMail.Subject = topic
 JMail.Body = mailbody
 If Err <> 0 Then
  SendMail="False"
 Else
  JMail.Send (Newasp.MailServer)   '發郵件伺服器地址
  JMail.ClearRecipients()
  If Err <> 0 Then
   SendMail="False"
  Else
   SendMail="OK"
  End If
 End If
 Set JMail=nothing
End Sub

Sub Cdonts(email,topic,mailbody)
 On Error Resume Next
 Dim objCDOMail
 Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
 objCDOMail.From = Newasp.MailFrom  '郵件地址
 objCDOMail.To = email
 objCDOMail.Subject = topic
 objCDOMail.BodyFormat = 0
 objCDOMail.MailFormat = 0
 objCDOMail.Body = mailbody
 If Err <> 0 Then
  SendMail="False"
 Else
  objCDOMail.Send
  If Err <> 0 Then
   SendMail="False"
  Else
   SendMail="OK"
  End If
 End If
 Set objCDOMail = Nothing
End Sub

Sub aspemail(email,topic,mailbody)
 On Error Resume Next
 Dim Mailer
 Set Mailer=Server.CreateObject("Persits.MailSender")
 Mailer.Charset = "gb2312"
 Mailer.IsHTML = True
 Mailer.username = Newasp.MailUserName '伺服器上有效使用者名稱
 Mailer.password = Newasp.MailPassword '伺服器上有效密碼
 Mailer.Priority = 1
 Mailer.Host = Newasp.setting(9)
 Mailer.Port = 25 ' 該項可選.連接埠25是預設值
 Mailer.From = Newasp.MailFrom   '郵件地址
 Mailer.FromName = Newasp.SiteName ' 該項可選
 Mailer.AddAddress email,email
 Mailer.Subject = topic
 Mailer.Body = mailbody
 If Err <> 0 Then
  SendMail="False"
 Else
  Mailer.Send
  If Err <> 0 Then
   SendMail="False"
  Else
   SendMail="OK"
  End If
 End If
 Set Mailer = Nothing
End Sub

Sub CDOMessage(Email,Topic,Mailbody)
 On Error Resume Next
 If Not IsObject(cdoConfig) Then
  Call CreatCDOConfig()
 End If
 Dim Obj
 Set Obj = Server.CreateObject("CDO.Message")
 With Obj
  Set .Configuration = cdoConfig
  '.From = Newasp.MailFrom
  .To = Email
  .Subject = Topic
  .TextBody = Mailbody
  .Send
 End With
 Set Obj = Nothing
 Set cdoConfig = Nothing
 If Err<>0 Then
  SendMail="False"
 Else
  SendMail="OK"
 End If
End Sub

Sub CreatCDOConfig()
 On Error Resume Next
 Dim Sch
 sch = "http://schemas.microsoft.com/cdo/configuration/"
 Set cdoConfig = Server.CreateObject("CDO.Configuration")
 With cdoConfig.Fields
  .Item(sch & "smtpserver") = Newasp.MailServer  '--SMTP 伺服器
  '.Item(sch & "smtpserverport") = 25
  .Item(sch & "sendusing") = 2
  .Item(sch & "smtpaccountname") = Newasp.SiteName
  .Item(sch & "sendemailaddress") = Newasp.MailFrom
  .Item(sch & "smtpuserreplyemailaddress") = 25
  '.Item(sch & "smtpauthenticate") = cdoBasic
  .Item(sch & "sendusername") = Newasp.MailUserName
  .Item(sch & "sendpassword") = Newasp.MailPassword
  .update
 End With
 If Err<>0 Then
  SendMail="False"
 End If
End Sub
%>