得到對象指令碼

/*
 在查詢分析器中調用sqldmo產生指令碼--預存程序

鄒建 2003.07(引用請保留此資訊)--*/

/*--調用執行個體
 declare @str varchar(8000)
 exec sp_getscript 'zj','','','xzkh_sa','地區資料',@str output
 print @str
*/
if exists(select 1 from sysobjects where id=object_id('sp_getscript') and objectproperty(id,'IsProcedure')=1)
 drop procedure sp_getscript
go
create procedure sp_getscript
 @servername varchar(50)      --伺服器名
 ,@userid varchar(50)       --使用者名稱,如果為nt驗證方式,則為空白
 ,@password varchar(50)      --密碼
 ,@databasename varchar(50)    --資料庫名稱
 ,@objectname varchar(250)     --對象名
 ,@re varchar(8000) output     --返回指令碼
as
declare @srvid int,@dbsid int    --定義伺服器、資料庫集id
declare @dbid int,@tbid int     --資料庫、表id
declare @err int,@src varchar(255), @desc varchar(255) --錯誤處理變數

--建立sqldmo對象
exec @err=sp_oacreate 'sqldmo.sqlserver',@srvid output
if @err<>0 goto lberr

--串連伺服器
if isnull(@userid,'')='' --如果是 Nt驗證方式
begin
 exec @err=sp_oasetproperty @srvid,'loginsecure',-1
 if @err<>0 goto lberr

 exec @err=sp_oamethod @srvid,'connect',null,@servername
end
else
 exec @err=sp_oamethod @srvid,'connect',null,@servername,@userid,@password

if @err<>0 goto lberr

--擷取資料庫集
exec @err=sp_oagetproperty @srvid,'databases',@dbsid output
if @err<>0 goto lberr

--擷取要取得指令碼的資料庫id
exec @err=sp_oamethod @dbsid,'item',@dbid output,@databasename
if @err<>0 goto lberr

--擷取要取得指令碼的對象id
exec @err=sp_oamethod @dbid,'getobjectbyname',@tbid output,@objectname
if @err<>0 goto lberr

--取得指令碼
exec @err=sp_oamethod @tbid,'script',@re output
if @err<>0 goto lberr

--print @re
return

lberr:
 exec sp_oageterrorinfo NULL, @src out, @desc out
 declare @errb varbinary(4)
 set @errb=cast(@err as varbinary(4))
 exec master..xp_varbintohexstr @errb,@re out
 select 錯誤號碼=@re, 錯誤源=@src, 錯誤描述=@desc
 return

go