用VBS讀寫二進位檔案的另一種方法分享

之前寫的那篇給出的方法雖然不錯，但是當檔案過大時（其實很小，也就幾M），對應的數組也會很大，然後會出現執行階段錯誤，提示記憶體耗盡，為此我鬱悶了好久。

最近在部落格的流量記錄中發現百度關鍵字“一些很惡作劇的vbs程式”（看來現在的年輕人很喜歡玩這口），於是開啟久違的百度搜尋了一下，發現出現在第三。出現在第二的是百度HI，上面也是一個惡作劇程式，而且還是加密的。我嘗試著解密，卻發現這個加密似乎比前幾天解密的那個病毒更變態，未果。

雖然我沒有把那個程式解密出來（如果哪位真正的高手會，麻煩指點一下），但是從中領悟出了用VBS讀寫二進位檔案的另一種方法，即Microsoft.XMLDOM+ADODB.Stream。這個方法的效率比原來那個高得多，而且似乎沒有檔案大小限制。 複製代碼 代碼如下:Function ReadBinary(FileName)
Const adTypeBinary = 1
Dim stream, xmldom, node
Set xmldom = CreateObject("Microsoft.XMLDOM")
Set node = xmldom.CreateElement("binary")
node.DataType = "bin.hex"
Set stream = CreateObject("ADODB.Stream")
stream.Type = adTypeBinary
stream.Open
stream.LoadFromFile FileName
node.NodeTypedValue = stream.Read
stream.Close
Set stream = Nothing
ReadBinary = node.Text
Set node = Nothing
Set xmldom = Nothing
End Function

函數的參數是要讀取的檔案路徑，傳回值是包含二進位檔案的十六進位值的字串。 複製代碼 代碼如下:Sub WriteBinary(FileName, Buf)
Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2
Dim stream, xmldom, node
Set xmldom = CreateObject("Microsoft.XMLDOM")
Set node = xmldom.CreateElement("binary")
node.DataType = "bin.hex"
node.Text = Buf
Set stream = CreateObject("ADODB.Stream")
stream.Type = adTypeBinary
stream.Open
stream.write node.NodeTypedValue
stream.saveToFile FileName, adSaveCreateOverWrite
stream.Close
Set stream = Nothing
Set node = Nothing
Set xmldom = Nothing
End Sub

第一個參數是要讀入的檔案路徑，第二個參數是包含二進位檔案的十六進位值的字串。至於如何獲得二進位檔案的十六進位值，那方法就很多了，最簡單的方法當然就是用fso對象將ReadBinary函數的傳回值寫到文字檔中去，然後Ctrl+C，Ctrl+V。其實用十六進位工具也很簡單。

其他的就不多說了，看不懂的多看看MSDN參考文檔。寫了一個樣本程式，裡麵包含了天空之城音樂的所有資料，雙擊後在同一檔案夾產生天空之城的MP3檔案並播放。

原文：http://demon.tw/programming/vbs-binary-file-another.html