使用SQL Server 2000建立臨時Job非同步執行SQL 指令碼

來源:互聯網
上載者:User
server|建立|指令碼|非同步|執行
應用情境:
    在龐大的資料庫中很多複雜的更新查詢非常的耗時。為了避免使用者長時間的等待,那些耗時的操作可以採用非同步執行的方法,立刻返回執行資訊給使用者,同時在資料庫後台執行操作,等到執行完畢再更新資料表。
   
開發環境:
SQL SERVER2000 .NET

解決方案:
    在SQL SERVER2000中建立一個臨時的Job,(或者固定的Job,根據具體的應用情境),傳遞需要執行的SQL batch指令碼,然後啟動這個Job。這樣就可以在資料庫獲得非同步呼叫的功能了。由於建立的是臨時的Job,
SQL SERVER在該Job運行結束以後會自動刪除該Job。

缺點:該預存程序必須指定資料庫的名字

====================================================================================
/******************************************************************************
 * Author: iret
 * Desc: Create temporary job to provide asynchronously invoking SQL batch
 *           在SQL SERVER 2000中建立用於執行非同步呼叫的臨時Job
 * @EXECSQL: Transact-SQL batch
 * Eample: EXEC dbo.AsynchronousInvoking @EXECSQL = 'UPDTAE customer SET balance = 0'
 * 缺點:該預存程序必須指定資料庫的名字
 * Modified Date: 2004/11/03
 ******************************************************************************/
CREATE Procedure dbo.AsynchronousInvoking
 @EXECSQL nvarchar(4000)
AS

BEGIN TRANSACTION           
  DECLARE @JobID BINARY(16) 
  DECLARE @ReturnCode INT   
  SELECT @ReturnCode = 0    

BEGIN

  -- Add the job
  EXECUTE @ReturnCode = msdb.dbo.sp_add_job @job_id = @JobID OUTPUT ,
     @job_name = N'temp_sqljob',
     @owner_login_name = N'',
     @description = N'description for job', -- the description of the job 
     @category_name = N'[Uncategorized (Local)]',
     @enabled = 1,
     @notify_level_email = 0,
     @notify_level_page = 0,
     @notify_level_netsend = 0,
     @notify_level_eventlog = 0,
     @delete_level= 3
     
  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

  -- Add the job steps
  EXECUTE @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID,
     @step_id = 1,
     @step_name = N'step1',
     @command = @EXECSQL, -- sql batch
     --缺點:該預存程序必須指定資料庫的名字
     @database_name = N'your_database_name', --the database name of the job to manipulate
     @server = N'',
     @database_user_name = N'appuser',
     @subsystem = N'TSQL',
     @cmdexec_success_code = 0,
     @flags = 0,
     @retry_attempts = 0, --execute once only
     @retry_interval = 0,
     @output_file_name = N'',
     @on_success_step_id = 0,
     @on_success_action = 1, -- on success abort
     @on_fail_step_id = 0,
     @on_fail_action = 2 -- on fail abort
     
  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 

  --set the star step id of the job
  EXECUTE @ReturnCode = msdb.dbo.sp_update_job @job_id = @JobID,
              @start_step_id = 1

  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
 
  -- Add the Target Servers
  EXECUTE @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @JobID,
          @server_name = N'(local)'
         
  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 
 
END

COMMIT TRANSACTION         
GOTO   EndSave             

QuitWithRollback:
  IF (@@TRANCOUNT > 0) BEGIN
    ROLLBACK TRANSACTION 
    RETURN 1
  END
EndSave:

--star the job immediately
EXEC @ReturnCode = msdb.dbo.sp_start_job @job_id = @JobID
 
--return to the invoker immediately
RETURN @ReturnCode

GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO

 


相關文章

Beyond APAC's No.1 Cloud

19.6% IaaS Market Share in Asia Pacific - Gartner IT Service report, 2018

Learn more >

Apsara Conference 2019

The Rise of Data Intelligence, September 25th - 27th, Hangzhou, China

Learn more >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。