ASP實現GB2312字元與區位碼的相互轉換的代碼_應用技巧

研究編碼，得知GB2312編碼與區位碼的關係，嘗試之後，得此程式。
搜尋，似乎沒人寫，故發此地。
原創首發：
http://bbs.blueidea.com
http://mytju.com/classcode/
任意轉載，任意使用。
1.簡述
（1）GB2312標準的定義，其實就是區位碼。
共94行，94列，行就是區號，列就是位號。
如“啊”字區號為16，位號為01，它的區位碼就是1601。
（2）每個字元由區號+位號組成，共佔兩個位元組。
每個位元組都是01-94，與通訊控制符0-31衝突，
所以，將區號和位號分別加上32，以避免衝突。
（3）由上，每個位元組是33-126，與ASCII編碼0-127衝突，
所以將最高位置為1，也就是加上128，以避免衝突。
所以，最終，每個位元組為161-254。
2。實現
原理很簡單，加加減減即可實現。
直接將我完成的函數帖於此處。

複製代碼 代碼如下:

'----取得區位碼的函數--------------------- 
Function CharToQWM(byVal str) 
    dim sHex,sHigh,sLow,iLow,iHigh,sResult 
    sHex=Hex(Asc(str)) '取得字元的內碼的編碼，如B0A1，此編碼是正確的順序，不必交換高低位。 
    sHigh=Left(sHex,2) '取得編碼的高位，如B0。 
    sLow=Right(sHex,2) '取得編碼的低位，如A1。 
    'GB2312內碼範圍為&HA1A1--&HFEFE，每個位元組都在A1-FE之間。 
    if NOT (sHigh>="A1" AND sHigh<="FE") then 
        CharToQWM="" 
        Exit Function 
    end if 
    if NOT (sLow>="A1" AND sLow<="FE") then 
        CharToQWM="" 
        Exit Function 
    end if 
    'GB交換碼僅使用了7位，高位置1，即為內碼。反過來就是將高位置0，可得到交換碼。 
    iLow=Clng("&H" & sLow)-128  
    iHigh=Clng("&H" & sHigh)-128 
    '區位碼與控制碼0-31衝突，所以加上32之後，即是交換碼。反過來減去32即可。 
    iLow=iLow-32 
    iHigh=iHigh-32 
    'OK，區位碼已經得到。 
    sResult="" 
    if iHigh<10 then 
        sResult = sResult & "0" & Cstr(iHigh) 
    else 
        sResult = sResult & Cstr(iHigh) 
    end if 
    if iLow<10 then 
        sResult = sResult & "0" & Cstr(iLow) 
    else 
        sResult = sResult & Cstr(iLow) 
    end if 
    CharToQWM=sResult 
End Function 
'----根據區位碼得到字元的函數--------------------- 
Function QWMToChar(byVal str,byVal doCheckFlg) 
    dim sHex,sHigh,sLow,iLow,iHigh,sResult 
    '-------------檢查輸入格式-------------- 
    if doCheckFlg then 
        if Len(str)<>4 then 
            QWMToChar="" 
            Exit Function 
        end if 
        '--4位必須都是數字 
        dim i,iAsc 
        for i=1 to 4 
            iAsc=Asc(mid(str,i,1)) 
            if NOT (iAsc>=&H30 AND iAsc<=&H39) then 
                QWMToChar="" 
                Exit Function 
            end if 
        next 
        '--區號，位號都要在01-94之間 
        iHigh=Clng(Left(str,2)) 
        iLow=Clng(Right(str,2)) 
        if NOT (iHigh>=1 AND iHigh<=94) then 
            QWMToChar="" 
            Exit Function 
        end if 
        if NOT (iLow>=1 AND iLow<=94) then 
            QWMToChar="" 
            Exit Function 
        end if 
    end if 
    '-------------檢查完畢------------------ 
    iHigh=Clng(Left(str,2)) 
    iLow=Clng(Right(str,2)) 
    iHigh=iHigh + 32 + 128 
    iLow=iLow + 32 + 128 
    sHex=Hex(iHigh) & Hex(iLow) 
    QWMToChar=Chr("&H" & sHex) 
End Function 

使用方法：
-----------------------------------------------------------------------------------------------------

複製代碼 代碼如下:

dim i,str,sChar 
str="娃哈哈" 
for i=1 to Len(str) 
       sChar=Mid(str,i,1)  
       Response.write sChar & ":" & CharToQWM(sChar) &"<br>" 
next 
----------------------------------------------------------------------------------------------------- 
dim str 
str="1601|1602|1603} 
if instr(str,"|")>0 then 
       dim s,sCharArray,i 
       sCharArray=Split(str,"|") 
       for i=0 to Ubound(sCharArray) 
              s=s & QWMToChar(trim(sCharArray(i)),True) 
       next 
       str=s 
else 
       str=QWMToChar(str,True) 
end if 

.......
-----------------------------------------------------------------------------------------------------
3.線上使用
http://www.mytju.com/classcode/tools/quweima.asp
進入以上網址即可線上查閱。