SQL SERVER 殺死結進程預存程序

use master        --必須在master資料庫中建立
go

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_lockinfo]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_lockinfo]
GO

/**//*--處理死結

        查看當前進程,或死結進程,並能自動殺掉死進程

        因為是針對死結的,所以如果有死結進程,只能查看死結進程
        當然,你可以通過參數控制,不管有沒有死結,都只查看死結進程

        感謝: caiyunxia,jiangopen 兩位提供的參考資訊

--鄒建 2004.04(引用請保留此資訊)--*/

/**//*--調用樣本

        exec p_lockinfo
--*/
create proc p_lockinfo
@kill_lock_spid bit=1,                --是否殺掉死結的進程,1 殺掉, 0 僅顯示
@show_spid_if_nolock bit=1        --如果沒有死結的進程,是否顯示正常進程資訊,1 顯示,0 不顯示
as
set nocount on
declare @count int,@s nvarchar(1000),@i int
select id=identity(int,1,1),標誌,
        進程ID=spid,線程ID=kpid,塊進程ID=blocked,資料庫ID=dbid,
        資料庫名=db_name(dbid),使用者ID=uid,使用者名稱=loginame,累計CPU時間=cpu,
        登陸時間=login_time,開啟事務數=open_tran,        進程狀態=status,
        工作站名=hostname,應用程式名稱=program_name,工作站進程ID=hostprocess,
        網域名稱=nt_domain,網卡地址=net_address
into #t from(
        select 標誌='死結的進程',
                spid,kpid,a.blocked,dbid,uid,loginame,cpu,login_time,open_tran,
                status,hostname,program_name,hostprocess,nt_domain,net_address,
                s1=a.spid,s2=0
        from master..sysprocesses a join (
                select blocked from master..sysprocesses group by blocked
                )b on a.spid=b.blocked where a.blocked=0
        union all
        select '|_犧牲品_>',
                spid,kpid,blocked,dbid,uid,loginame,cpu,login_time,open_tran,
                status,hostname,program_name,hostprocess,nt_domain,net_address,
                s1=blocked,s2=1
        from master..sysprocesses a where blocked<>0
)a order by s1,s2

select @count=@@rowcount,@i=1

if @count=0 and @show_spid_if_nolock=1
begin
        insert #t
        select 標誌='正常的進程',
                spid,kpid,blocked,dbid,db_name(dbid),uid,loginame,cpu,login_time,
                open_tran,status,hostname,program_name,hostprocess,nt_domain,net_address
        from master..sysprocesses
        set @count=@@rowcount
end

if @count>0
begin
        create table #t1(id int identity(1,1),a nvarchar(255),b Int,EventInfo nvarchar(1000))
        if @kill_lock_spid=1
        begin
                declare @spid varchar(255),@標誌 varchar(255)
                while @i<=@count
                begin
                        select @spid=進程ID,@標誌=標誌 from #t where id=@i
                        insert #t1 exec('dbcc inputbuffer('+@spid+')')
                        if @@rowcount=0 insert #t1(a) values(null)
                        if @標誌='死結的進程' exec('kill '+@spid)
                        set @i=@i+1
                end
        end
        else
                while @i<=@count
                begin
                        select @s='dbcc inputbuffer('+cast(進程ID as varchar)+')' from #t where id=@i
                        insert #t1 exec(@s)
                        if @@rowcount=0 insert #t1(a) values(null)
                        set @i=@i+1
                end
        select a.*,進程的SQL語句=b.EventInfo
        from #t a join #t1 b on a.id=b.id
        order by 進程ID
end
set nocount off
go