詳解SQL Server的兩個預存程序:sp_MSforeachtable/sp_MSforeachdb

1.簡介:
    作為DBA會經常需要檢查所有的資料庫或使用者表,比如:檢查所有資料庫的容量;看看指定資料庫所有使用者表的容量,所有表的記錄數...,我們一般處理這樣的問題都是用遊標分別處理處理,比如:在資料庫檢索效率非常慢時,我們想檢查資料庫所有的使用者表,我們就必須通過寫遊標來達到要求；如果我們用sp_MSforeachtable就可以非常方便的達到相同的目的:EXEC sp_MSforeachtable @command1="print '?' DBCC CHECKTABLE ('?')"
    系統預存程序sp_MSforeachtable和sp_MSforeachdb,是微軟提供的兩個不公開的預存程序,從mssql6.5開始。存放在SQL Server的MASTER資料庫中。可以用來對某個資料庫的所有表或某個SQL伺服器上的所有資料庫進行管理，後面將對此進行詳細介紹。

2.參數說明:
  @command1 nvarchar（2000）,                     --第一條啟動並執行SQL指令
  @replacechar nchar（1） = N'?',                     --指定的預留位置號
  @command2 nvarchar（2000）= null,           --第二條啟動並執行SQL指令
  @command3 nvarchar（2000）= null,           --第三條啟動並執行SQL指令
  @whereand nvarchar（2000）= null,              --可選條件來選擇表
  @precommand nvarchar（2000）= null,       --執行指令前的操作(類似控制項的觸發前的操作)
  @postcommand nvarchar（2000）= null      --執行指令後的操作(類似控制項的觸發後的操作)

  以後為sp_MSforeachtable的參數，sp_MSforeachdb不包括參數@whereand

3.使用舉例:

  --統計資料庫裡每個表的詳細情況：
  exec sp_MSforeachtable @command1="sp_spaceused '?'"

  --獲得每個表的記錄數和容量:
  EXEC sp_MSforeachtable @command1="print '?'",
       @command2="sp_spaceused '?'",
       @command3= "SELECT count(*) FROM ? "

  --獲得所有的資料庫的儲存空間:
  EXEC sp_MSforeachdb  @command1="print '?'",
       @command2="sp_spaceused "

  --檢查所有的資料庫
  EXEC sp_MSforeachdb  @command1="print '?'",
       @command2="DBCC CHECKDB (?) "

  --更新PUBS資料庫中已t開頭的所有表的統計:
  EXEC sp_MSforeachtable @whereand="and name like 't%'",
       @replacechar='*',
       @precommand="print 'Updating Statistics.....' print ''",
       @command1="print '*' update statistics * ",
       @postcommand= "print''print 'Complete Update Statistics!'"

  --刪除當前資料庫所有表中的資料
  sp_MSforeachtable @command1='Delete from ?'
  sp_MSforeachtable @command1 = "TRUNCATE TABLE ?"

4.參數@whereand的用法：

  @whereand參數在預存程序中起到指令條件限制的作用，具體的寫法如下：
  @whereend,可以這麼寫 @whereand=' AND o.name in (''Table1'',''Table2'',.......)'
  例如：我想更新Table1/Table2/Table3中NOTE列為NULL的值
  sp_MSforeachtable @command1='Update ? Set NOTE='''' Where NOTE is NULL',@whereand=' AND o.name in (''Table1'',''Table2'',''Table3'')'

5."?"在預存程序的特殊用法,造就了這兩個功能強大的預存程序.

      這裡"?"的作用,相當於DOS命令中、以及我們在WINDOWS下搜尋檔案時的萬用字元的作用。

6.小結

  有了上面的分析,我們可以建立自己的sp_MSforeachObject:（轉貼）
USE MASTER
GO
CREATE proc sp_MSforeachObject
 @objectType int=1,
 @command1 nvarchar(2000),
 @replacechar nchar(1) = N'?',
 @command2 nvarchar(2000) = null,
    @command3 nvarchar(2000) = null,
 @whereand nvarchar(2000) = null,
 @precommand nvarchar(2000) = null,
 @postcommand nvarchar(2000) = null
as
 /* This proc returns one or more rows for each table (optionally, matching @where), with each table defaulting to its
own result set */
 /* @precommand and @postcommand may be used to force a single result set via a temp table. */
 /* Preprocessor won't replace within quotes so have to use str(). */
 declare @mscat nvarchar(12)
 select @mscat = ltrim(str(convert(int, 0x0002)))
 if (@precommand is not null)
  exec(@precommand)
 /* Defined  @isobject for save object type */
 Declare @isobject varchar(256)
 select @isobject= case @objectType when 1 then 'IsUserTable'
         when 2 then 'IsView'
         when 3 then 'IsTrigger'
         when 4 then 'IsProcedure'
         when 5 then 'IsDefault'  
         when 6 then 'IsForeignKey'
         when 7 then 'IsScalarFunction'
         when 8 then 'IsInlineFunction'
         when 9 then 'IsPrimaryKey'
         when 10 then 'IsExtendedProc'   
         when 11 then 'IsReplProc'
         when 12 then 'IsRule'
                  end
 /* Create the select */
 /* Use @isobject variable isstead of IsUserTable string */
EXEC(N'declare hCForEach cursor global for select ''['' + REPLACE(user_name(uid), N'']'', N'']]'') + '']'' + ''.'' + ''['' +
REPLACE(object_name(id), N'']'', N'']]'') + '']'' from dbo.sysobjects o '
        + N' where OBJECTPROPERTY(o.id, N'''+@isobject+''') = 1 '+N' and o.category & ' + @mscat + N' = 0 '
       + @whereand)
 declare @retval int
 select @retval = @@error
 if (@retval = 0)
  exec @retval = sp_MSforeach_worker @command1, @replacechar, @command2, @command3
 if (@retval = 0 and @postcommand is not null)
  exec(@postcommand)
 return @retval
GO

這樣我們來測試一下:
   --獲得所有的預存程序的指令碼:
         EXEc sp_MSforeachObject @command1="sp_helptext '?' ",@objectType=4
   --獲得所有的視圖的指令碼:
         EXEc sp_MSforeachObject @command1="sp_helptext '?' ",@objectType=2
   --比如在開發過程中,沒一個使用者都是自己的OBJECT OWNER,所以在真實的資料庫時都要改為DBO:
         EXEc sp_MSforeachObject @command1="sp_changeobjectowner '?', 'dbo'",@objectType=1
         EXEc sp_MSforeachObject @command1="sp_changeobjectowner '?', 'dbo'",@objectType=2
         EXEc sp_MSforeachObject @command1="sp_changeobjectowner '?', 'dbo'",@objectType=3
         EXEc sp_MSforeachObject @command1="sp_changeobjectowner '?', 'dbo'",@objectType=4
   這樣就非常方便的將每一個資料庫物件改為DBO.