晚上在 QQ 上看到暱稱為“亂碼”的好友回答了搜搜問問裡一個問題：
在VBS中有辦法定義位元組數組嗎？
在VBS中有辦法定義位元組數組嗎？就是位元組子類型數組（VarType是8209的那種）注意不是VB！
但是回答實在是不堪入目，連別人問什麼都沒搞懂，而且那人居然還滿意，真不知道他在想什麼。
閑來沒事，我來簡單回答一下。首先要搞清楚別人在問什麼，VBS 是弱類型指令碼語言，只有一種資料類型，稱為 Variant，但是 Variant 可以進一步分為幾種子類型，這裡不展開，詳見《VBScript 資料類型》。所謂位元組子類型數組（VarType是8209的那種），就是子類型為 Byte 的數組（vbByte + vbArray = 17 + 8192 = 8209）。
例如，Msxml2.XMLHTTP 對象的 responseBody 屬性返回的就是位元組數組：
複製代碼 代碼如下:
'Author: Demon
'Website: http://demon.tw
'Date: 2012/2/22
Dim http, res
Set http = CreateObject("Msxml2.XMLHTTP")
http.open "GET", "http://demon.tw", False
http.send
res = http.responseBody
WScript.Echo VarType(res), TypeName(res)
再例如，ADODB.Stream 對象的 Read 方法返回的也是位元組數組：
複製代碼 代碼如下:
'Author: Demon
'Website: http://demon.tw
'Date: 2012/2/22
Dim ado, data
Set ado = CreateObject("ADODB.Stream")
ado.Type = 1
ado.Open
ado.LoadFromFile "demon.tw"
data = ado.Read
WScript.Echo VarType(data), TypeName(data)
那麼如何在 VBS 中定義一個位元組數組呢？有人說那還不簡單，用 CByte 函數強制轉換一下不就行了？真的是這樣麼，寫個簡單的例子測試一下：
複製代碼 代碼如下:
'Author: Demon
'Website: http://demon.tw
'Date: 2012/2/22
Dim a(9), i
For i = 0 To 9
a(i) = CByte(i)
Next
WScript.Echo VarType(a), TypeName(a)
'輸出 8204 Variant()程式輸出 8204 Variant()，很可惜，這不是我們想要的。
那麼正確的方法是什麼呢？其實在《用VBS讀寫二進位檔案的另一種方法》中出現過，使用 Msxml2.DOMDocument 對象：
複製代碼 代碼如下:
'Author: Demon
'Website: http://demon.tw
'Date: 2012/2/22
Dim xmldoc, node, bytes
Set xmldoc = CreateObject("Msxml2.DOMDocument")
Set node = xmldoc.CreateElement("binary")
node.DataType = "bin.hex"
'demon.tw 的十六進位值為
'64 65 6D 6F 6E 2E 74 77
node.Text = "64656D6F6E2E7477"
bytes = node.NodeTypedValue
WScript.Echo VarType(bytes), TypeName(bytes)
這樣 bytes 變數就是位元組數組了，如果你知道其他的方法，歡迎不吝賜教。
原文：http://demon.tw/programming/vbs-byte-array.html
