開發基於XML的留言板
XML（Extensible Markup Language）是一種基於文字格式設定的標記語言，它注重對資料結構和資料意義的描述，實現了資料內容和顯示樣式的分離，而且是與平台無關的。由於XML注重資料內容的描述，因而，對於資料的檢索非常有意義，我們不會再象HTML那樣，檢索出與我們要求無關的資訊。另一方面，XML檔案是資料的載體，利用XML作為資料庫，不需要訪問任何資料庫系統，我們可以使用任意WEB技術來顯示我們的資料，比如HTML，Flash 5 等。由於世界各大電腦公司的積极參与，XML正日益成為基於互連網的資料格式新一代的標準。下面利用XML作為資料的載體，開發一個基於XML的留言板。
首先，我們建立XML檔案guestbook.xml，該檔案記錄了留言者的姓名、電子郵件、網址、留言內容。當然，我們也可以根據需要添加任意多的資訊。檔案內容如下：
<?xml version="1.0" encoding="gb2312"?>
<留言本>
<留言記錄>
<留言者姓名>孟憲會</留言者姓名>
<電子郵件>amxh@testDomain.com</電子郵件>
<網址>http://go.163.com/~colorweb</網址>
<留言內容>測試成功！！</留言內容>
</留言記錄>
</留言本>
由於目前許多伺服器都支援ASP，我們採用常見的ASP來作為實現的工具，guestbook.asp檔案如下：
<%@Language="VBScript"%>
<%
'設定Web頁面的資訊
Response.Buffer = true
Response.Expires = -1
'顯示留言函數init()
Function init()
entryForm()
'定義局部變數
Dim objXML
Dim arrNames
Dim arrEmails
Dim arrURLS
Dim arrMessages
'建立XMLDOM文檔對象，用來存放留言
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))
'取得留言本各元素的集合
Set arrNames = objXML.getElementsByTagName("留言者姓名")
Set arrEmails = objXML.getElementsByTagName("電子郵件")
Set arrURLS = objXML.getElementsByTagName("網址")
Set arrMessages = objXML.getElementsByTagName("留言內容")
Response.Write "<table border='0' width='100%'>"
Response.Write "<tr><td bgcolor='#00CCFF' align='center' height='26'>"
Response.Write "<b>各位的留言如下：</b>"
Response.Write "</td></tr>"
'輸出留言本各元素的內容，最新的留言先顯示
For x=arrNames.length-1 To 0 Step -1
Response.Write "<tr><td><a href=mailto:" & arrEmails.item(x).text & ">" & arrNames.item(x).text & "</a></td></tr>"
Response.Write "<tr><td>網址：<a href=" & arrURLS.item(x).text & " target='_blank'>" & arrURLS.item(x).text & "</a><td></tr>"
Response.Write "<tr><td>留言內容：</td></tr>"
Response.Write "<tr><td bgcolor='#0099ff'>" & arrMessages.item(x).text &"</td></tr>"
Response.Write "<tr><td> </td></tr>"
Next
Response.Write "</table>"
Set objXML = nothing
End Function
'向XML檔案添加留言記錄的函數addEntry()
Function addEntry()
'定義局部變數
Dim strName
Dim strEmail
Dim strURL
Dim strMessage
'取得留言表單的輸入內容
strName = Request.Form("姓名")
strEmail = Request.Form("電子郵件")
strURL = Request.Form("網址")
strMessage = Request.Form("留言")
Dim objXML
Dim objEntry
Dim objName
Dim objEmail
Dim objURL
Dim objMessage
'向XML檔案添加留言內容
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))
Set objEntry = objXML.createNode("element", "留言記錄", "")
objXML.documentElement.appendChild(objEntry)
Set objName = objXML.createNode("element", "留言者姓名", "")
objEntry.appendChild(objName)
objName.text = strName
Set objEmail = objXML.createNode("element", "電子郵件", "")
objEntry.appendChild(objEmail)
objEmail.text = strEmail
Set objURL = objXML.createNode("element", "網址", "")
objEntry.appendChild(objURL)
objURL.text = strURL
Set objMessage = objXML.createNode("element", "留言內容", "")
objEntry.appendChild(objMessage)
objMessage.text = strMessage
objXML.save(server.MapPath("guestbook.xml"))
Response.Redirect("guestbook.asp")
End function
'填寫和發送留言表單的函數entryForm()
Function entryForm()
Response.Write "<p align='center'><b>XML 留言本 例子</b></p>"
Response.Write "<hr color='#000099' width='100%' noshade>"
Response.Write "<form action=guestbook.asp?action=addEntry method=post>"
Response.Write "<table border=1>"
Response.Write "<tr><td>您的姓名：</td><td><input type=text name=姓名 /></td></tr>"
Response.Write "<tr><td>電子郵件：</td><td><input type=text name=電子郵件 /></td></tr>"
Response.Write "<tr><td>您的網址：</td><td><input type=text name=網址 /></td></tr>"
Response.Write "<tr><td>您的留言：</td><td><textarea name=留言 cols=40 rows=5></textarea></td></tr>"
Response.Write "<tr><td> </td><td><input type=submit value=發布留言 /></td></tr>"
Response.Write "</table>"
Response.Write "</form>"
End Function
%>
<html>
<head>
<title>XML 留言例子</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</head>
<body>
<%
'判斷是否發送了留言，並更新留言資訊
Dim a
a = Request.Querystring("action")
If a<>"" Then
addEntry
else
init
End If
%>
</body>
</html>
以上是利用XML開發留言板簡單的例子，可以根據需要進行添加更多的功能，所有程式在WIN98SE+PWS+IE5.5+MSXML3+Netscape4.75+Netscape6調試通過。
Start building with 50+ products and up to 12 months usage for Elastic Compute Service
1 on 1 presale consultation
24/7 Technical Support 6 Free Tickets per Quarter Faster Response
Alibaba Cloud offers highly flexible support services tailored to meet your exact needs.
A comprehensive suite of global cloud computing services to power your business
Payment Methods We Support
