純asp分離FORM資料中的二進位檔案和文本資料

來源:互聯網
上載者:User
二進位|資料 以下原始碼為一個檔案

<%
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'作者:playxp,Email:playxp@sohu.com有問題請與我聯絡
'功能:純asp分離FORM資料中的二進位檔案和文本資料(支援中文)。
'使用方法:將此檔案包含在處理form的asp檔案中,使用GetValue(name)來讀取表單中各個元素的值。
'注意:一定不要使用request.form來讀取資料。
'在絕大數的支援asp的首頁空間僅能使用有限的組件,不能使用上傳組件,而內建的Request對象又不
'支援讀取二進位檔案,因此使用該檔案可以解決上傳檔案困難的弊病,但在效能上卻大打折扣。本程式參考了網上的一些代碼。

'由GBK向UNICODE轉換
Function GBToU(BinStr,byteNum)
GBToU=""
For j=1 To byteNum
gbcode1=AscB(MidB(BinStr,j,1))
If gbcode1>&H80 Then
gbcode2=AscB(MidB(BinStr,j+1,1))
a=gbcode1-&H81
b=gbcode2-&H40
If gbcode2>&H7f Then b=b-1
GBToU=GBToU & ChrW(GB2U(a*190+b)) 'GB2U為轉換表
j=j+1
Else
GBToU=GBToU & ChrW(AscB(MidB(BinStr,j,1)))
End If
Next
End Function

'得到邊界字串
boundary=Mid(Request.ServerVariables("CONTENT_TYPE"),31)
'Form中資料的位元組數
byteCount=Request.TotalBytes
'Form中的位元據
binRead=Request.BinaryRead(byteCount)
'邊界ASCII字串
endStr=ChrB(13)&ChrB(10)&ChrB(45)&ChrB(45)
For i=1 To Len(boundary)
endStr=endStr&ChrB(AscB(Mid(boundary,i,1)))
Next

Dim FormValue(31,3)
Dim byteI '位元組指標
E=0
byteI=37+Len(boundary) '第一個元素資料開始處
Do While byteI<byteCount
If AscB(MidB(binRead,byteI,1))=110 Then '元素資料存在
FormValue(E,0)=""
FormValue(E,1)=""
FormValue(E,2)=""
FormValue(E,3)=""
byteI=byteI+6 '名字開始處
nameStart=byteI
byteI=InStrB(byteI,binRead,ChrB(34)) '名字結束處
nameLen=byteI-nameStart '名字長度
FormValue(E,0)=GBToU(MidB(binRead,nameStart,nameLen),nameLen) '讀入名字
If AscB(MidB(binRead,byteI+1,1))=13 Then '元素為文本
byteI=byteI+5 '文本資料開始處
dataStart=byteI
byteI=InStrB(byteI,binRead,endStr) '文本資料結束處
dataLen=byteI-dataStart '文本資料長度
FormValue(E,1)=GBToU(MidB(binRead,dataStart,dataLen),dataLen) '讀入文本資料
Else '元素為檔案
byteI=byteI+13 '路徑開始處
pathStart=byteI
byteI=InStrB(byteI,binRead,ChrB(34)) '路徑結束處
pathLen=byteI-pathStart
FormValue(E,2)=GBToU(MidB(binRead,pathStart,pathLen),pathLen) '讀入路徑
byteI=byteI+17 '檔案類型開始
typeStart=byteI
byteI=InStrB(byteI,binRead,ChrB(13)) '檔案類型結束處
typeLen=byteI-typeStart '檔案類型長度
FormValue(E,3)=GBToU(MidB(binRead,typeStart,typeLen),typeLen) '讀入檔案類型
byteI=byteI+4 '檔案資料開始處
dataStart=byteI
byteI=InStrB(byteI,binRead,endStr) '檔案資料結束處
dataLen=byteI-dataStart '檔案資料長度
FormValue(E,1)=MidB(binRead,dataStart,dataLen) '讀入檔案資料
End If
byteI=byteI+38+Len(boundary) '移向下一元素資料開始處
E=E+1
Else
Exit Do
End If
Loop

'根據元素名來檢索元素資料
'如果表單元素為文本資料直接返回其值
'如果表單元素為位元據檔案,則返回一3元素數組,第一個元素為檔案的位元據,
'第二個元素為檔案的路徑,第三個為檔案的類型。
Function GetValue(name)
For i=0 To 31
If StrComp(FormValue(i,0),name,1)=0 Then
If FormValue(i,3)="" Then
GetValue=FormValue(i,1)
Else
GetValue=Array(FormValue(i,1),FormValue(i,2),FormValue(i,3))
End If
Exit Function
End If
Next
GetValue=Null
End Function
%>




相關文章

E-Commerce Solutions

Leverage the same tools powering the Alibaba Ecosystem

Learn more >

Apsara Conference 2019

The Rise of Data Intelligence, September 25th - 27th, Hangzhou, China

Learn more >

Alibaba Cloud Free Trial

Learn and experience the power of Alibaba Cloud with a free trial worth $300-1200 USD

Learn more >

聯繫我們

該頁面正文內容均來源於網絡整理,並不代表阿里雲官方的觀點,該頁面所提到的產品和服務也與阿里云無關,如果該頁面內容對您造成了困擾,歡迎寫郵件給我們,收到郵件我們將在5個工作日內處理。

如果您發現本社區中有涉嫌抄襲的內容,歡迎發送郵件至: info-contact@alibabacloud.com 進行舉報並提供相關證據,工作人員會在 5 個工作天內聯絡您,一經查實,本站將立刻刪除涉嫌侵權內容。