用asp自動解析網頁中的圖片地址

一，取得原頁中的圖片的地址。

<%
function PicStr(str)
Set objRegExp = New Regexp '設定設定物件
objRegExp.IgnoreCase = True '忽略大小寫
objRegExp.Global = True '設定為全文檢索搜尋
objRegExp.Pattern = "<IMG.+?>" '為了確保能準確地取出圖片地址所以分為兩層配置：首先找到裡面的<IMG>標籤，然後再取出裡面的圖片地址後面的getimgs函數就是實現後一個功能的。
strs=trim(str)
Set Matches =objRegExp.Execute(strs) '開始執行配置
For Each Match in Matches
PicStr = PicStr &getimgs( Match.Value ) '執行第二輪的匹配
Next
'所有的圖片在裡面都是這樣的src="http://圖片的地址"，所以可以這樣來取得確切的圖片地址
end function

function getimgs(str)
getimgs=""
Set objRegExp1 = New Regexp
objRegExp1.IgnoreCase = True
objRegExp1.Global = True
objRegExp1.Pattern = "http://.+?""" '取出裡面的地址
set mm=objRegExp1.Execute(str)
For Each Match1 in mm
getimgs=getimgs&"||"&left(Match1.Value,len(Match1.Value)-1) '把裡面的地址串起來備用
next
end function
%>

二，下載圖片並儲存在伺服器上。

<%
function getHTTPPage(url)
on error resume next
dim http
set http=server.createobject("MSXML2.XMLHTTP") '使用xmlhttp的方法來獲得圖片的內容
Http.open "GET",url,false
Http.send()
if Http.readystate<>4 then
exit function
end if
getHTTPPage=Http.responseBody
set http=nothing
if err.number<>0 then err.Clear
end function
'取得了圖片的內容要儲存，給人一種感覺是用FSO來作就可以了，但實際上不行，這樣儲存程式就會出錯，因為FSO不支援流式的檔案，所以我們要調用另一個對象：ADO.STREM。具體的過程如下：
function saveimage(from,tofile)
dim geturl,objStream,imgs
geturl=trim(from)
imgs=gethttppage(geturl)'取得圖片的具休內容的過程
Set objStream = Server.CreateObject("ADODB.Stream")'建立ADODB.Stream對象，必須要ADO 2.5以上版本
objStream.Type =1'以二進位模式開啟
objStream.Open
objstream.write imgs'將字串內容寫入緩衝
objstream.SaveToFile server.mappath(tofile),2'-將緩衝的內容寫入檔案
objstream.Close()'關閉對象
set objstream=nothing
end function

'所以只要用一個迴圈來把剛才取得的地址中的圖片全部儲存下來，具體過程如下：
arrimg=split(PicStr(str),"||") '分割字串，取得裡面地址清單
allimg=""
newimg=""
for i=1 to ubound(arrimg)
if arrimg(i)<>"" and instr(allimg,arrimg(i))<1 then '看這個圖片是否已經下載過
fname=baseurl&cstr(i&mid(arrimg(i),instrrev(arrimg(i),".")))
saveimage(arrimg(i),fname)‘儲存地址的函數，過程見上面
allimg=allimg&"||"&arrimg(i) '把儲存下來的圖片的地址串回起來，以確定要替換的地址
newimg=newimg&"||"&fname '把本地的地址串回起來
end if
next
'第三步就是替換原來的地址了。具體的過程就是下面了：
arrnew=split(newimg,"||") '取得原來的圖片地址清單
arrall=split(allimg,"||") '取得已經儲存下來的圖片的地址清單
for i=1 to ubound(arrnew) '執行迴圈替換原來的地址
strs=replace(strs,arrall(i),arrnew(i))
next
%>