超級ASP大分頁_我的類容我做主

超級ASP大分頁_我的類容我做主 選擇自 AppleBBS 的 Blog
關鍵字 超級ASP大分頁_我的類容我做主
出處
<%
'===================================================================
'ShowMorePage ASP版本
'Version HuangJM1.00
'Code by maomao
'Create Date 2004-09-28
'QQ:5144707
'http://blog.csdn.net/maomaoysq
'Write for my lover:HuangJM '本程式可以免費使用、修改，但請保留以上資訊
'
'function
'本程式主要是對資料分頁的部分進行了封裝，而資料顯示部份完全由使用者自訂，
'支援URL多個參數:http://www.***.com/***.asp?aa=1&page=9&bb=2
'
'
'Paramers:
'PapgeSize 定義分頁每一頁的記錄數
'GetCurPageNum 返回當前頁的記錄集數目此屬性唯讀
'GetRS 返回經過分頁的Recordset此屬性唯讀
'GetConn 得到資料庫連接
'GetSQL 得到查詢語句
'Interface of Class
'ShowPage 顯示分頁導航條,唯一的公用方法
'
'#############類調用範例#################
'建立對象
'Set hjmPage=new ShowMorePage
'得到資料庫連接
'hjmPage.getconn=conn
'sql語句
'hjmPage.getsql="select * from shop_books where newsbook=1 order by bookid desc"
'設定每一頁的記錄條資料為20條,預設顯示10條
'hjmPage.pagesize=20
'顯示分頁資訊,可在任意位置調用，可以調用多次
'hjmPage.showpage()
'set rs=hjmPage.getrs() '返回Recordset
'顯示資料開始
'這裡就可以自訂顯示方式了
'for i=1 to hjmPage.GetCurPageNum '當前頁的記錄數目
'response.write left(trim(rs("bookname")),13)&"...."
'rs.movenext
'next
'顯示資料結束
'set hjmPage=nothing
'#############類調用範例#################
'===================================================================
Const Btn_First="<font face=""webdings"">9</font>" '定義第一頁按鈕顯示樣式
Const Btn_Prev="<font face=""webdings"">3</font>" '定義前一頁按鈕顯示樣式
Const Btn_Next="<font face=""webdings"">4</font>" '定義下一頁按鈕顯示樣式
Const Btn_Last="<font face=""webdings"">:</font>" '定義最後一頁按鈕顯示樣式
Const XD_Align="Center" '定義分頁資訊對齊
Const XD_Width="100%" '定義分頁資訊框大小
Class ShowMorePage
Private Obj_Conn,Obj_Rs,Str_Sql,int_PageSize,Str_Errors,Int_CurPage,Str_URL,Int_TotalPage,Int_TotalRecord

'=================================================================
'PageSize 屬性
'設定每一頁的分頁大小
'=================================================================
Public Property Let PageSize(intvalue)
If IsNumeric(intvalue) Then
int_PageSize=CLng(intvalue)
Else
Str_Errors=Str_Errors & "PageSize的參數不正確"
ShowError()
End If
End Property
Public Property Get PageSize
If int_PageSize="" or (not(IsNumeric(int_PageSize))) Then
PageSize=10
Else
PageSize=int_PageSize
End If
End Property
'=================================================================
'GetRS 屬性
'返回分頁後的記錄集
'=================================================================
Public Property Get GetRs()
if Int_TotalRecord= 0 then Call GetPage()
If not(Obj_Rs.eof and Obj_Rs.BOF) Then
if Int_CurPage<>1 then
if Int_CurPage-1<Int_TotalPage then
Obj_Rs.move (Int_CurPage-1)*PageSize
dim bookmark
bookmark=Obj_Rs.bookmark
else
Int_CurPage=1
end if
end if
End If
Set GetRs=Obj_Rs
End Property
'=================================================================
'GetCurPageNum 屬性
'返回當前頁的記錄集數目
'=================================================================
Public Property Get GetCurPageNum()
dim int_PageNum
int_PageNum = int_PageSize
if Int_TotalRecord= 0 then Call GetPage()
If Int_CurPage>Int_TotalPage Then
Int_CurPage=Int_TotalPage
int_PageNum = Int_TotalRecord-(Int_TotalPage-1)*int_PageSize
ElseIf Int_CurPage=Int_TotalPage Then
int_PageNum = Int_TotalRecord-(Int_TotalPage-1)*int_PageSize
End If
GetCurPageNum = int_PageNum
End Property
'================================================================
'GetConn 得到資料庫連接
'
'================================================================
Public Property Let GetConn(sconn)
Set Obj_Conn=sconn
End Property
'================================================================
'GetSQL 得到查詢語句
'
'================================================================
Public Property Let GetSQL(svalue)
Str_Sql=svalue
End Property

