SQL Server 分頁預存程序

CREATE PROCEDURE pagination
  @tblName varchar(255), -- 表名
  @strGetFields varchar(1000) = '*', -- 需要返回的列
  @fldName varchar(255)='', -- 排序的欄位名
  @PageSize int = 10, -- 頁尺寸
  @PageIndex int = 1, -- 頁碼
  @doCount bit = 0, -- 返回記錄總數, 非 0 值則返回
  @OrderType bit = 0, -- 設定排序類型, 非 0 值則降序
  @strWhere varchar(1500) = '' -- 查詢條件 (注意: 不要加 where)
AS
  declare @strSQL varchar(5000) -- 主語句
  declare @strTmp varchar(110) -- 臨時變數
  declare @strOrder varchar(400) -- 排序類型
if @doCount != 0
  begin
    if @strWhere !=''
      set @strSQL = 'select count(*) as Total from [' + @tblName + '] where '+@strWhere
    else
      set @strSQL = 'select count(*) as Total from [' + @tblName + ']'
    end
--以上代碼的意思是如果@doCount傳遞過來的不是0，就執行總數統計。以下的所有代碼都是@doCount為0的情況
else
  begin
    if @OrderType != 0
  begin
    set @strTmp = '<(select min'
    set @strOrder = ' order by [' + @fldName +'] desc'
--如果@OrderType不是0，就執行降序，這句很重要！
end
else
  begin
    set @strTmp = '>(select max'
    set @strOrder = ' order by [' + @fldName +'] asc'
  end
  if @PageIndex = 1
    begin
      if @strWhere != ''
        set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from [' + @tblName + '] where ' + @strWhere + ' ' + @strOrder
    else
        set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from ['+ @tblName + '] '+ @strOrder
--如果是第一頁就執行以上代碼，這樣會加快執行速度
    end
  else
    begin
--以下代碼賦予了@strSQL以真正執行的SQL代碼
      set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from [' + @tblName + ']
                    where [' + @fldName + ']' + @strTmp + '(['+ @fldName + '])
                    from (select top ' + str((@PageIndex-1)*@PageSize) + ' ['+ @fldName + ']
                    from [' + @tblName + ']' + @strOrder + ')
                    as tblTmp)'+ @strOrder
      if @strWhere != ''
      set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from [' + @tblName + ']
                    where [' + @fldName + ']' + @strTmp + '([' + @fldName + '])
                    from (select top ' + str((@PageIndex-1)*@PageSize) + ' [' + @fldName + ']
                    from [' + @tblName + ']
                    where ' + @strWhere + ' ' + @strOrder + ')
                    as tblTmp) and ' + @strWhere + ' ' + @strOrder
    end
end
exec (@strSQL)
GO

 /*
-- 需要傳遞的參數
@tblName varchar(255), -- 表名
  @strGetFields varchar(1000) = '*', -- 需要返回的列
  @fldName varchar(255)='', -- 排序的欄位名
  @PageSize int = 10, -- 頁尺寸
  @PageIndex int = 1, -- 頁碼
  @doCount bit = 0, -- 返回記錄總數, 非 0 值則返回
  @OrderType bit = 0, -- 設定排序類型, 非 0 值則降序
  @strWhere varchar(1500) = '' -- 查詢條件 (注意: 不要加 where)
-- 調用測試

exec pagination @tblName='jobs', @strGetFields='job_id,job_desc,min_lvl,max_lvl',
                @fldName='job_id',@PageSize=3,@PageIndex=1,
                @doCount=0,@OrderType=1,@strWhere=''
*/
============================================

CREATE PROC SP_PageList
@tbname     sysname,           --要分頁顯示的表名
@FieldKey   sysname,           --用於定位記錄的主鍵(惟一鍵)欄位,只能是單個欄位
@PageCurrent int=1,             --要顯示的頁碼
@PageSize   int=10,            --每頁的大小(記錄數)
@FieldShow  nvarchar(1000)='',  --以逗號分隔的要顯示的欄位列表,如果不指定,則顯示所有欄位
@FieldOrder  nvarchar(1000)='', --以逗號分隔的排序欄位列表,可以指定在欄位後面指定DESC/ASC
                                          --用於指定排序次序
@Where     nvarchar(1000)='',  --查詢條件
@RecordCount  int OUTPUT,       --總記錄數
@PageCount  int OUTPUT        --總頁數
AS
DECLARE @sql nvarchar(4000)
SET NOCOUNT ON
--檢查對象是否有效
IF OBJECT_ID(@tbname) IS NULL
BEGIN
RAISERROR(N'對象"%s"不存在',1,16,@tbname)
RETURN
END
IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0
AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0
AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0
BEGIN
RAISERROR(N'"%s"不是表、視圖或者資料表值函式',1,16,@tbname)
RETURN
END

--分分頁欄位檢查
IF ISNULL(@FieldKey,N'')=''
BEGIN
RAISERROR(N'分頁處理需要主鍵（或者惟一鍵）',1,16)
RETURN
END

--其他參數檢查及規範
IF ISNULL(@PageCurrent,0)<1 SET @PageCurrent=1
IF ISNULL(@PageSize,0)<1 SET @PageSize=10
IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*'
IF ISNULL(@FieldOrder,N'')=N''
SET @FieldOrder=N''
ELSE
SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder)
IF ISNULL(@Where,N'')=N''
SET @Where=N''
ELSE
SET @Where=N'WHERE ('+@Where+N')'

--如果@PageCount為NULL值,則計算總頁數(這樣設計可以只在第一次計算總頁數,以後調用時,把總頁數傳回給預存程序,避免再次計算總頁數,對於不想計算總頁數的處理而言,可以給@PageCount賦值)
IF @PageCount IS NULL
BEGIN
SET @sql=N'SELECT @PageCount=COUNT(*)'
+N' FROM '+@tbname
+N' '+@Where
EXEC sp_executesql @sql,N'@PageCount int OUTPUT',@PageCount OUTPUT
SET @RecordCount = @PageCount
SET @PageCount=(@PageCount+@PageSize-1)/@PageSize
END

--計算分頁顯示的TOPN值
DECLARE @TopN varchar(20),@TopN1 varchar(20)
SELECT @TopN=@PageSize,
@TopN1=@PageCurrent*@PageSize

--第一頁直接顯示
IF @PageCurrent=1
EXEC(N'SELECT TOP '+@TopN
+N' '+@FieldShow
+N' FROM '+@tbname
+N' '+@Where
+N' '+@FieldOrder)
ELSE
BEGIN
SELECT @PageCurrent=@TopN1,
@sql=N'SELECT @n=@n-1,@s=CASE WHEN @n<'+@TopN
+N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey
+N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname
+N' '+@Where
+N' '+@FieldOrder
SET ROWCOUNT @PageCurrent
EXEC sp_executesql @sql,
N'@n int,@s nvarchar(4000) OUTPUT',
@PageCurrent,@sql OUTPUT
SET ROWCOUNT 0
IF @sql=N''
EXEC(N'SELECT TOP 0'
+N' '+@FieldShow
+N' FROM '+@tbname)
ELSE
BEGIN
SET @sql=STUFF(@sql,1,1,N'')
--執行查詢
EXEC(N'SELECT TOP '+@TopN
+N' '+@FieldShow
+N' FROM '+@tbname
+N' WHERE '+@FieldKey
+N' IN('+@sql
+N') '+@FieldOrder)
END
END
GO