ASP調用帶參數預存程序的幾種方式

ASP調用帶參數預存程序的幾種方式 選擇自 hxfwsk 的 Blog
關鍵字 預存程序
出處

作者: 討飯貓

ASP調用帶參數預存程序的幾種方式

最近有很多的朋友問到調用預存程序的問題，這裡簡單介紹幾種ASP調用帶參數預存程序的方法。

1 這也是最簡單的方法,兩個輸入參數，無傳回值：
set connection = server.createobject("adodb.connection")
connection.open someDSN
Connection.Execute "procname varvalue1, varvalue2"

'將所有對象清為nothing，釋放資源
connection.close
set connection = nothing

2 如果要返回 Recordset 集:
set connection = server.createobject("adodb.connection")
connection.open someDSN
set rs = server.createobject("adodb.recordset")
rs.Open "Exec procname varvalue1, varvalue2",connection

'將所有對象清為nothing，釋放資源
rs.close
connection.close
set rs = nothing
set connection = nothing

3 以上兩種方法都不能有傳回值，（Recordset除外），如果要得到傳回值，需要用Command的方法。
首先說明，傳回值有兩種。一種是在預存程序中直接return一個值，就象C和VB的函數傳回值那樣；另一種是可以返回多個值，存
儲這些值的變數名稱需要在調用參數中先行指定。
這個例子要處理多種參數，輸入參數，輸出參數，返回記錄集以及一個直接傳回值（夠全了吧？）
預存程序如下：

use pubs
GO

-- 建立預存程序
create procedure sp_PubsTest

-- 定義三個參數變數，注意第三個，特別標記是用於輸出
@au_lname varchar (20),
@intID int,
@intIDOut int OUTPUT

AS

SELECT @intIDOut = @intID + 1

SELECT *
FROM authors
WHERE au_lname LIKE @au_lname + '%'

--直接返回一個值
RETURN @intID + 2

調用該預存程序的asp程式如下：

<%@ Language=VBScript %>
<%
Dim CmdSP
Dim adoRS
Dim adCmdSPStoredProc
Dim adParamReturnValue
Dim adParaminput
Dim adParamOutput
Dim adInteger
Dim iVal
Dim oVal
Dim adoField
Dim adVarChar

‘這些值在 VB 中是預定義常量，可以直接調用，但在 VBScript 中沒有預定義
adCmdSPStoredProc = 4
adParamReturnValue = 4
adParaminput = 1
adParamOutput = 2
adInteger = 3
adVarChar = 200

iVal = 5
oVal = 3

'建一個command對象
set CmdSP = Server.CreateObject("ADODB.Command")

'建立連結
CmdSP.ActiveConnection = "Driver={SQL Server};server=(local);Uid=sa;Pwd=;Database=Pubs"

'定義command 對象調用名稱
CmdSP.CommandText = "sp_PubsTest"

'設定command調用類型是預存程序 (adCmdSPStoredProc = 4)
CmdSP.CommandType = adCmdSPStoredProc

'往command 對象中加參數
'定義預存程序有直接傳回值，並且是個整數，省缺值是4
CmdSP.Parameters.Append CmdSP.CreateParameter("RETURN_VALUE", adInteger, adParamReturnValue, 4)
'定義一個字元型輸入參數
CmdSP.Parameters.Append CmdSP.CreateParameter("@au_lname", adVarChar, adParaminput, 20, "M")
'定義一個整型輸入參數
CmdSP.Parameters.Append CmdSP.CreateParameter("@intID", adInteger, adParamInput, , iVal)
'定義一個整型輸出參數
CmdSP.Parameters.Append CmdSP.CreateParameter("@intIDOut", adInteger, adParamOutput, oVal)

'運行預存程序，並得到返回記錄集
Set adoRS = CmdSP.Execute

'把每個記錄列印出來，其中的欄位是虛擬，可以不用管
While Not adoRS.EOF

for each adoField in adoRS.Fields
Response.Write adoField.Name & "=" & adoField.Value & "<br>" & vbCRLF
Next
Response.Write "<br>"
adoRS.MoveNext
Wend

'列印兩個輸出值：
Response.Write "<p>@intIDOut = “ & CmdSP.Parameters("@intIDOut").Value & "</p>"
Response.Write "<p>Return value = " & CmdSP.Parameters("RETURN_VALUE").Value & "</p>"

'大掃除
Set adoRS = nothing
Set CmdSP.ActiveConnection = nothing
Set CmdSP = nothing
%>

asp調用資料庫預存程序 選擇自 11830 的 Blog
關鍵字 asp,資料庫,預存程序
出處

asp調用資料庫預存程序

<%Set Dataconn = Server.CreateObject("ADODB.Connection")
'建立連線物件
Dataconn.Open "DSN=SinoTrans;SERVER=APP_SERVER;UID=sa;PWD=;APP=Microsoft(R) Developer Studio;WSID=APP_SERVER;Regional=Yes"
Set cmdTemp = Server.CreateObject("ADODB.Command")
'建立命令對象
Set rst = Server.CreateObject("ADODB.Recordset")
'建立記錄集對象
cmdTemp.CommandText = "dbo.pd_test" '預存程序名稱
cmdTemp.CommandType = 4
'命令類別為4,表示為預存程序
Set cmdTemp.ActiveConnection = Dataconn
Set tmpParam = cmdTemp.CreateParameter("Return Value", 3, 4, 4)
cmdTemp.Parameters.Append tmpParam
Set tmpParam = cmdTemp.CreateParameter("@BeginDate", 135, 1, 16, riqi)
'建立輸入參數對象
cmdTemp.Parameters.Append tmpParam
rst.Open cmdTemp, , 1, 3
'產生查詢結果
%>
這裡調用的預存程序為pd_test，這種是ADO中提供的標準方法，但存在一個問題，就是當在預存程序中有兩個以上的SELECT語句，但從邏輯上又不可能同時執行的時候，ADO會提示你預存程序中SELECT語句太多，解決方案是直接用ADO的CONNECTION對象的EXECUTE方法直接執行預存程序，如下：
<%
Set Dataconn = Server.CreateObject("ADODB.Connection")
'建立連線物件
Dataconn.Open "DSN=SinoTrans;SERVER=APP_SERVER;UID=sa;PWD=;APP=Microsoft(R) Developer Studio;WSID=APP_SERVER;Regional=Yes"
ss = "EXECUTE dbo.pd_test " & "'" & riqi1 & "'"
Set rs = dataconn.Execute(ss)
%>