實現掃描按鍵顯示功能

;********************************************************************************
;本程式實現掃描按鍵顯示功能.                                                    *   
;分別按16個鍵盤顯示分別顯示數字123A456B789C*0#D                                 *
;鍵盤口P1,數位管顯示第一位p21, 數位管段位p0口                                   *
;********************************************************************************
;將行線所接的單片機的IO口作為輸出端，而列線所接的IO口則作為輸入。這樣，當按鍵沒有按下時，所有的輸出端都是高電平，代表無鍵按下。
;行線輸出是低電平，一旦有鍵按下，則輸入線就會被拉低，這樣，通過讀入輸入線的狀態就可得知是否有鍵按下了。
;確定矩陣式按鍵上何鍵被按下，行掃描法或者線反轉法。
;行掃描法 行掃描法又稱為逐行（或列）掃描查詢法，是一種最常用的按鍵識別方法。
;判斷鍵盤中有無鍵按下：將全部行線置低電平，然後檢測列線的狀態。只要有一列的電平為低，則表示鍵盤中有鍵被按下，而且閉合的鍵位於
;低電平與4根行線線交叉的4個按鍵之中。若所有列線均為高電平，則鍵盤中無鍵按下。
;判斷閉合鍵所在的位置：在確認有鍵按下後，即可進入確定具體閉合鍵的過錯。其方法是：一次將行線置為低電平，即在置某根行線為低電平時，其他線為高電平。
;在確定某根行線位置為低電平後，再逐行檢測各列線的電平狀態。若某列為低，則該列線與置為低電平的行線交叉處的按鍵就是閉合的按鍵。
;單片機的P1口用作鍵盤I/O口，鍵盤的列線接到P1口的低4位，鍵盤的行線接到P1口的高4位，列線P1.0-P1.3設定為輸入線，行線P1.4-P1.7設定為輸出線，
;4根行線和4根列線形成16個相交點。
;1.檢測當前是否有鍵被按下，檢測的方法是P1.4-P1.7輸出全“0”，讀取P1.0-P1.3的狀態，若P1.0-P1.3為全“1”，則無鍵閉合，否則有鍵閉合；
;2.去除鍵抖動，當檢測到有鍵按下後，延時一段時間再做下一步的檢測判斷。
;3.若有鍵被按下，應識別出是哪一個鍵閉合。方法是對鍵盤的行線進行掃描。P1.4-P1.7按下述4種組合依次輸出：
;P1.7  1110    P1.6 1101  P1.5 1011   P1.4 0111
;在每組行輸出時讀取P1.0-P1.3，若全為“1”，則表示為“0”這一行沒有鍵閉合。否則有鍵閉合，由此得出閉合鍵的行值和列值，如後
;然後可採用計演算法和查表法將閉合鍵的行值和列值轉換成所定義的鍵；
;4,為保證鍵沒閉合一次CPU僅作一次處理，必須去除鍵釋放時的抖動；
     org 0000h
     ajmp main
     org 0030h
main:
     mov dptr,#tab  ;將表頭放入DPTR
     lcall key   ;調用鍵盤掃描程式
     movc a,@a+dptr               ;查表後將索引值送入ACC
     mov p0,a                    ;將Acc值送入P0口
     CLR P2.1                           ;開顯示
     ljmp main                    ;返回調用子程式反覆迴圈顯示
KEY: LCALL KS                           ;調用檢測按鍵子程式
     JNZ K1                             ;有鍵按下繼續
     LCALL DELAY2                       ;無鍵按下調用延時防震程式
     AJMP KEY                           ;返回繼續檢測有無按鍵按下
K1:  LCALL DELAY2
     LCALL DELAY2                       ;有鍵按下繼續延時防震
     LCALL KS                           ;再一次調用檢測按鍵程式
     JNZ K2                             ;確認有按下進行下一步
     AJMP KEY                           ;無鍵按下返回繼續檢測
K2:  MOV R2,#0EFH                       ;將掃描值送入 R2暫存
     MOV R4,#00H                        ;將第一列的列值00H送入R4暫存,R4用於存放列值。
K3:  MOV P1,R2                          ;將R2的值送入P1口
L6:  JB P1.0,L1                         ;P1.0等於1跳轉到L1
     MOV A,#00H                         ;將第一行的行值00H送入ACC
     AJMP LK                            ;跳轉到索引值處理常式
L1:  JB P1.1,L2                         ;P1.1等於1跳轉到L2
     MOV A,#04H                         ;將第二行的行值送入ACC
     AJMP LK                            ;跳轉到索引值理程式進行索引值處理
L2:  JB P1.2,L3                         ;P1.2等於1跳轉到L3
     MOV A,#08H                         ;將第三行的行值送入ACC
     AJMP LK                            ;跳轉到索引值處理常式
L3:  JB P1.3,NEXT                       ;P1.3等於1跳轉到NEXT處
     MOV A,#0cH                         ;將第四行的行值送入ACC
LK:  ADD A,R4                           ;行值與列值相加後的索引值送入A
     PUSH ACC                           ;將A中的值送入堆棧暫存
K4:  LCALL DELAY2                       ;調用延時防震程式
     LCALL KS                           ;調用按鍵檢測程式
     JNZ K4                             ;按鍵沒有鬆開繼續返回檢測
     POP ACC                            ;將堆棧的值送入ACC
     RET

NEXT:
      INC  R4                            ;將列值加一
      MOV A,R2                           ;將R2的值送入A
      JNB ACC.7,KEY                      ;掃描完成跳至KEY處進行下一回合的掃描
      RL A                               ;掃描未完成將A中的值右移一位進行下一列的掃描
      MOV R2,A                           ;將ACC的值送入R2暫存
      AJMP K3                            ;跳轉到K3繼續
KS:   MOV P1,#0FH                        ;將P1口高四位置0低四位值1
      MOV A,P1                           ;讀P1口
      XRL A,#0FH                         ;將A中的值與A中的值相異或
      RET                                ;子程式返回
DELAY2:                                  ;40ms延時防震子程式8*FA*2=40ms
      MOV R5,#08H
L7:   MOV R6,#0FAH
L8:   DJNZ R6,L8
      DJNZ R5,L7
      RET

tab:
      db  28h,34h,28h,34h,0a9h,60h,20h,7ah,20h,21h,61h,74h,30h,62h,0a2h,7eh
         ;0h0hc9878654a321 輪流顯示鍵盤因為無法表達*# 就用H表示，B用8表示
end