'==================================================================
'Class_Initialize 類的初始化
'初始化當前頁的值
'
'==================================================================
Private Sub Class_Initialize
'========================
'設定一些參數的黙認值
'========================
int_PageSize=10 '設定分頁的預設值為10
Int_TotalRecord= 0
'========================
'擷取當前面的值
'========================
If request("page")="" Then
Int_CurPage=1
ElseIf not(IsNumeric(request("page"))) Then
Int_CurPage=1
ElseIf CInt(Trim(request("page")))<1 Then
Int_CurPage=1
Else
Int_CurPage=CInt(Trim(request("page")))
End If
End Sub
'====================================================================
'openRS 開啟資料集
'有首頁、前一頁、下一頁、末頁、還有數字導航
'
'====================================================================
Private Sub openRS()
Set Obj_Rs=Server.createobject("adodb.recordset")
Obj_Rs.Open Str_Sql,Obj_Conn,1,1
End Sub
'====================================================================
'getPage 建立分頁導航條
'有首頁、前一頁、下一頁、末頁、還有數字導航
'
'====================================================================
Private Sub GetPage()
If TypeName(Obj_Rs)<>"Object" Then Call openRS()
Int_TotalRecord=Obj_Rs.RecordCount
If Int_TotalRecord<=0 Then
Str_Errors=Str_Errors & "總記錄數為零，請輸入資料"
Call ShowError()
End If
If Int_TotalRecord mod PageSize =0 Then
Int_TotalPage = Int_TotalRecord \ int_PageSize
Else
Int_TotalPage = Int_TotalRecord \ int_PageSize+1
End If
If Int_CurPage>Int_TotalPage Then
Int_CurPage=Int_TotalPage
End If
End Sub
'====================================================================
'ShowPage 建立分頁導航條
'有首頁、前一頁、下一頁、末頁、還有數字導航
'
'====================================================================
Public Sub ShowPage()
Dim str_tmp
Str_URL = GetUrl()
if Int_TotalRecord= 0 then Call GetPage()
'==================================================================
'顯示分頁資訊，各個模組根據自己要求更改顯求位置
'==================================================================
response.write ""
str_tmp=ShowFirstPrv
response.write str_tmp
str_tmp=showNumBtn
response.write str_tmp
str_tmp=ShowNextLast
response.write str_tmp
str_tmp=ShowPageInfo
response.write str_tmp
response.write ""
End Sub
'====================================================================
'ShowFirstPrv 顯示首頁、前一頁
'
'
'====================================================================
Private function ShowFirstPrv()
Dim Str_tmp,int_prvpage
If Int_CurPage=1 Then
str_tmp=Btn_First&" "&Btn_Prev
Else
int_prvpage=Int_CurPage-1
str_tmp="<a href="""&Str_URL & "1" & """>" & Btn_First&"</a> <a href=""" & Str_URL & CStr(int_prvpage) & """>" & Btn_Prev&"</a>"
End If
ShowFirstPrv=str_tmp
End function
'====================================================================
'ShowNextLast 下一頁、末頁
'
'
'====================================================================
Private function ShowNextLast()
Dim str_tmp,int_Nextpage
If Int_CurPage>=Int_TotalPage Then
str_tmp=Btn_Next & " " & Btn_Last
Else
Int_NextPage=Int_CurPage+1
str_tmp="<a href=""" & Str_URL & CStr(int_nextpage) & """>" & Btn_Next&"</a> <a href="""& Str_URL & CStr(Int_TotalPage) & """>" & Btn_Last&"</a>"
End If
ShowNextLast=str_tmp
End function

'====================================================================
'ShowNumBtn 數字導航
'每次顯示10頁
'
'====================================================================
Private function showNumBtn()
Dim i,str_tmp,m,n
m = Int_CurPage - 4
n = Int_TotalPage
if n>1 then
for i = 1 to 10
if m < 1 then m = 1
if m > n then
exit for
end if
str_tmp=str_tmp & "[<a href=""" & Str_URL & CStr(i) & """>"&i&"</a>] "
m = m + 1
next
end if
showNumBtn=str_tmp
End function

'====================================================================
'ShowPageInfo 分頁資訊
'更據要求自行修改
'
'====================================================================
Private function ShowPageInfo()
Dim str_tmp
str_tmp="頁次:"&Int_CurPage&"/"&Int_TotalPage&"頁 共"&Int_TotalRecord&"條記錄 "&int_PageSize&"條/每頁"
ShowPageInfo=str_tmp
End function
'==================================================================
'GetURL 得到當前的URL
'更據URL參數不同，擷取不同的結果
'
'==================================================================
Private function GetURL()
Dim strUrl,tmp_URL,i,j,search_str,result_url
search_str="page="
strUrl=Request.Servervariables("URL")
strUrl=split(strUrl,"/")
i=UBound(strUrl,1)
tmp_URL=strUrl(i)'得到當前頁檔案名稱
str_params=Trim(Request.Servervariables("QUERY_STRING"))
If str_params="" Then
result_url=tmp_URL & "?page="
Else
If InstrRev(str_params,search_str)=0 Then
result_url=tmp_URL & "?" & str_params &"&page="
Else
j=InstrRev(str_params,search_str)-2
If j=-1 Then
result_url=tmp_URL & "?page="
Else
str_lparams=Left(str_params,j)
str_rparams=right(str_params,len(str_params)-j-1)
if InStr(str_rparams,"&")<>0 then
str_rparams=right(str_rparams,len(str_rparams)-InStr(str_rparams,"&")+1)
else
str_rparams = ""
end if
result_url=tmp_URL & "?" & str_lparams&str_rparams&"&page="
End If
End If
End If
GetURL=result_url
End function
'====================================================================
' 設定 Terminate 事件。
'
'====================================================================
Private Sub Class_Terminate
Obj_Rs.close
Set Obj_Rs=nothing
Obj_Conn.close
set Obj_Conn = nothing
End Sub
'====================================================================
'ShowError 錯誤提示
'
'
'====================================================================
Private Sub ShowError()
If Str_Errors <> "" Then
Response.Write("" & Str_Errors & "")
Response.End
End If
End Sub
End class
%>

<!--#include file="include/function.asp"-->
<%
dim conn
call dbconnect()
'#############類調用範例#################
'建立對象
Set hjmPage=new ShowMorePage
'得到資料庫連接
hjmPage.getconn=conn
'sql語句
hjmPage.getsql="select Top 6 * from shop_books where newsbook=1 order by bookid desc"
'設定每一頁的記錄條資料為5條
hjmPage.pagesize=2
set rs=hjmPage.getrs() '返回Recordset
'顯示分頁資訊，這個方法可以，在set rs=hjmPage.getrs()以後,可在任意位置調用，可以調用多次
hjmPage.showpage()
'顯示資料
Response.Write("<br/>")
for i=1 to hjmPage.GetCurPageNum '當前頁的記錄數目
'這裡就可以自訂顯示方式了
%>