在ASP中按指定參數格式化顯示時間的函數

函數|顯示|函數 <%
'該函數作用：按指定參數格式化顯示時間。
'numformat=1:將時間轉化為yyyy-mm-dd hh:nn格式。
'numformat=2:將時間轉化為yyyy-mm-dd格式。
'numformat=3:將時間轉化為hh:nn格式。
'numformat=4:將時間轉化為yyyy年mm月dd日 hh時nn分格式。
'numformat=5:將時間轉化為yyyy年mm月dd日格式。
'numformat=6:將時間轉化為hh時nn分格式。
'numformat=7:將時間轉化為yyyy年mm月dd日 星期×格式。
'numformat=8:將時間轉化為yymmdd格式。
'numformat=9:將時間轉化為mmdd格式。

function formatdate(shijian,numformat)
dim ystr,mstr,dstr,hstr,nstr '變數含義分別為年字串，月字串，日字串，時字串，分字串

if isnull(shijian) then
numformat=0
else
ystr=DatePart("yyyy",shijian)

if DatePart("m",shijian)>9 then
mstr=DatePart("m",shijian)
else
mstr="0"&DatePart("m",shijian)
end if

if DatePart("d",shijian)>9 then
dstr=DatePart("d",shijian)
else
dstr="0"&DatePart("d",shijian)
end if

if DatePart("h",shijian)>9 then
hstr=DatePart("h",shijian)
else
hstr="0"&DatePart("h",shijian)
end if

if DatePart("n",shijian)>9 then
nstr=DatePart("n",shijian)
else
nstr="0"&DatePart("n",shijian)
end if
end if

select case numformat
case 0
formatdate=""
case 1
formatdate=ystr&"-"&mstr&"-"&dstr&" "&hstr&":"&nstr
case 2
formatdate=ystr&"-"&mstr&"-"&dstr
case 3
formatdate=hstr&":"&nstr
case 4
formatdate=ystr&"年"&mstr&"月"&dstr&"日 "&hstr&"時"&nstr&"分"
case 5
formatdate=ystr&"年"&mstr&"月"&dstr&"日"
case 6
formatdate=hstr&"時"&nstr&"分"
case 7
formatdate=ystr&"年"&mstr&"月"&dstr&"日 "&WeekdayName(Weekday(shijian))
case 8
formatdate=right(ystr,2)&mstr&dstr
case 9
formatdate=mstr&dstr
end select
end function
%>

現在用ASP.NET一切都簡單多了，還是寫出來紀念一下原來用ASP的歲月。