sqlserver 重複資料刪除記錄處理（轉）_實用技巧

註：此處“重複”非完全重複,意為某欄位資料重複
　　HZT表結構
ID　int
Title　nvarchar(50)
AddDate　datetime
　　資料
一. 尋找重複記錄
　　1. 尋找全部重複記錄
Select * From 表 Where 重複欄位 In (Select 重複欄位 From 表 Group By 重複欄位 Having Count(*)>1)

2. 過濾重複記錄(只顯示一條)
Select * From HZT Where ID In (Select Max(ID) From HZT Group By Title)
註：此處顯示ID最大一條記錄
二. 重複資料刪除記錄
　　1. 刪除全部重複記錄（慎用）
Delete 表 Where 重複欄位 In (Select 重複欄位 From 表 Group By 重複欄位 Having Count(*)>1)

　　2. 保留一條（這個應該是大多數人所需要的）
Delete HZT Where ID Not In (Select Max(ID) From HZT Group By Title)
　　註：此處保留ID最大一條記錄

其它相關:

重複資料刪除記錄有大小關係時,保留大或小其中一個記錄

--> --> (Roy)產生測試數據

if not object_id('Tempdb..#T') is null
  drop table #T
Go
Create table #T([ID] int,[Name] nvarchar(1),[Memo] nvarchar(2))
Insert #T
select 1,N'A',N'A1' union all
select 2,N'A',N'A2' union all
select 3,N'A',N'A3' union all
select 4,N'B',N'B1' union all
select 5,N'B',N'B2'
Go

--I、Name相同ID最小的記錄(推薦用1,2,3),保留最小一條
方法1:
delete a from #T a where exists(select 1 from #T where Name=a.Name and ID<a.ID)
方法2:
delete a from #T a left join (select min(ID)ID,Name from #T group by Name) b on a.Name=b.Name and a.ID=b.ID 
where b.Id is null
方法3:
delete a from #T a where ID not in (select min(ID) from #T where Name=a.Name)
方法4(注:ID為唯一時可用):
delete a from #T a where ID not in(select min(ID)from #T group by Name)
方法5:
delete a from #T a where (select count(1) from #T where Name=a.Name and ID<a.ID)>0
方法6:
delete a from #T a where ID<>(select top 1 ID from #T where Name=a.name order by ID)
方法7:
delete a from #T a where ID>any(select ID from #T where Name=a.Name)
select * from #T

產生結果:
/*
ID     Name Memo
----------- ---- ----
1      A  A1
4      B  B1

(2 行受影響)
*/


--II、Name相同ID保留最大的一條記錄:
方法1:
delete a from #T a where exists(select 1 from #T where Name=a.Name and ID>a.ID)
方法2:
delete a from #T a left join (select max(ID)ID,Name from #T group by Name) b on a.Name=b.Name and a.ID=b.ID
where b.Id is null
方法3:
delete a from #T a where ID not in (select max(ID) from #T where Name=a.Name)
方法4(注:ID為唯一時可用):
delete a from #T a where ID not in(select max(ID)from #T group by Name)
方法5:
delete a from #T a where (select count(1) from #T where Name=a.Name and ID>a.ID)>0
方法6:
delete a from #T a where ID<>(select top 1 ID from #T where Name=a.name order by ID desc)
方法7:
delete a from #T a where ID<any(select ID from #T where Name=a.Name)
select * from #T
/*
ID     Name Memo
----------- ---- ----
3      A  A3
5      B  B2

(2 行受影響)
*/


--3、重複資料刪除記錄沒有大小關係時，處理重複值
--> --> (Roy)產生測試數據
 
if not object_id('Tempdb..#T') is null
  drop table #T
Go
Create table #T([Num] int,[Name] nvarchar(1))
Insert #T
select 1,N'A' union all
select 1,N'A' union all
select 1,N'A' union all
select 2,N'B' union all
select 2,N'B'
Go

方法1:
if object_id('Tempdb..#') is not null
  drop table #
Select distinct * into # from #T--排除重複記錄結果集產生暫存資料表#
truncate table #T--清空表
insert #T select * from #  --把暫存資料表#插入到表#T中

--查看結果
select * from #T

/*
Num     Name
----------- ----
1      A
2      B

(2 行受影響)
*/

--重新執行測試資料後用方法2
方法2:
alter table #T add ID int identity--新增識別欄位
go
delete a from #T a where exists(select 1 from #T where Num=a.Num and Name=a.Name and ID>a.ID)--只保留一條記錄
go
alter table #T drop column ID--刪除識別欄位

--查看結果
select * from #T

/*
Num     Name
----------- ----
1      A
2      B

(2 行受影響)

*/

--重新執行測試資料後用方法3
方法3:
declare Roy_Cursor cursor local for
select count(1)-1,Num,Name from #T group by Num,Name having count(1)>1
declare @con int,@Num int,@Name nvarchar(1)
open Roy_Cursor
fetch next from Roy_Cursor into @con,@Num,@Name
while @@Fetch_status=0
begin 
  set rowcount @con;
  delete #T where Num=@Num and Name=@Name
  set rowcount 0;
  fetch next from Roy_Cursor into @con,@Num,@Name
end
close Roy_Cursor
deallocate Roy_Cursor

--查看結果
select * from #T
/*
Num     Name
----------- ----
1      A
2      B

(2 行受影響)
*/