類：初識類的事件

先勾畫一下思路:
1、建立一個類, 裡面有年齡欄位 FAge;
2、通過 Age 屬性讀寫 FAge;
3、如果輸入的年齡剛好是 100 歲, 將會激發一個事件, 這個事件我們給它命名為: OnHundred

 

Code
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  //先定義一個特殊的類型，一個對象所屬的過程類型，這就是建立一個事件的前提
  TMyEvent = procedure of Object;

  TMyClass = class
  strict private
    FAge: Integer; //年齡欄位
    FOnHundred: TMyEvent; //為我們剛剛定義的TMyEvent類型指定一個變數：FOnHundred
    procedure SetAge(const Age: Integer);
  public
    procedure SetOnHundred1; //建立事件要調用的過程
    procedure SetOnHundred2; //建立事件要調用的過程
    constructor Create;
    property Age: Integer read FAge write SetAge;
    property OnHundred: TMyEvent read FOnHundred write FOnHundred; //其它事件也是屬性，事件命名一般由On開始
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TMyClass }

constructor TMyClass.Create;
begin
  FOnHundred := SetOnHundred1; //在對象建立時，我們先讓事件調用 SetOnHundred1方法
end;

procedure TMyClass.SetAge(const Age: Integer);
begin
 if (Age > 0) and (Age < 200) then FAge := Age;
 if Age = 100 then OnHundred; //當輸入的年齡是100歲時，啟用事件

end;

procedure TMyClass.SetOnHundred1;
begin
  ShowMessage('祝您100歲大壽！');
end;

procedure TMyClass.SetOnHundred2;
begin
  ShowMessage('但願我們都能活到100歲。');
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  MyClass: TMyClass;
begin
  MyClass := TMyClass.Create;
  MyClass.Age := 99; //如果年齡不是負數而又小於200
  ShowMessage(IntToStr(MyClass.Age)); //99 對象就接受了
  MyClass.Free;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  MyClass: TMyClass;
begin
  MyClass := TMyClass.Create;
  MyClass.Age := 100;
  MyClass.Free;
end;

procedure TForm1.Button3Click(Sender: TObject);
var
  MyClass: TMyClass;
begin
  MyClass := TMyClass.Create;
  MyClass.OnHundred := MyClass.SetOnHundred2; //讓事件指定另一個方法
  MyClass.Age := 100; //這時會啟用事件，彈出對話方塊：但願我們都能活到100歲
  MyClass.Free;
end;

end.