使用vbscript指令碼調用web服務

來源:互聯網
上載者:User
vbscript|web|web服務|指令碼 最近碰到的一個問題,需要在asp和用戶端調用.NET的webservice,也就是說需要用vbscript或javascript來調用webservice。在網上看了看,大多數方案都是利用SOAP Toolkit,但是因為SOAP Toolkit在今年就會被停止後續的支援了,並且要使用soapclient需要專門安裝SOAP Toolkit,這對用戶端來說不具有通用性,因此想到了使用xmlhttp,利用xmlhttp來和webservice互動。

用戶端代碼如下:
<script language="vbscript">
Set objHTTP = CreateObject("MSXML2.XMLHTTP")
Set xmlDOC =CreateObject("MSXML.DOMDocument")
strWebserviceURL = "http://localhost/possible/Service1.asmx/add"
'設定參數及其值
strRequest = "x=2&y=3"
objHTTP.Open "POST", strWebserviceURL, False
'設定這個Content-Type很重要
objHTTP.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
objHTTP.Send(strRequest)
bOK = xmlDOC.load(objHTTP.responseXML)
'看看狀態值
msgBox objHTTP.Status
msgbox objHTTP.StatusText
'objHTTP.Status=200,這裡就可以處理返回的xml片段了
'如果需要,可以替換返回的xml字串當中的<和>
xmlStr = xmlDOC.xml
xmlStr = Replace(xmlStr,"<","<",1,-1,1)
xmlStr = Replace(xmlStr,">",">",1,-1,1)
msgbox xmlStr
</script>

改為伺服器端的asp代碼為:
<%
Set objHTTP = Server.CreateObject("MSXML2.XMLHTTP")
Set xmlDOC =Server.CreateObject("MSXML.DOMDocument")
strWebserviceURL = "http://localhost/possible/Service1.asmx/add"
'設定參數及其值
strRequest = "x=2&y=3"
objHTTP.Open "POST", strWebserviceURL, False
'設定這個Content-Type很重要
objHTTP.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
objHTTP.Send(strRequest)
bOK = xmlDOC.load(objHTTP.responseXML)
'看看狀態值
if objHTTP.Status=200 then
xmlStr = xmlDOC.xml
xmlStr = Replace(xmlStr,"<","<",1,-1,1)
xmlStr = Replace(xmlStr,">",">",1,-1,1)
Response.Write xmlStr
else
Response.Write objHTTP.Statu&"<br>"
Response.Write objHTTP.StatusText
end if
%>

以上代碼在本地測試都沒有問題(在部署webservice的本地機器上測試的),然而把strWebserviceURL = "http://localhost/possible/Service1.asmx/add"改為部署在其他機器上的webservice時,卻出了問題,結果一直是返回500錯誤,即objHTTP.Status一直都為500。
原因在於.Net Framework1.1預設不支援HttpGet和HttpPost。如果修改webservice裡的web.config增加
<webServices>
<protocols>
<add name="HttpPost"/>
<add name="HttpGet"/>
</protocols>
</webServices>
後,上代碼就可以調用遠程機器上的webservice了。
而利用SOAP發送在預設情況下即可得到.Net Framework1.1的支援,因此用構造Soap請求的xml字串給xmlhttp對象來send的方法就對遠程伺服器的web.config沒有要求了,於是根據local顯示的例子構造了一個soapRequest的string,發送給了即將部署的遠程主機,結果返回了200的status code,並且可以順利取得responseXML.類似代碼如下:

用戶端代碼如下:
<script language="vbscript">
Dim url,xmlhttp,dom,node,xmlDOC
'根據webservice的測試頁不同的方法構造不同的soap request
SoapRequest = "<?xml version="&CHR(34)&"1.0"&CHR(34)&" encoding="&CHR(34)&"utf-8"&CHR(34)&"?>"& _
"<soap:Envelope xmlns:xsi="&CHR(34)&"http://www.w3.org/2001/XMLSchema-instance"&CHR(34)&" "& _
"xmlns:xsd="&CHR(34)&"http://www.w3.org/2001/XMLSchema"&CHR(34)&" "& _
"xmlns:soap="&CHR(34)&"http://schemas.xmlsoap.org/soap/envelope/"&CHR(34)&">"& _
"<soap:Body>"& _
"<add xmlns="&CHR(34)&"http://localhost"&CHR(34)&">"& _
"<x>3</x>"& _
"<y>4</y>"& _
"</add>"& _
"</soap:Body>"& _
"</soap:Envelope>"
url = "http://www.xxxx.com/Service1.asmx?methodname=Add"
Set xmlDOC =CreateObject("MSXML.DOMDocument")
xmlDOC.loadXML(SoapRequest)
Set xmlhttp = CreateObject("Msxml2.XMLHTTP")
xmlhttp.Open "POST",url,false
xmlhttp.setRequestHeader "Content-Type", "text/xml;charset=utf-8"
'SOAPAction這個Header頭同樣可以在sample中找到
xmlhttp.setRequestHeader "SOAPAction", "http://localhost/add"
xmlhttp.setRequestHeader "Content-Length",LEN(SoapRequest)
xmlhttp.Send(xmlDOC)
msgbox xmlhttp.Status
msgbox xmlhttp.StatusText
msgbox xmlhttp.responseText
If xmlhttp.Status = 200 Then
xmlDOC.load(xmlhttp.responseXML)
msgbox "執行結果為:"&xmlDOC.getElementsByTagName("addResult")(0).text
else
msgbox "failed"
end if
</script>

