asp sqlserver 執行預存程序返回記錄集報對象關閉時不允許操作

如果要得到傳回值，需要用Command的方法。
首先說明，傳回值有兩種。一種是在預存程序中直接return一個值，就象C和VB的函數傳回值那樣；另一種是可以返回多個值，儲存這些值的變數名稱需要在調用參數中先行指定。
這個例子要處理多種參數，輸入參數，輸出參數，返回記錄集以及一個直接傳回值（夠全了吧？）
預存程序如下： 複製代碼 代碼如下:use pubs
GO
-- 建立預存程序
create procedure sp_PubsTest
-- 定義三個參數變數，注意第三個，特別標記是用於輸出
@au_lname varchar (20),
@intID int,
@intIDOut int OUTPUT
AS
SELECT @intIDOut = @intID + 1
SELECT *
FROM authors
WHERE au_lname LIKE @au_lname + ''%''
--直接返回一個值
RETURN @intID + 2

調用該預存程序的asp程式如下： 複製代碼 代碼如下:<%@ Language=VBScript %>
<%
Dim CmdSP
Dim adoRS
Dim adCmdSPStoredProc
Dim adParamReturnValue
Dim adParaminput
Dim adParamOutput
Dim adInteger
Dim iVal
Dim oVal
Dim adoField
Dim adVarChar
‘這些值在 VB 中是預定義常量，可以直接調用，但在 VBScript 中沒有預定義
adCmdSPStoredProc = 4
adParamReturnValue = 4
adParaminput = 1
adParamOutput = 2
adInteger = 3
adVarChar = 200
iVal = 5
oVal = 3
''建一個command對象
set CmdSP = Server.CreateObject("ADODB.Command")
''建立連結
CmdSP.ActiveConnection = "Driver={SQL Server};server=(local);Uid=sa;Pwd=;Database=Pubs"
''定義command 對象調用名稱
CmdSP.CommandText = "sp_PubsTest"
''設定command調用類型是預存程序 (adCmdSPStoredProc = 4)
CmdSP.CommandType = adCmdSPStoredProc
''往command 對象中加參數
''定義預存程序有直接傳回值，並且是個整數，省缺值是4
CmdSP.Parameters.Append CmdSP.CreateParameter("RETURN_VALUE", adInteger, adParamReturnValue, 4)
''定義一個字元型輸入參數
CmdSP.Parameters.Append CmdSP.CreateParameter("@au_lname", adVarChar, adParaminput, 20, "M")
''定義一個整型輸入參數
CmdSP.Parameters.Append CmdSP.CreateParameter("@intID", adInteger, adParamInput, , iVal)
''定義一個整型輸出參數
CmdSP.Parameters.Append CmdSP.CreateParameter("@intIDOut", adInteger, adParamOutput, oVal)
''運行預存程序，並得到返回記錄集
Set adoRS = CmdSP.Execute
''把每個記錄列印出來，其中的欄位是虛擬，可以不用管
While Not adoRS.EOF
for each adoField in adoRS.Fields
Response.Write adoField.Name & "=" & adoField.Value & "<br>" & vbCRLF
Next
Response.Write "<br>"
adoRS.MoveNext
Wend
''列印兩個輸出值：
Response.Write "<p>@intIDOut = “ & CmdSP.Parameters("@intIDOut").Value & "</p>"
Response.Write "<p>Return value = " & CmdSP.Parameters("RETURN_VALUE").Value & "</p>"
''大掃除
Set adoRS = nothing
Set CmdSP.ActiveConnection = nothing
Set CmdSP = nothing
%>

用asp調用預存程序並返回記錄集的時候，一直報出“對象關閉時不允許操作”的錯誤，搜了很多問題，都不能對症下藥，找了一段比較靠譜的代碼
最後發現問題出現在預存程序裡，例子裡的預存程序沒有問題，但是用上我自己的預存程序就報錯
最後的解決辦法是在我自己用的預存程序裡的要在
每個Insert語句之前都加一句set nocount on 也就是在遊標迴圈裡面加一句
具體什麼原因還沒有去深究，瞭解的人可以指明下，謝謝