改為伺服器端的asp代碼為:
<%
Dim url,xmlhttp,dom,node,xmlDOC
'根據webservice的測試頁不同的方法構造不同的soap request
SoapRequest = "<?xml version="&CHR(34)&"1.0"&CHR(34)&" encoding="&CHR(34)&"utf-8"&CHR(34)&"?>"& _
"<soap:Envelope xmlns:xsi="&CHR(34)&"http://www.w3.org/2001/XMLSchema-instance"&CHR(34)&" "& _
"xmlns:xsd="&CHR(34)&"http://www.w3.org/2001/XMLSchema"&CHR(34)&" "& _
"xmlns:soap="&CHR(34)&"http://schemas.xmlsoap.org/soap/envelope/"&CHR(34)&">"& _
"<soap:Body>"& _
"<add xmlns="&CHR(34)&"http://localhost"&CHR(34)&">"& _
"<x>3</x>"& _
"<y>4</y>"& _
"</add>"& _
"</soap:Body>"& _
"</soap:Envelope>"
url = "http://www.xxxx.com/Service1.asmx?methodname=Add"
Set xmlDOC =server.CreateObject("MSXML.DOMDocument")
xmlDOC.loadXML(SoapRequest)
Set xmlhttp = server.CreateObject("Msxml2.XMLHTTP")
xmlhttp.Open "POST",url,false
xmlhttp.setRequestHeader "Content-Type", "text/xml;charset=utf-8"
xmlhttp.setRequestHeader "SOAPAction", "http://localhost/add"
xmlhttp.setRequestHeader "Content-Length",LEN(SoapRequest)
xmlhttp.Send(xmlDOC)
If xmlhttp.Status = 200 Then
xmlDOC.load(xmlhttp.responseXML)
Response.Write xmlhttp.Status&"<br>"
Response.Write xmlhttp.StatusText&"<br>執行結果為:"
Response.Write xmlDOC.getElementsByTagName("addResult")(0).text
else
Response.Write xmlhttp.Status&"<br>"
Response.Write xmlhttp.StatusText
end if
%>

以上用的都是vbscript的,對於javascript基本上都是一樣的,只需要做一些小的改動,具體代碼這裡就省略了。

/////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

附:
測試時用的webservice檔案Service1.asmx的代碼:
using System;
using System.Collections;
using System.ComponentModel;
using System.Data;
using System.Diagnostics;
using System.Web;
using System.Web.Services;

namespace possible
{
/// <summary>
/// Service1 的摘要說明。
/// </summary>
[WebService(Description="my web service",Name="myService",Namespace="http://localhost")]
public class myService : System.Web.Services.WebService
{
public myService()
{
//CODEGEN: 該調用是 ASP.NET Web 服務設計器所必需的
InitializeComponent();
}

#region 組件設計器產生的程式碼

//Web 服務設計器所必需的
private IContainer components = null;

/// <summary>
/// 設計器支援所需的方法 - 不要使用代碼編輯器修改
/// 此方法的內容。
/// </summary>
private void InitializeComponent()
{
}

/// <summary>
/// 清理所有正在使用的資源。
/// </summary>
protected override void Dispose( bool disposing )
{
if(disposing && components != null)
{
components.Dispose();
}
base.Dispose(disposing);
}

#endregion

[WebMethod(Description="返回兩整數之和")]
public int add(int x,int y)
{
return x+y;
}
}
}



相關文章

E-Commerce Solutions

Leverage the same tools powering the Alibaba Ecosystem

Learn more >

11.11 Big Sale for Cloud

Get Unbeatable Offers with up to 90% Off,Oct.24-Nov.13 (UTC+8)

Get It Now >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。